你能帮我列出这个文件中的浏览器吗 http://techpatterns.com/downloads/firefox/useragentswitcher.xml 成 txt 文件，用 %tab% 分隔符分隔？

应该有 3 或 4 列:

1) 来自示例数据的文件夹描述:<folder description="Browsers - Windows">

2) 来自示例数据的浏览器类型:<folder description="Legacy Browsers">

3) 来自示例数据的用户代理:<useragent description="Avant Browser 1.2" useragent="Avant Browser/1.2.789rel1 (http://www.avantbrowser.com)" app

在这里我看到第一个问题，因为一些浏览器不在文件夹 <folder description="Legacy Browsers">" 中但在 <separator/> 下

所以第一列应该定义系统，第二列是类型，第三列是浏览器。

下一个问题是 Devises 文件夹中又包含一个文件夹。

@echo off 
Setlocal EnableDelayedExpansion
SET file=useragentswitcher.xml
SET delim="

FOR /F "tokens=* skip=1" %%F IN (!file!) DO (
  REM echo %%F
  call :parse "%%F" > temp.txt
  FOR /F "tokens=1,2,3,4,5,6,7 skip=1 delims=" %%A IN (temp.txt) DO (
    IF "%%A"=="folder" (
      SET /A level=!level!+1
      echo Level:!level!
      ) ELSE IF "%%A"=="/folder" (
          SET /A level=!level!-1
          echo Level:!level!
        )

   echo A:%%A
  )
  pause
)

exit /b

:parse
Setlocal EnableDelayedExpansion
  SET A=%*
  REM REMOVE double paranthesis and <> 
  SET A=!A:~2,-2!
  REM replace double qoutes
  SET A=!A:"=µ!
  FOR /F "tokens=1,2 delims=µ=" %%A IN ("!A!") DO (
    SET first=%%A
    SET second=%%B
    echo !first!
    FOR /F "tokens=1,2 delims= " %%A IN ("!first!") DO (
      echo %%A
      echo %%B
    )
    echo !second!
  )
endlocal
exit /b

这会解析该行的一个标记，我现在要使用它。

最佳答案

看来你应该能够找到比批处理更好的工具来解析 XML...

但我相信下面的代码就是您要找的。

由于文件夹数量不同，我交换了输出中列的顺序。我把浏览器描述放在第一位，然后是文件夹，每列一个。这允许固定每一列的定义。

我使用 jeb 的答案中的信息将 " 作为 FOR 分隔符。

编辑 - 我简化了代码

注意 - 第一次尝试是为了处理使用 Internet Explorer 检索的 XML 副本。我后来发现 IE 改变了文件的格式。此代码高度依赖于文件的确切格式，因此它不适用于原始 XML。它还作为一个例子说明为什么批处理是解析 XML 的糟糕选择

@echo off
setlocal enableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set "folder0="
>%output% (
  for /f usebackq^ tokens^=1^,2^ delims^=^=^" %%A in (%input%) do (
    for %%N in (!cnt!) do (
      if "%%A"=="- <folder description" (
        set /a cnt+=1
        for %%M in (!cnt!) do set "folder%%M=!folder%%N!%TAB%%%B"
      )
      if "%%A"=="  </folder>" (
        set /a cnt-=1
      )
      if "%%A"=="  <useragent description" (
        echo %%B!folder%%N!
      )
    )
  )
)

如果 ! 出现在任何描述中，代码将失败，因为延迟扩展会破坏任何包含 ! 的 FOR 变量的扩展。我检查过，您的文件在任何描述中都不包含 !。

可以修改代码以处理描述中的 !，但它会变得更复杂。它需要打开和关闭延迟扩展，并跨 ENDLOCAL 屏障保存变量值。

以上代码高度依赖于 XML 的格式。如果删除了非标准破折号，或者如果空白排列发生变化，它将失败。

下面的变体更健壮一些，但它仍然要求每一行只包含一个 XML 标记。

@echo off
setlocal enableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set "folder0="
>%output% (
  for /f usebackq^ tokens^=1^,2^ delims^=^=^" %%A in (%input%) do (
    for %%N in (!cnt!) do (
      set "test=%%A"
      if "!test:<folder description=!" neq "!test!" (
        set /a cnt+=1
        for %%M in (!cnt!) do set "folder%%M=!folder%%N!%TAB%%%B"
      )
      if "!test:</folder>=!" neq "!test!" (
        set /a cnt-=1
      )
      if "!test:<useragent description=!" neq "!test!" (
        echo %%B!folder%%N!
      )
    )
  )
)

编辑 - 最后一个版本

这是一个可以处理数据中的 ! 的版本。我在输出中添加了一个额外的列。第一列仍然是浏览器描述。第二列是用户代理字符串。其余列是文件夹。该解决方案使用延迟扩展切换技术。它还使用额外的 FOR/F 来保留跨 ENDLOCAL 屏障的变量值。

@echo off
setlocal disableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set folder0=""
>%output% (
  for /f usebackq^ tokens^=1-4^ delims^=^=^" %%A in (%input%) do (
    set "test=%%A"
    set "desc=%%B"
    set "agent=%%D"
    setlocal enableDelayedExpansion
    for %%N in (!cnt!) do (
      if "!test:<folder description=!" neq "!test!" (
        set /a cnt+=1
        for %%M in (!cnt!) do for /f "delims=" %%E in ("!folder%%N!") do (
          endlocal
          set "folder%%M=%%~E%TAB%%%B"
          set "cnt=%%M"
        )
      ) else if "!test:</folder>=!" neq "!test!" (
        endlocal
        set /a cnt-=1
      ) else if "!test:<useragent description=!" neq "!test!" (
        echo !desc!%TAB%!agent!!folder%%N!
        endlocal
      ) else endlocal
    )
  )
)

关于xml - 如何批量解析xml文件(CMD)，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/11014319/