我正在使用 XSLT 2.0 从 XML 中提取数据。数据有很长的行，我想通过自动换行使它们适合窗口大小。

在 XSLT 中可以吗？

最佳答案

您可以使用标准 XSLT 2.0 函数 unparsed-text()直接在 XSLT 2.0 代码中读取文本文件。

然后就用:

replace(concat(normalize-space($text),' '),
                '(.{0,60}) ',
                '$1
')

解释:

这首先规范化空白，删除前导和尾随纯空白字符序列，并用单个空格替换任何内部此类序列。

然后规范化的结果用作标准 XPath 2.0 函数的第一个参数 replace() .

匹配模式是任何(最多 61 个字符的最长可能序列，以空格结尾。

替换参数指定找到的任何此类序列都应替换为结尾空格之前的字符串，并与 NL 字符连接。

这是一个完整的解决方案，从文件 C:\temp\delete\text.txt 中读取并格式化此文本:

Dec. 13 — As always for a presidential inaugural, security and surveillance were
extremely tight in Washington, DC, last January. But as George W. Bush prepared to
take the oath of office, security planners installed an extra layer of protection: a
prototype software system to detect a biological attack. The U.S. Department of
Defense, together with regional health and emergency-planning agencies, distributed
a special patient-query sheet to military clinics, civilian hospitals and even aid
stations along the parade route and at the inaugural balls. Software quickly
analyzed complaints of seven key symptoms — from rashes to sore throats — for
patterns that might indicate the early stages of a bio-attack. There was a brief
scare: the system noticed a surge in flulike symptoms at military clinics.
Thankfully, tests confirmed it was just that — the flu.

XSLT 代码:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output method="text"/>

 <xsl:variable name="vText" select=
 "unparsed-text('file:///c:/temp/delete/text.txt')"/>

 <xsl:template match="/">
  <xsl:sequence select=
   "replace(concat(normalize-space($vText),' '),
            '(.{0,60}) ',
            '$1&#xA;')
   "/>
 </xsl:template>
</xsl:stylesheet>

结果是一组行，每行不超过固定长度 60:

Dec. 13 — As always for a presidential inaugural, security
and surveillance were extremely tight in Washington, DC,
last January. But as George W. Bush prepared to take the
oath of office, security planners installed an extra layer
of protection: a prototype software system to detect a
biological attack. The U.S. Department of Defense, together
with regional health and emergency-planning agencies,
distributed a special patient-query sheet to military
clinics, civilian hospitals and even aid stations along the
parade route and at the inaugural balls. Software quickly
analyzed complaints of seven key symptoms — from rashes to
sore throats — for patterns that might indicate the early
stages of a bio-attack. There was a brief scare: the system
noticed a surge in flulike symptoms at military clinics.
Thankfully, tests confirmed it was just that — the flu.

更新:

如果文本来自 XML 文件，只需对上述解决方案进行最小更改即可完成此操作:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output method="text"/>

 <xsl:template match="/">
  <xsl:sequence select=
   "replace(concat(normalize-space(text),' '),
            '(.{0,60}) ',
            '$1&#xA;')
   "/>
 </xsl:template>
</xsl:stylesheet>

这里我假设所有文本都在 XML 文档的顶部元素(名为 text)的唯一文本节点子节点中:

<text>
Dec. 13 — As always for a presidential inaugural, security and surveillance were
extremely tight in Washington, DC, last January. But as George W. Bush prepared to
take the oath of office, security planners installed an extra layer of protection: a
prototype software system to detect a biological attack. The U.S. Department of
Defense, together with regional health and emergency-planning agencies, distributed
a special patient-query sheet to military clinics, civilian hospitals and even aid
stations along the parade route and at the inaugural balls. Software quickly
analyzed complaints of seven key symptoms — from rashes to sore throats — for
patterns that might indicate the early stages of a bio-attack. There was a brief
scare: the system noticed a surge in flulike symptoms at military clinics.
Thankfully, tests confirmed it was just that — the flu.
</text>

将此转换应用于上述 XML 文档时，会产生与第一个解决方案相同的结果。

关于xml - 如何在 XSLT 中包装文本以适应窗口，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/7850200/