我正在尝试创建一个可以将其他文件拖放到其中的批处理文件。具体来说，我正在使用 ffmpeg编辑手持录音机制作的音频文件。问题是在使用带符号 (&) 的文件名时。即使在引用输入时， & 之后的任何内容都会被删除，但只有当文件被放到它上面时；如果在命令行上输入文件名，则脚本可以正常工作。在 cmd 窗口关闭之前，我短暂地看到了文件名的其余部分，并显示一条错误消息，指出它未被识别为有效命令。

这是我的脚本:

rem Change to drive and directory of input file
%~d1
cd %~p1

rem ffmpeg: mix to one channel, double the volume
%HOMEDRIVE%%HOMEPATH%\ffmpeg.exe -i "%~nx1" -ac 1 -vol 1024 "%~n1 fixed%~x1"

pause

这是在删除 "ch17&18.mp3" 之后出现在命令行上的内容:

C:\Users\computergeeksjw\Desktop>C:\Users\computergeeksjw\ffmpeg.exe -i "ch17" -ac 1 -vol 1024 "ch17 fixed"
[...]
ch17: No such file or directory

以防万一:我使用的是 Windows 8 Developer Preview。这是导致我的问题吗？在 Windows 7 或更早版本上是否出现相同的错误？

最佳答案

关于包含 & 的文件路径，Windows 拖放功能中存在一个长期存在的错误。或 ^但不包含 <space> .

如果一个文件路径至少包含一个<space> ，然后 Windows 会自动将路径括在引号中，以便正确解析。如果文件路径包含 &，Windows 应该做同样的事情。或 ^ , 但事实并非如此。

如果您创建以下简单的批处理文件并将文件拖到其中，您就会看到问题。

@echo off
setlocal enableDelayedExpansion
echo cmd=!cmdcmdline!
echo %%1="%~1"
pause
exit

!cmdcmdline!变量包含启动批处理文件的实际命令。 批处理文件打印出命令行和第一个参数。

如果你拖放一个名为“a.txt”的文件，你会得到

cmd=cmd /c ""C:\test\drag.bat" C:\test\a.txt"
%1=C:\test\a.txt
Press any key to continue . . .

如果忽略整个命令周围的引号，您会看到文件参数周围没有引号。没有特殊字符，所以没有问题。

现在拖放“a b.txt”你会得到

cmd=cmd /c ""C:\test\drag.bat" "C:\test\a b.txt""
%1="C:\test\a b.txt"
Press any key to continue . . .

您可以看到 Windows 如何检测名称中的空格并将文件括在引号中。再次没有问题。

现在拖放“a&b.txt”，你会得到

cmd=cmd /c ""C:\test\drag.bat" C:\test\a&b.txt"
%1=C:\test\a
Press any key to continue . . .

Windows 在名称中找不到空格，因此不会将其括在引号中。大问题! Windows 将“C:\test\a”传递给批处理文件，并将“b.txt”视为批处理文件完成后要执行的第二个文件。批处理文件中的硬 EXIT 命令可防止在批处理后执行任何拆分文件名。当然 b.txt 永远不会执行。但是如果文件名为“a&b.bat”并且存在“b.bat”，那么如果批处理文件中没有硬退出，那可能会很麻烦。

可以将多个文件拖到一个批处理文件中，每个文件都应作为参数传递。

!cmdcmdline!是可靠地访问拖放参数的唯一方法。但是，如果在对批处理文件的正常调用中将文件作为正常参数传递，那将不起作用。

下面是一个批处理文件，可以检测它是通过拖放调用还是通过普通调用调用的。 (它不是防弹的，但我认为它应该适用于大多数情况)它会处理每个文件参数，一次一个，不管调用类型如何。 (该过程只是简单地回显文件名，但您可以替换任何您想要的处理。)如果批处理是使用拖放调用的，那么它将执行硬退出以防止拆分文件名。

@echo off
setlocal disableDelayedExpansion
::
:: first assume normal call, get args from %*
set args=%*
set "dragDrop="
::
:: Now check if drag&drop situation by looking for %0 in !cmdcmdline!
:: if found then set drag&drop flag and get args from !cmdcmdline!
setlocal enableDelayedExpansion
set "cmd=!cmdcmdline!"
set "cmd2=!cmd:*%~f0=!"
if "!cmd2!" neq "!cmd!" (
  set dragDrop=1
  set "args=!cmd2:~0,-1! "
  set "args=!args:* =!"
)
::
:: Process the args
for %%F in (!args!) do (
  if "!!"=="" endlocal & set "dragDrop=%dragDrop%"
  rem ------------------------------------------------
  rem - Your file processing starts here.
  rem - Each file will be processed one at a time
  rem - The file path will be in %%F
  rem -
  echo Process file "%%~F"
  rem -
  rem - Your file processing ends here
  rem -------------------------------------------------
)
::
:: If drag&drop then must do a hard exit to prevent unwanted execution
:: of any split drag&drop filename argument
if defined dragDrop (
  pause
  exit
)

看起来您现有的批处理只能处理一个文件。我不知道您是否需要修改调用以支持多个文件。我将上面的批处理修改为只处理第一个参数，并将你的过程代入参数处理循环。这是未经测试的，但我认为它应该适合你。

@echo off
setlocal disableDelayedExpansion
::
:: first assume normal call, get args from %*
set args=%*
set "dragDrop="
::
:: Now check if drag&drop situation by looking for %0 in !cmdcmdline!
:: if found then set drag&drop flag and get args from !cmdcmdline!
setlocal enableDelayedExpansion
set "cmd=!cmdcmdline!"
set "cmd2=!cmd:*%~f0=!"
if "!cmd2!" neq "!cmd!" (
  set dragDrop=1
  set "args=!cmd2:~0,-1! "
  set "args=!args:* =!"
)
::
:: Process the first argument only
for %%F in (!args!) do (
  if "!!"=="" endlocal & set "dragDrop=%dragDrop%"
  rem ------------------------------------------------
  rem - Your file processing starts here.
  rem - Use %%F wherever you would normally use %1
  rem
  rem Change to drive and directory of input file
  %%~dF
  cd %%~pF
  rem ffmpeg: mix to one channel, double the volume
  %HOMEDRIVE%%HOMEPATH%\ffmpeg.exe -i "%%~nxF" -ac 1 -vol 1024 "%%~nF fixed%%~xF"
  rem
  rem - Your file processing ends here
  rem -------------------------------------------------
  goto :continue
)
:continue
if defined dragDrop (
  pause
  exit
)

关于windows - "Droplet"批处理脚本 - 包含符号的文件名，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/8547676/