1. 我必须访问一个 URL，使用凭据登录，然后选择一个区域名称并单击显示按钮，以便在 HTML 页面中显示最近的帐单(我使用 Selenium 脚本完成了所有这些操作)。

2. 该页面上有一个按钮打印选项。单击时会出现打印弹出窗口，我需要单击确定。但是我也无法使用 AutoIt 脚本来完成此操作。
   
   

3. 单击确定 完成后，“将打印输出另存为”窗口打开，我必须在其中输入文件名并单击保存.
   
   

这两个弹出窗口对于 Firefox 和 Chrome 是不同的。如何处理这些？我尝试使用 AutoIt 脚本并在 Selenium 脚本中使用 Runtime .exec(file name) 调用它，但这对我来说都不起作用。

WinWait("Print", "", 5000)

If WinExists("Print", "") Then
    Send("OK{ENTER}")
EndIf

Sleep(5000)
WinWait("Save Print Output As", "", 5000)

If WinExists("Save Print Output As", "") Then
    ControlFocus("Save Print Output As", "", "Edit1")
    Sleep(5000)
    ControlSetText("Save Print Output As", "", "Edit1", "H282")
    Sleep(5000)
    ControlClick("Save Print Output As", "", "Button2")
EndIf

另外，我需要针对不同的区域多次运行脚本，但它在第一次运行后停止执行。

“打印”和“另存为打印输出”弹出窗口的窗口信息工具摘要是-

AutoIt Window Info of Print pop-up

AutoIt Window Info of 'Save as Print Output' for the Field to Enter File Name

AutoIt Window Info of 'Save as Print Output' for the Save Field

问题 selenium 代码执行良好，当单击打印选项然后处理打印窗口时，调用 .exe 文件并开始在后台运行。但不起作用。一旦打印窗口打开，执行就会停止。

Now the New pop-up is seen , when file name is entered in 'Edit1" for each different file name

最佳答案

Opt("TrayIconDebug", True)

; String in filename to replace with an incremented integer.
$sTag = "++1"

; Show custom progress window (True|False).
$bEnableProgress = True

Switch $CMDLINE[0]
    Case 0
        Exit

    Case 1
        If $CMDLINE[1] = '/?' Then
            ; Help message.
            _HelpMsg()
            Exit
        Else
            ; Assign default command line array.
            $aFilenames = $CMDLINE
        EndIf

    Case 2
        ; If not $sTag in the 1st argument, then goto the next case.
        If Not StringInStr($CMDLINE[1], $sTag) Then ContinueCase

        ; If the 2nd argument is not an integer, then goto the next case.
        If Not StringIsInt($CMDLINE[2]) Then ContinueCase

        ; Create array with filenames starting from index 1.
        Global $aFilenames[$CMDLINE[2] + 1]

        $aFilenames[0] = Int($CMDLINE[2])

        ; Find first filepath that does not exist and set an offset.
        $iOffset = 0

        For $i1 = 1 To 1000
            If Not FileExists(StringReplace($CMDLINE[1], $sTag, $i1, -1)) Then
                $iOffset = $i1 - 1
                ExitLoop
            EndIf
        Next

        ; Assign the array with filenames, replacing tag with an integer.
        For $i1 = 1 To $aFilenames[0]
            $aFilenames[$i1] = StringReplace($CMDLINE[1], $sTag, $i1 + $iOffset, -1)
        Next

    Case Else
        ; Assign default command line array.
        $aFilenames = $CMDLINE
EndSwitch

If $bEnableProgress Then
    ProgressOn(@ScriptName, 'SaveAs')
EndIf

For $i1 = 1 To $aFilenames[0]
    ; Filename to save as.
    $sSaveAsFilename = $aFilenames[$i1]

    ; Print window.
    $hPrint = WinWait("Print")
    ControlClick($hPrint, "", "OK")

    ; Progress window.
    $hProgress = WinWait("Printing")

    ; Save As window.
    $hSaveAs = WinWait("Save Print Output As")

    Do
        Sleep(500)
        ControlSetText($hSaveAs, "", "Edit1", $sSaveAsFilename)
    Until ControlGetText($hSaveAs, "", "Edit1") = $sSaveAsFilename

    Sleep(500)

    If $bEnableProgress Then
        ProgressSet(100 / $aFilenames[0] * $i1, $sSaveAsFilename)
    EndIf

    ControlClick($hSaveAs, "", "Button2")
    AdlibRegister("_ConfirmSaveAs")
    WinWaitClose($hSaveAs)
    AdlibUnRegister("_ConfirmSaveAs")

    ; Wait for the progress window to close.
    WinWaitClose($hProgress)
Next

If $bEnableProgress Then ProgressOff()

Exit

Func _ConfirmSaveAs()
    ; Handle possible msgbox to confirm overwrite.
    If WinExists("Confirm Save As") Then
        ControlClick("Confirm Save As", "", "&Yes")
    EndIf
EndFunc

Func _HelpMsg()
    ; Help message.
    MsgBox(0, @ScriptName, _
     "Automates the standard print dialog from a web browser." & @CRLF & _
     @CRLF & _
     "Syntax:" & @CRLF & _
     "  " & @ScriptName & " filepath [filepath] ..." & @CRLF & _
     "  " & @ScriptName & " filepath integer" & @CRLF & _
     @CRLF & _
     "1st syntax can pass 1 or more filepath arguments." & @CRLF & _
     @CRLF & _
     "2nd syntax replaces the tag " & $sTag & " from right side of the " & _
     "1st argument with an incremented integer (starting from 1). " & _
     "Example: test" & $sTag & ".pdf will start with test1.pdf and end " & _
     "with testN.pdf (which N is the integer set by the 2nd argument)." & @CRLF & _
     @CRLF & _
     "Tested with Firefox 63 on Windows 10.")
EndFunc

文件名|文件路径可以作为参数传递。 如果要另存为 1 个文件名，请使用:

scriptname.exe "C:\SaveFolder\a.pdf"

你也可以在同一次执行中做很多，即:

scriptname.exe "C:\SaveFolder\a.pdf" "C:\SaveFolder\b.pdf" ...

如果你想用一个整数递增文件名，那么即:

scriptname.exe "C:\SaveFolder\a++1.pdf" 3

which ++1 将被替换为一个整数，并将被处理为:

scriptname.exe "C:\SaveFolder\a1.pdf" "C:\SaveFolder\a2.pdf" "C:\SaveFolder\a3.pdf"

第一个参数必须包含字符串 ++1 和 第二个参数必须是要识别的整数 作为要递增的基本文件名。

Help Msgbox 可以通过使用 /? 作为唯一的参数来显示。

同一执行中的许多参数可能不适合控制 在您的 Selenium 脚本中，尽管它是一个选项。

这些窗口是标准的打印对话框所以不同 Chrome 和 Firefox 之间可能没有。 如果您从 即记事本，因此不能将窗口视为标准窗口。

将 $sSaveAsFilename 设置为将要设置的值 进入“文件名:”的编辑控件，在标题为 “将打印输出另存为”。

Opt 参数会显示当前 当鼠标光标悬停在系统托盘中时 图标。 因此，如果它停滞不前，那么您可以追踪它是否被困住了。 这是一个可选的函数调用。

这是在 Windows 10 虚拟机中测试的 使用 Firefox 63。 window 看起来很慢 在显示上，这就是为什么检查 Edit1 正确的字符串，然后再继续。替代 是使用Opt()和参数WinWaitDelay 大约 1000 在窗口显示后暂停， 尽管脚本平均需要更长的时间才能完成。

我添加了一个 AdlibRegister 函数用于重复 测试并且可能仍然有用，因为文件名可能 不知不觉中存在，需要处理。

主要等待“打印”窗口， 只是为了阻止脚本在 打印进度完成。 如果不需要，则删除相关代码。

关于windows - 如何处理 print- 和 "Save Print output as"浏览器窗口？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/52625757/