所以我有这个子例程，我想从批处理文件中的另一个位置调用它。这些功能按预期工作，但出于某种原因我无法确定，提示希望用户输入两次内容，然后它才会接受任何内容。

例如，如果我输入“0”以返回上一个菜单，它会立即返回到提示符，我必须再次输入“0”才能真正返回上一个菜单(在其他地方)在我的主脚本中)。

我可以，比方说，输入“w”(或任何其他值)，然后第二次输入我真正想要使用的值，它最终会执行。

这让我抓狂。

:subfullbackup
cls

if exist "%current%\Backup\Full_Backup" (
  Echo  Backup folder already exists
  Echo.
  Echo  [o]  Overwrite local device files with existing local files
  Echo  [w]  Wipe current local backup and start fresh
  Echo.
  set /p choice=Select: 


  if %choice% == o (
    Echo.
    Echo  Depending on how much data you have,
    Echo  this could take a couple hours.
    Echo.
    Echo  Backing up...
    adb pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  -= BACKUP COMPLETE =-
    Pause
    Goto :backup
  )


  if %choice% == w (
    Echo.
    Echo  Removing all current local backup files in 'Full_Backup'
    rmdir /S /Q "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  Depending on how much data you have,
    Echo  this could take a couple hours.
    Echo.
    Echo  Backing up...
    adb pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  -= BACKUP COMPLETE =-
    Pause
    Goto :backup
  )


  if not %choice% == o goto subfullbackup
  if not %choice% == w goto subfullbackup
) else (
    Echo.
    Echo  Depending on how much data you have,
    Echo  this could take a couple hours.
    Echo.
    Echo  Backing up...
    adb pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  -= BACKUP COMPLETE =-
    Pause
    Goto :backup
)
Goto :eof

最佳答案

使用延迟扩展的批处理代码，在批处理脚本顶部使用命令 setlocal 启用，它另外创建所有环境变量的副本并记住当前目录以恢复变量列表，当前目录命令扩展的当前状态和 endlocal 上的延迟扩展或离开批处理:

@echo off
setlocal EnableDelayedExpansion
set "current=%CD%"

:FullBackup
cls

if exist "%current%\Backup\Full_Backup" (
  Echo  Backup folder already exists
  Echo.
  Echo  [o]  Overwrite local device files with existing local files
  Echo  [w]  Wipe current local backup and start fresh
  Echo.
  set "UserChoice="
  set /p "UserChoice=Select: "


  if /I "!UserChoice!" == "o" (
    Echo.
    Echo  Depending on how much data you have,
    Echo  this could take a couple hours.
    Echo.
    Echo  Backing up...
    adb.exe pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  -= BACKUP COMPLETE =-
    Pause
    Goto DoBackup
  )


  if /I "!UserChoice!" == "w" (
    Echo.
    Echo  Removing all current local backup files in 'Full_Backup'
    rmdir /S /Q "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  Depending on how much data you have,
    Echo  this could take a couple hours.
    Echo.
    Echo  Backing up...
    adb.exe pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  -= BACKUP COMPLETE =-
    Pause
    Goto DoBackup
  )

  goto FullBackup

) else (
    Echo.
    Echo  Depending on how much data you have,
    Echo  this could take a couple hours.
    Echo.
    Echo  Backing up...
    adb.exe pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
    Echo.
    Echo  -= BACKUP COMPLETE =-
    Pause
    Goto DoBackup
)
Goto :EOF

:DoBackup

但是您的批处理代码也可以在没有延迟扩展的情况下编写，并且可以更紧凑地避免重复的代码行:

@echo off
set "current=%CD%"

:FullBackup
cls

if exist "%current%\Backup\Full_Backup" goto PromptBackup

:OverwriteBackup
Echo.
Echo  Depending on how much data you have,
Echo  this could take a couple hours.
Echo.
Echo  Backing up...
adb.exe pull /sdcard/ "%current%\Backup\Full_Backup" >nul 2>&1
Echo.
Echo  -= BACKUP COMPLETE =-
Pause
Goto DoBackup

:PromptBackup
Echo  Backup folder already exists
Echo.
Echo  [o]  Overwrite local device files with existing local files
Echo  [w]  Wipe current local backup and start fresh
Echo.
set "UserChoice="
set /p "UserChoice=Select: "

if /I "%UserChoice%" == "o" goto OverwriteBackup

if /I not "%UserChoice%" == "w" goto FullBackup

Echo.
Echo  Removing all current local backup files in 'Full_Backup'
rmdir /S /Q "%current%\Backup\Full_Backup" >nul 2>&1
goto OverwriteBackup

:DoBackup

关于代码小改动的一些说明:

1. choice (SS64 文章)是一个标准的 Windows 命令。因此，建议避免 choice (Microsoft 文章)作为环境变量或标签的名称。 UserChoice(CamelCase 拼写更易于阅读)用于代替 choice。

2. backup (SS64文章)不是标准的Windows命令，而是标准的SQL命令。因此，还建议避免将 backup 作为环境变量或标签的名称。 DoBackup 用于代替上面的批处理代码。

3. 建议在提示用户之前为环境变量定义默认值。用户只需点击 RETURN 或 ENTER，在这种情况下，环境变量将保持其值。

   环境变量在提示用户之前通过 set "UserPoint=" 清除，因此当用户什么都不输入时该变量不存在。

   也可能是 set "UserPoint=o" 或 set "UserPoint=w" 来定义有效的默认值。

4. 将字符串与用户输入进行比较时，应始终使用双引号，以避免在用户未输入任何内容时因语法错误导致批处理退出。

   if %choice% == w ( 变为 if == w ( 当用户没有输入任何内容时这是一个语法错误并导致命令处理器中断批处理.

   if/I "%UserChoice%"== "w"( 变为 if/I ""== "w" 当用户在上面的代码中没有输入任何内容时这仍然是有效的批代码，因此可以进行处理。

   注意:用户现在可以通过输入“w”来中断批处理。
   但是这里可以预期用户在被要求输入 o 或 w 时不会输入 1 个或多个双引号。

5. 在将用户输入的字符串与预定义字符串进行比较时，如果比较的字符串中包含字母，建议进行不区分大小写的字符串比较。

   选项 /I 将字符串比较从区分大小写更改为不区分大小写。

   所以现在用户也可以输入 O 或 W 并且这被解释为 o 或 w。

关于windows - 批处理脚本提示需要多个条目，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/33977470/