我正在尝试使用 iExpress 在我在 NodeJS 上创建的小脚本上安装依赖项。

iExpress 包只安装包 Node :

msiexec /i node.msi

然后运行安装后批处理将 Javascript 放入 %UserProfile% 文件夹中的文件夹中。

安装后批处理运行: cmd /c post_install.bat

批处理中有一行不工作:

npm install <dependency>

这似乎不会在 MSI 安装后立即起作用，但它会在第二次运行 .exe 并安装 NodeJS 时起作用。

因此，无论出于何种原因，MSI 直到批处理完成后才设置 PATH 变量，或者 iExpress 安装后批处理未设置正确的环境变量。

有没有其他人遇到过这个问题，是否有解决方法或建议？

是否应该将 MSI 的安装和 NPM 的运行放在安装脚本中而不是使用 Post Install？

最佳答案

What is the reason for '...' is not recognized as an internal or external command, operable program or batch file? 上的答案解释了 system 和 user 环境变量存储在 Windows 注册表中的位置以及如何对它们进行更新。它还解释了没有进程可以修改已运行进程的环境变量，并且每个新进程都继承其父进程的当前环境变量列表。

因此，在启动 IExpress 安装过程时，此安装过程从其父进程(通常是 Windows 资源管理器，但也可以是 www 浏览器或任何其他应用程序)继承环境变量。

IExpress 安装过程运行 msiexec/i node.msi 安装 Node.js 并且很可能添加或修改 system Windows 注册表中的 或 user 环境变量。但是那些对整个机器和当前用户的持久存储环境变量的修改不会自动接管到已经运行的IExpress安装过程的本地环境变量列表。

接下来由 IExpress 安装过程开始，这是一个使用命令行 cmd/c post_install.bat 的命令过程，它由 Windows 获取当前设置的环境变量的新副本要使用的 IExpress 安装过程。

因此，无论 Node.js 安装过程在 Windows 注册表中修改了持久存储的系统 和用户 环境变量还是 MSIEXEC 进程的本地 环境变量对于执行批处理文件 post_install.bat 的 Windows 命令进程不可见。

但是 post_install.bat 执行的 npm 批处理文件依赖于在 Node.js 安装过程中存储在 Windows 注册表中的环境变量。因此，在执行 npm 之前，有必要使用 system 和 user 环境变量(按此顺序)更新 local 环境变量 批处理文件。

这可以通过使用以下注释代码扩展 post_install.bat 来完成:

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Set current directory to user's profile directory.
cd /D "%UserProfile%"

rem Make sure the environment variables used to build local PATH from
rem the PATH environment variables currently stored in Windows registry
rem do not already exist with unwanted values.
set "LocalPath="
set "SystemPath="
set "UserPath="

rem Get all system environment variables as currently stored in Windows
rem registry and set them in local environment with exception of system PATH.
for /F "skip=2 tokens=1,2*" %%A in ('%SystemRoot%\System32\reg.exe query "HKLM\System\CurrentControlSet\Control\Session Manager\Environment" 2^>nul') do (
    if /I "%%A" == "Path" (
        set "SystemPath=%%C"
    ) else if /I "%%B" == "REG_SZ" (
        set "%%A=%%C"
    ) else if /I "%%B" == "REG_EXPAND_SZ" (
        call set "%%A=%%C"
    )
)

rem Get all user environment variables as currently stored in Windows
rem registry and set them in local environment with exception of user PATH.
for /F "skip=2 tokens=1,2*" %%A in ('%SystemRoot%\System32\reg.exe query "HKEY_CURRENT_USER\Environment" 2^>nul') do (
    if /I "%%A" == "Path" (
        set "UserPath=%%C"
    ) else if /I "%%B" == "REG_SZ" (
        set "%%A=%%C"
    ) else if /I "%%B" == "REG_EXPAND_SZ" (
        call set "%%A=%%C"
    )
)

rem PATH can contain references to environment variables which can be
rem expanded only after having all environment variables except system
rem and user PATH already set in local environment. Now it is possible
rem to expand the environment variable references in system and user
rem PATH and concatenate them two one PATH set in local environment
rem replacing PATH as inherited from process starting this batch file.

if not defined SystemPath goto ProcessUserPath
call set "LocalPath=%SystemPath%"
if not "%LocalPath:~-1%" == ";" set "LocalPath=%LocalPath%;"

:ProcessUserPath
if not defined UserPath goto SetLocalPath
call set "LocalPath=%LocalPath%%UserPath%"

:SetLocalPath
if not defined LocalPath goto DoInstall
if "%LocalPath:~-1%" == ";" set "LocalPath=%LocalPath:~0,-1%"
if defined LocalPath set "PATH=%LocalPath%"

:DoInstall
rem Call NPM in its own environment inherited from current local environment.
rem Then discard all modifications made by NPM batch file on its own local
rem environment and restore the environment this batch file has set before.
setlocal
call npm.cmd install ...
endlocal

rem Insert here other post installation commands.


rem Restore previous environment on starting this batch file which means
rem discarding all modifications made on local list of environment variables
rem and restoring initial current directory before modification by CD at top
rem and restoring initial status of command extensions and delayed expansion.
endlocal

此批处理文件读取当前存储在 Windows 注册表中的系统 和用户 环境变量，并更新本地 环境变量，包括本地 PATH 甚至可以在 Windows XP/Windows Server 2003 上运行，尽管 REG 在 Windows XP/Server 2003 上的输出与 Windows Vista/Server 2008 和所有系统上的不同更高版本的 Windows。

要了解使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读为每个命令显示的所有帮助页面。

• 调用/?
• cd/?
• echo/?
• endlocal/?
• for/?
• 如果/?
• reg/?
• reg查询/?
• rem/?
• 设置/?
• setlocal/?

关于node.js - 带有 NodeJS 的 IExpress 安装后批处理没有立即找到 NPM，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/51867784/