我有一些 XML 如下；

<risk>
  <driver driverId="2">
    <vehicleUse>M</vehicleUse>
  </driver>
  <driver driverId="3">
    <vehicleUse>F</vehicleUse>
  </driver>
  <driver driverId="4">
    <vehicleUse>I</vehicleUse>
  </driver>
</risk>

我正在使用 XSLT(v1.0，.NET 实现)将每个 vehicleUse 转换为一个数字，然后得到这些数字的总和。 vehicleUses 翻译为 M=3、F=2 和 I=1。一个额外的复杂性是，对于 ID 为 3 的驱动程序，这些值乘以 10，对于驱动程序 4 乘以 100。因此在上面的示例中，总数将为 3 + 20 + 100 = 123。

我在我的 XSLT 文件中定义了这样一个模板；

<xsl:template name="getVehicleUseScore">
  <xsl:param name="driverId" />
  <xsl:param name="vehicleUse" />
  <!-- Implementation left out for brevity -->
</xsl:template>

然后 XSLT 文件的其余部分调用模板；

<xsl:template match="risk">
  <vehicleUseScore>
    <xsl:for-each select="driver">
      <xsl:call-template name="getVehicleUseScore">
        <xsl:with-param name="driverId" select="@driverId" />
        <xsl:with-param name="vehicleUse" select="vehicleUse" />
      </xsl:call-template>
    </xsl:for-each>
  </vehicleUseScore>
</xsl:template>

<xsl:template match="/">
  <xsl:apply-templates />
</xsl:template>

结果是我得到的文本“320100”只是将 3、20 和 100 连接在一起，这至少证明 getVehicleUseScore 模板有效。

我想将 getVehicleUseScore 的结果传递给 sum() 函数，但我不知道如何传递。我尝试了以下；

<xsl:value-of select="sum(getVehicleUseScore(@driverId, vehicleUse))" />

但是 XSLT 编译器指出“getVehicleUseScore() 是一个未知的 XSLT 函数”。

有什么办法吗？

最佳答案

这是一个简短的 XSLT 1.0 方法来完成此操作:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

 <xsl:template match="risk">
  <vehicleUseScore>
   <xsl:variable name="vrtfResult">
        <xsl:for-each select="driver">
          <xsl:call-template name="getVehicleUseScore">
            <xsl:with-param name="pdriverId" select="@driverId" />
            <xsl:with-param name="pvehicleUse" select="vehicleUse" />
          </xsl:call-template>
        </xsl:for-each>
    </xsl:variable>

    <xsl:value-of select="sum(msxsl:node-set($vrtfResult)/*)"/>
  </vehicleUseScore>
 </xsl:template>

 <xsl:template name="getVehicleUseScore">
  <xsl:param name="pdriverId" />
  <xsl:param name="pvehicleUse" />
  <score>
   <xsl:variable name="vValue" select=
   "(($pvehicleUse='M')*3 + ($pvehicleUse='F')*2 + ($pvehicleUse='I')*1)"/>
   <xsl:variable name="vFactor" select=
   "1 +(9*($pdriverId=3)) + (99*($pdriverId=4))"/>

   <xsl:value-of select="$vValue*$vFactor"/>
  </score>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时:

<risk>
    <driver driverId="2">
        <vehicleUse>M</vehicleUse>
    </driver>
    <driver driverId="3">
        <vehicleUse>F</vehicleUse>
    </driver>
    <driver driverId="4">
        <vehicleUse>I</vehicleUse>
    </driver>
</risk>

产生了想要的、正确的结果:

<vehicleUseScore>123</vehicleUseScore>

解释:

当捕获变量中模板的输出时，此变量的类型为 RTF(结果树片段)，除非其内容包含任何节点(文本节点除外)，否则其内容无法通过 XPath 表达式导航。

为此，需要对该变量调用依赖于供应商的扩展函数 xxx:node-set()，以便将 RTF 转换为常规树。

这里我们还使用了这样一个事实，即每当在算术表达式中遇到 bool 值时，它都会被转换为数字，并且根据定义:

number(true()) = 1

和

number(false()) = 0

关于.net - 您如何在 XSLT 中对调用模板的结果求和？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/14530762/