Part1. Unity前向渲染的介绍

1.1 前向渲染的基本原理

前向渲染的主要特点是针对每个物体，对于每个光源都会分别进行一次光照计算，最后的颜色值是由所有光源的光照结果混合而成的，比如场景中有M个物体，N个光源，则渲染整个场景需要N × M个Pass，可以看到如果光源数目多，前向渲染的开销是非常巨大的

为了解决这个开销问题，选让引擎常常会限制在每个物体上进行逐像素光照的数目，Unity引擎也是这样做的

1.2 Unity中前向渲染的实现原理

Unity的前向渲染中，实现光照有三种方式：逐像素处理、逐顶点处理、球谐函数(SH)，它们的开销是依次递减的

Unity中，我们可以手动设置光照的重要度模式，有三种可选：Important, Not Important, Auto

设置为Important的光源，总是按照逐像素方式进行处理

设置为Not Important的光源，会按照逐顶点或者SH的方式处理

设置为Auto的光源，将由Unity根据光源对于物体的影响程度，对光源进行重要度排序，然后分配逐顶点、逐像素、SH方式的使用

1.3 Base Pass

前向渲染的Pass被分为两类：Base Pass 和 Additional Pass

Base Pass只会执行一次（如果定义了多个Bass Pass，也可能执行多次）

Bass Pass需要处理一个逐像素的平行光和其他所有逐顶点光源和SH光源，如果存在多个平行光，引擎会选择将最重要的平行光传递给Base Pass处理

环境光和自发光的实现也是在Base Pass中实现的，因为如果在Additional Pass中实现这些效果，由于Additional Pass是多次执行的，对于每个光源都会执行一次Additional Pass，这就会造成多个环境光和自发光的叠加，这是我们不希望看到的，而Base Pass只会执行一次，适用于处理环境光和自发光

Bass Pass是默认开启阴影的

1.4 Additional Pass

Additional Pass是多次执行的，对于每个光源都会执行一次Additional Pass

Additional Pass需要对其余所有的逐像素光源进行处理，即每个逐像素光源调用一次Additional Pass

Additional Pass默认不开启阴影，我们也可以使用#pragma multi_compile_fwdadd_fullshadows代替#pragma multi_compile_fwdadd编译指令来开启阴影

Additional Pass需要开启混合模式，因为每个逐顶点光源是依次计算的，我们不能直接覆盖上一次的计算颜色，而需要进行混合

Part2.代码实现一个典型的前向渲染Shader

Pass {
        // Pass for ambient light & first pixel light (directional light)
        Tags { "LightMode"="ForwardBase" }

        CGPROGRAM

        // 需要添加base pass的编译指令
        #pragma multi_compile_fwdbase	

        #pragma vertex vert
        #pragma fragment frag

        #include "Lighting.cginc"

在第一个Pass：Base Pass中，我们需要手动添加Base Pass的编译指令

v2f vert(a2v v) {
    v2f o;
    //将顶点位置从模型空间变换到裁剪空间
    o.pos = UnityObjectToClipPos(v.vertex);
    //将法线从模型空间变换到世界空间
    o.worldNormal = UnityObjectToWorldNormal(v.normal);
    //将顶点位置从模型空间变换到世界空间
    o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

    return o;
}

在Base Pass的顶点着色器，我们只需要做一些简单的工作，对顶点位置和法线进行空间变换

fixed4 frag(v2f i) : SV_Target {
    //法向量的归一化
    fixed3 worldNormal = normalize(i.worldNormal);
    //调用内置变量_WorldSpaceLightPos0
    //对于点光源，它可以获取当前正在处理的逐像素光源的位置
    //对于平行光的_WorldSpaceLightPos0代表了平行光方向
    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
    //调用内置变量UNITY_LIGHTMODEL_AMBIENT，获取环境光的颜色
    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
    //基于兰伯特模型计算漫反射项
    fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
    //通过世界空间下相机位置和顶点位置坐差，获得观察方向
    fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
    //计算半程向量，为Blinn-Phong模型计算高光项做准备
    fixed3 halfDir = normalize(worldLightDir + viewDir);
    //基于Blinn-Phong模型计算高光项
    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
    //手动设置衰减因子为1.0，代表不衰减
    fixed atten = 1.0;
    //叠加后返回颜色值
    return fixed4(ambient + (diffuse + specular) * atten, 1.0);
}

片元着色器实现了简单的兰伯特和Blinn-Phong模型光照，需要注意的点是Unity内置变量_WorldSpaceLightPos0的使用，对于点光源，该变量获取的是光源的世界空间位置，对于平行光，该变量获取的是世界空间下的光照方向，我们假设该shader的Base Pass只需要处理平行光，于是直接将_WorldSpaceLightPos0归一化即可获得光照方向

Pass {
    // 设置光照模式为ForwardAdd，代表这是一个Additional Pass
    Tags { "LightMode"="ForwardAdd" }
    //设置混合模式
    Blend One One

    CGPROGRAM

    // 需要添加Additional Pass的编译指令
    #pragma multi_compile_fwdadd

在下一个Pass：Additional Pass中，我们需要手动添加Additional Pass的编译指令，并手动设置混合模式，这里设置为Blend One One，代表不考虑透明度，进行1：1混合

v2f vert(a2v v) {
    v2f o;
    //将顶点位置从模型空间变换到裁剪空间
    o.pos = UnityObjectToClipPos(v.vertex);
    //将法线从模型空间变换到世界空间
    o.worldNormal = UnityObjectToWorldNormal(v.normal);
    //将顶点位置从模型空间变换到世界空间
    o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

    return o;
}

顶点着色器中的工作和Base Pass完全一致

fixed4 frag(v2f i) : SV_Target {
    fixed3 worldNormal = normalize(i.worldNormal);
    #ifdef USING_DIRECTIONAL_LIGHT  //判断是否正在处理平行光
        //平行光的_WorldSpaceLightPos0代表了平行光方向
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);  
    #else
        //其他光源（点光源、聚光灯）的_WorldSpaceLightPos0代表了光源所处的位置在世界空间下的坐标
        //光源世界坐标减去像素点世界坐标得到光照方向
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);    
    #endif

    fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

    fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
    fixed3 halfDir = normalize(worldLightDir + viewDir);
    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

    #ifdef USING_DIRECTIONAL_LIGHT
        fixed atten = 1.0;
    #else
        //将坐标变换到光源坐标系
        float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
        //使用坐标在光照材质上进行采样，得到衰减值
        fixed atten = tex2D(_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
    #endif

    return fixed4((diffuse + specular) * atten, 1.0);
}

在片元着色器中，我们需要处理其余所有的逐像素光照，它可能是平行光，也可能是点光源，我们希望能够对它们分别处理，所以需要用到条件判断语句#ifdef USING_DIRECTIONAL_LIGHT，它可以判断当前是否正在处理平行光

根据之前对于内置变量_WorldSpaceLightPos0的描述我们知道，对于点光源，_WorldSpaceLightPos0的含义是光源位置，所以为了获取光源方向，我们需要将光源位置和顶点位置坐差，而在平行光中则可直接通过_WorldSpaceLightPos0获取光源方向

我们还希望在光照衰减上对点光源和平行光进行分别处理，这同样需要依靠条件判断语句#ifdef USING_DIRECTIONAL_LIGHT

对于平行光，我们可以假设它不衰减，所以直接定义衰减因子为1.0

对于点光源，为了节省计算，我们不采用数学计算的方式来计算衰减因子，而是直接在一张光照材质上进行采样得到衰减因子

Part3.完整代码

Shader "Chapter 9/Forward Rendering" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		
		Pass {
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma multi_compile_fwdbase	
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
			 	fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
			 	fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
			 	fixed3 halfDir = normalize(worldLightDir + viewDir);
			 	fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				fixed atten = 1.0;
				return fixed4(ambient + (diffuse + specular) * atten, 1.0);
			}
			
			ENDCG
		}
	
		Pass {
			Tags { "LightMode"="ForwardAdd" }
			Blend One One
		
			CGPROGRAM
			
			#pragma multi_compile_fwdadd
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				#ifdef USING_DIRECTIONAL_LIGHT
					fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);  
				#else
					fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);    
				#endif
				
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
				
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				
				#ifdef USING_DIRECTIONAL_LIGHT
					fixed atten = 1.0;
				#else
					float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
					fixed atten = tex2D(_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
				#endif

				return fixed4((diffuse + specular) * atten, 1.0);
			}
			
			ENDCG
		}
	}
	FallBack "Specular"
}