我想我可以用一 block 石头打死两只鸟，然后通过将以下示例代码(取自 http://blog.smartbear.com/programming/an-introduction-to-the-go-language-boldly-going-where-no-man-has-ever-gone-before/)从 Go 转换为 Erlang，自学一点 Go 和 Erlang:

package main

import (
    "fmt"
    "time"
)

type Ball struct{ hits int }

func main() {
    table := make(chan *Ball)
    go player("ping", table)
    go player("pong", table)
    table <- new(Ball) // game on; toss the ball
    time.Sleep(1 * time.Second)
    <-table // game over; grab the ball
}

func player(name string, table chan *Ball) {
    for {
        ball := <-table
        ball.hits++
        fmt.Println(name, ball.hits)
        time.Sleep(100 * time.Millisecond)
        table <- ball
    }
}

但是我失败了。该代码基本上创建了一个共享计数器(球)并在两个 goroutine(玩家)之间来回发送它。到目前为止，一切都很好。但是我如何在 Erlang 中做类似的事情呢？我的问题是:

• 如何在 Erlang 中创建一个计数器？ Erlang 似乎不允许 设置变量后更改其值。
• 如何在两个 erlang 进程之间共享这样一个计数器？

最佳答案

变量在 erlang 中是不可变的，这意味着在一个函数的计算过程中，变量要么是未绑定(bind)的，要么设置为一个不能改变的值。但是您可以递归地从前一个函数中调用具有新值构建的相同函数。该值存储在通常称为状态的变量中，并在收到消息时修改。这是服务器的基本行为。

在您的示例中，您实际上并不需要一个变量来包含计数器，因为这个值将在 2 个玩家之间交换。 I 可以包含在它们之间交换的消息中，例如在元组 {count,V} 中。

2 个进程之间唯一的通信方式是消息传递。最简单的语法是 Pid ! Message，其中 Pid 是接收者的进程 ID，而 Message 是消息 :o)(如果进程已注册，Pid 可以用名称替换)。

你可以这样写:

-module(pingpong).
-export([start/0,player/1,stop/1]).

player(Name) ->
    receive
        {count,From,Val} -> 
            io:format("~p received the ball for the ~p th exchange~n",[Name,Val]),
            ok = timer:sleep(500),
            From ! {count,self(),Val+1},
            player(Name);
        {start,To} ->
            io:format("~p start the exchange~n",[Name]),
            To ! {count,self(),1},
            player(Name);
         stop -> gameover
     end.

start() ->
    Ping = spawn(?MODULE,player,[ping]),
    Pong = spawn(?MODULE,player,[pong]),
    Ping ! {start,Pong},
    {Ping,Pong}.

stop(P1) -> P1 ! stop. 

在外壳中:

1> c(pingpong).
{ok,pingpong}
2> {P1,P2} = pingpong:start().
ping start the exchange
pong received the ball for the 1 th exchange
{<0.39.0>,<0.40.0>}
ping received the ball for the 2 th exchange
pong received the ball for the 3 th exchange
ping received the ball for the 4 th exchange
pong received the ball for the 5 th exchange
ping received the ball for the 6 th exchange
pong received the ball for the 7 th exchange
ping received the ball for the 8 th exchange
pong received the ball for the 9 th exchange
ping received the ball for the 10 th exchange
pong received the ball for the 11 th exchange
ping received the ball for the 12 th exchange
pong received the ball for the 13 th exchange
ping received the ball for the 14 th exchange
pong received the ball for the 15 th exchange
ping received the ball for the 16 th exchange
pong received the ball for the 17 th exchange
ping received the ball for the 18 th exchange
pong received the ball for the 19 th exchange
ping received the ball for the 20 th exchange
pong received the ball for the 21 th exchange
ping received the ball for the 22 th exchange
pong received the ball for the 23 th exchange
ping received the ball for the 24 th exchange
3> pingpong:stop(P1).
stop
4> pingpong:stop(P2).
stop
5>

关于go - 如何将此示例代码从 Go 转换为 Erlang，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/26316005/