是否有可能从一个进程连接到 Oracle(通过 OCI)，然后从另一个进程连接到同一个数据库 session ？

在我当前的应用程序中，有两种访问数据库的方式:同步方式和异步方式(通过使用单独的进程，通过套接字进行通信)。 问题是这两种方法实现了不同的 session 。

如果我尝试，例如在一个 session 上更新，然后尝试在不提交的情况下从另一个 session 更新同一个表，我在 OCI 调用上挂起。

更糟糕的是，如果一个 session 变量是从一个 session 设置的——另一个 session 看不到它(这正是名字所说的...)。

最佳答案

如果您使用的是 11g 数据库，则可以使用 DBMS_XA package允许一个 session 加入由第一个 session 启动的事务。正如 Tim Hall 所演示的那样，您可以在一个 session 中启动一个事务，从另一个 session 中加入该事务，然后读取事务中未提交的更改。然而，不幸的是，这对 session 变量没有帮助(假设“ session 变量”是指具有 session 范围的包变量)。

创建包和表:

CREATE TABLE foo( col1 NUMBER );

create or replace package pkg_foo
as
  g_var number;
  procedure set_var( p_in number );
end;

create or replace package body pkg_foo
as
  procedure set_var( p_in number )
  as
  begin
    g_var := p_in;
  end;
end;

在 session 1 中，我们启动一个全局事务，设置包变量，并在暂停全局事务之前向表中插入一行(这允许另一个 session 恢复它)

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4  begin
  5    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmnoflags );
  6    pkg_foo.set_var(42);
  7    dbms_output.put_line( 'Set pkg_foo.g_var to ' || pkg_foo.g_var );
  8    insert into foo values( 42 );
  9    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuspend );
 10* end;
SQL> /
Set pkg_foo.g_var to 42

PL/SQL procedure successfully completed.

在 session 2 中，我们恢复全局事务，从表中读取，读取 session 变量，然后结束全局事务。请注意，对表的查询会看到我们插入的行，但包变量更改不可见。

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4    l_col1 integer;
  5  begin
  6    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmresume );
  7    dbms_output.put_line( 'Read pkg_foo.g_var as ' || pkg_foo.g_var );
  8    select col1 into l_col1 from foo;
  9    dbms_output.put_line( 'Read COL1 from FOO as ' || l_col1 );
 10    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuccess );
 11* end;
SQL> /
Read pkg_foo.g_var as
Read COL1 from FOO as 42

PL/SQL procedure successfully completed.

要在 session 之间共享 session 状态，是否可以使用 global application context而不是使用包变量？如果您想同时读取数据库表和 session 状态，可以将它与 DBMS_XA 包结合使用。

使用 getter 和 setter 创建上下文和包

CREATE CONTEXT my_context
  USING pkg_foo
  ACCESSED GLOBALLY;

create or replace package pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number );
  function get_var( p_session_id in number )
    return number;
end;

create or replace package body pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number )
  as
  begin
    dbms_session.set_identifier( p_session_id );
    dbms_session.set_context( 'MY_CONTEXT', 'G_VAR', p_in, null, p_session_id );
  end;
  function get_var( p_session_id in number )
    return number
  is
  begin
    dbms_session.set_identifier( p_session_id );
    return sys_context('MY_CONTEXT', 'G_VAR');
  end;
end;

在 session 1 中，将 session 12345 的上下文变量 G_VAR 的值设置为 47

begin
  pkg_foo.set_var( 12345, 47 );
end;

现在， session 2 可以从上下文中读取值

  1* select pkg_foo.get_var( 12345 ) from dual
SQL> /

PKG_FOO.GET_VAR(12345)
----------------------
                    47

关于c++ - 我可以从两个 oci 客户端维护一个 Oracle session 吗？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/9602801/