我有一个文件夹区域，每个文件夹有数百个文档，结构如下:

C:\myLibrary\Accident Investigation Report
C:\myLibrary\Address Change
C:\myLibrary\Medical Certificate
C:\myLibrary\New Starter

这些文件夹中的文档命名如下例(基于日期戳、时间戳、部门编号、报告类型、员工姓名)。

2013-06-06 16-28-59 165 Accident Investigation Report - J Bloggs.xml
2013-06-06 16-28-59 165 Accident Investigation Report - J Bloggs.pdf

2013-06-11 15-38-07 147 Address Change - L Test.xml
2013-06-11 15-38-07 147 Address Change - L Test.pdf

等等

(每个都在自己明显的标题文件夹中)

确定文件来自哪个部门编号(重要位)是日期戳和时间戳后的数字 - 在上面的示例中分别为 165 和 147。

我想根据部门编号将所有文件移动到另一个设置的文件夹结构(已经创建)(每个部门都有另一个类似的结构，如下所示)；

C:\Dept Structure\165man\Accident Investigation Report
C:\Dept Structure\165man\Address Change

等等

因此，在批处理文件运行后，就像上面的示例文件一样，我应该结束；

C:\Dept Structure\165man\Accident Investigation Report\2013-06-06 16-28-59 165 Accident Investigation Report - J Bloggs.pdf
C:\Dept Structure\165man\Accident Investigation Report\2013-06-06 16-28-59 165 Accident Investigation Report - J Bloggs.xml
C:\Dept Structure\165man\Address Change\2013-06-06 16-28-59 165 Address Change - J Bloggs.pdf
C:\Dept Structure\165man\Address Change\2013-06-06 16-28-59 165 Address Change - J Bloggs.xml

C:\Dept Structure\147man\Accident Investigation Report\2013-06-11 15-38-07 147 Accident Investigation Report - L Test.pdf
C:\Dept Structure\147man\Accident Investigation Report\2013-06-11 15-38-07 147 Accident Investigation Report - L Test.xml
C:\Dept Structure\147man\Address Change\2013-06-11 15-38-07 147 Address Change - L Test.pdf
C:\Dept Structure\147man\Address Change\2013-06-11 15-38-07 147 Address Change - L Test.xml

我有一个文本文件，其中包含所有部门经理的编号，例如

003man
004man
005man
006man
007man
008man
009man
etc
etc
410man

由此我想遍历文本文件，根据前 3 位数字创建一个变量，添加“事故”或到此变量的末尾，检查第一个“C:\myLibrary\Accident Investigation Report”文件夹，找到标题中带有该变量的任何文件，并将其移动到如上命名的“部门结构”目录 - 呸!!

我设法找到了一些“几乎”完成此任务的脚本，看起来非常简单；

`cd /D "C:\Test"`

`for /F %%i in (C:\Dept.txt) do set str1=%%i`

`set _dept=%str1%`
`set _dept=%_dept:~0,3%`
`set "str2=%_dept%`

`move "????????????????????%str2%*.*" "C:\Dept Structure\%str1%\Accident Investigation Report"`

它确实将一些文件移动到正确的位置，但是，这似乎贯穿整个文本文件并且只处理最后一行!因此，所有其他行都保持不变，其余文件不会移动。

最佳答案

测试这个 - 顶部创建测试文件和文件夹。然后它会按照您希望的方式移动文件。

@echo off
md "c:\mylibrary2\Accident Investigation Report\" 2>nul
md "c:\mylibrary2\Address Change\" 2>nul
type nul > "c:\mylibrary2\Accident Investigation Report\2013-06-06 16-28-59 165 Accident Investigation Report - J Bloggs.pdf"
type nul > "c:\mylibrary2\Accident Investigation Report\2013-06-06 16-28-59 165 Accident Investigation Report - J Bloggs.xml"
type nul > "c:\mylibrary2\Address Change\2013-06-06 16-28-59 165 Address Change - J Bloggs.pdf"
type nul > "c:\mylibrary2\Address Change\2013-06-06 16-28-59 165 Address Change - J Bloggs.xml"
type nul > "c:\mylibrary2\Accident Investigation Report\2013-06-11 15-38-07 147 Accident Investigation Report - L Test.pdf"
type nul > "c:\mylibrary2\Accident Investigation Report\2013-06-11 15-38-07 147 Accident Investigation Report - L Test.xml"
type nul > "c:\mylibrary2\Address Change\2013-06-11 15-38-07 147 Address Change - L Test.pdf"
type nul > "c:\mylibrary2\Address Change\2013-06-11 15-38-07 147 Address Change - L Test.xml"



for /f "delims=" %%a in ('dir "c:\mylibrary2" /a-d /b /s') do (
for /f "tokens=3" %%b in ("%%~nxa") do (
for /f "delims=" %%c in ("%%~dpa\.") do (
md "C:\Dept Structure2\%%bman\%%~nxc\" 2>nul
move "%%a" "C:\Dept Structure2\%%bman\%%~nxc\" >nul
)
)
)

关于windows - 批处理文件循环遍历文本文件的内容，创建变量并移动具有部分名称的文件，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/17048349/