通过以下方式:https://productforums.google.com/forum/#!topic/chrome/8XnSOnhLBzA

• 前往 http://ninite.com/chrome/获取他们的 chrome 安装程序(但这对我没有帮助，因为我需要在安装 Google Chrome 后最后打开一个特定的网站)

• 现在我正在尝试自己使用 Inno Setup，以确保我与 Ninite 几乎相同

• Inno Setup 与 Google Chrome 安装完成后，如何确保使用 Google Chrome 打开 www.stackoverflow.com？

这是我的 Inno Setup 代码，第 3 点没有正确执行:

1. 安装谷歌浏览器

2. 安装后执行 Google Chrome

3. 但是我如何告诉 Google Chrome - 执行第一个链接:www.stackoverflow.com？

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "My Program"
#define MyAppVersion "1.5"
#define MyAppPublisher "My Company, Inc."
#define MyAppURL "http://www.example.com/"
#define MyAppExeName "ChromeSetup (1).exe"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{FCF7940A-D96F-4A7A-9C69-C9DFE8BB308A}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
OutputDir=C:\Users\sun\Desktop\Nieuwe map
OutputBaseFilename=setup
Compression=lzma
SolidCompression=yes

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "C:\Program Files (x86)\Inno Setup 5\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\Users\sun\Downloads\ChromeSetup (1).exe"; DestDir: "{app}"; Flags: ignoreversion
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[Run]
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent

最佳答案

以下可能有效，因为我所指的注册表项在 official docs 中进行了描述对于 Chrome 安装程序。有一个注册表项直接包含到 chrome.exe 的路径。文件，因此恕我直言，这是获取 Chrome 应用程序的最佳选择。文件名。就是这把 key :

<root>\Software\Microsoft\Windows\CurrentVersion\App Paths\chrome.exe

哪里<root>是 HKEY_LOCAL_MACHINE或 HKEY_CURRENT_USER注册表根取决于 Chrome 是为当前用户安装还是为整个系统全局安装。

在以下脚本中，我不仅使用上述 key 来获取 Chrome 应用程序。文件名，但即使是为了确定是否安装了 Chrome:

[Files]
Source: "chrome_installer.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall

[Run]
Filename: "{tmp}\chrome_installer.exe"; Check: not IsChromeInstalled
Filename: "{code:GetChromeFileName}"; Parameters: "www.stackoverflow.com"; \
    Check: IsChromeInstalled

[Code]
const
  ChromeAppRegKey = 'Software\Microsoft\Windows\CurrentVersion\App Paths\chrome.exe';

function IsChromeInstalled: Boolean;
begin
  { check if there's the Chrome app registration entry under the HKCU, or }
  { HKLM root key, return the result }
  Result := RegKeyExists(HKEY_CURRENT_USER, ChromeAppRegKey) or
    RegKeyExists(HKEY_LOCAL_MACHINE, ChromeAppRegKey);
end;

function GetChromeFileName(Value: string): string;
var
  S: string;
begin
  { initialize returned value to an empty string }
  Result := '';
  { first attempt to read the Chrome app file name from the HKCU root key; }
  { if that fails, try to read the same from HKLM; if any of that succeed, }
  { return the obtained registry value }
  if RegQueryStringValue(HKEY_CURRENT_USER, ChromeAppRegKey, '', S) or
    RegQueryStringValue(HKEY_LOCAL_MACHINE, ChromeAppRegKey, '', S)
  then
    Result := S;
end;

关于windows - Inno Setup - 在执行 Google Chrome 时如何告诉安装，它应该打开 stackoverflow.com？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/22467996/