我正在创建一个摘要审计文件，我正在扫描的其中一个文件有 300-1000 多页。我试图提取到此审计文件中的信息始终是最后 3 页左右。

因此，虽然我对 findstr 或 find 函数有点熟悉，但我不知道如何在找到该信息后返回所有内容。帮忙？

使用该逻辑，那么我如何在余额报告之后获得所有内容？

FINDSTR /l "BALANCE REPORT" EXAMPLE.REPORT 1>NUL 2>&1 && (
ECHO WHAT DO I PUT HERE??? >> NightlyAudit.txt
) || (
ECHO No Balance Report Found! >> NightlyAudit.txt
)

最佳答案

我认为您的 FINDSTR 搜索可能不正确 - "BALANCE REPORT" 将匹配任何包含 BALANCE 或 REPORT 的行。我怀疑您想匹配文字字符串 BALANCE REPORT，在这种情况下您需要使用 /c:"BALANCE REPORT"。

您可以添加/N 选项以获取匹配的行号，使用 FOR/F 解析出该值，然后使用带有 +n 的 MORE 来跳过适当的行数。

以下将写出匹配行之后的所有行

@echo off
setlocal
set "skip="
for /f "delims=:" %%N in (
  'findstr /nlc:"BALANCE REPORT" example.report'
) do if not defined skip set skip=%%N
if not defined skip (
  echo BALANCE REPORT not found
  exit /b 1
)
more +%skip% example.report >NightlyAudit.txt

如果要在输出中包含匹配行，则必须减去一个。如果第一行恰好匹配，那么您不想跳过任何行，但 MORE 不允许 +0，因此逻辑需要的不仅仅是简单地减 1。

@echo off
setlocal
set "skip="
for /f "delims=:" %%N in (
  'findstr /nlc:"BALANCE REPORT" example.report'
) do if not defined skip set skip=%%N
if not defined skip (
  echo BALANCE REPORT not found
  exit /b 1
)
set /a skip-=1
if %skip% equ 0 (
  set "skip="
) else (
  set "skip=+%skip%"
)
more %skip% example.report >NightlyAudit.txt

请注意，MORE 会将任何 [Tab] 字符转换为一系列空格。还有另外一个潜在问题。我不确定 MORE 是否可以跳过超过 64k 行，如果您的源文件有 1000 页，每页 60 行，那么您可能已经接近极限了。

所以 MORE 可能不适合您，在这种情况下您需要一个替代方案。这是一种使用纯批处理的方法，但速度相对较慢，并且每行限制为 ~8190 字节。

将以下内容替换为 MORE 命令以打印匹配后的所有行:

...
>NightlyAudit.txt (
  for /f "skip=%skip% delims=" %%A in ('findstr /n "^" example.report') do (
    set "ln=%%A"
    setlocal enableDelayedExpansion
    echo(!ln:*:=!
    endlocal
  )
)

如果您想要包含匹配行，则 SKIP 变量的计算会稍微改变，FOR/F 选项也是如此。 FOR/F 也不允许 skip=0，但语法与 MORE 有点不同。

...
set /a skip-=1
if %skip% equ 0 (
  set "skip="
) else (
  set "skip=skip=%skip%"
)
>NightlyAudit.txt (
  for /f "%skip% delims=" %%A in ('findstr /n "^" example.report') do (
  ...

如果您使用其他脚本语言，只需读取一次输入即可轻松实现您的目标。例如，您可以将 JScript 与 CSCRIPT 结合使用。

例如，下面可以用来写匹配后的所有行:

writeAfterMatch.js

var str, go=0;
while (!WScript.StdIn.AtEndOfStream) {
  str=WScript.StdIn.ReadLine();
  if (go) WScript.StdOut.WriteLine(str);
  if (!go) if (str.indexOf(WScript.Arguments(0))>0) go=1;
}

用法

cscript //nologo writeAfterMatch.js "BALANCE REPORT" <example.report >NightlyAudit.txt

只需颠倒几行的顺序，您就可以包含匹配的行:

writeAfterMatchInclusive.js

var str, go=0;
while (!WScript.StdIn.AtEndOfStream) {
  str=WScript.StdIn.ReadLine();
  if (!go) if (str.indexOf(WScript.Arguments(0))>0) go=1;
  if (go) WScript.StdOut.WriteLine(str);
}

用法

cscript //nologo writeAfterMatchInclusive.js "BALANCE REPORT" <example.report >NightlyAudit.txt

另一种选择是使用我的 JREPL.BAT text processing utility用最少的代码解决问题。 JREPL 是纯脚本(混合 JScript/批处理)，可以在从 XP 开始的任何 Windows 机器上本地运行。通过从命令行发出 JREPL/?? 可以获得完整的文档。

它可能看起来令人生畏，因为有太多选择。但解决方案其实很简单。

下面的一行将写出匹配之后的所有行

jrepl "BALANCE REPORT" "go++;$0" /l /j /jendln "if(go<2)$txt=false;if(go)go++" /jbeg "go=0" /f example.report /o NightlyAudit.txt

这个更简单的变体将包括匹配行:

jrepl "BALANCE REPORT" "go=1;$0" /l /j /jendln "if(!go)$txt=false" /jbeg "go=0" /f example.report /o NightlyAudit.txt

如果您在自己的批处理脚本中使用 JREPL 命令，则需要使用 CALL JREPL。

关于Windows 批处理脚本 - 查找字符串并回显之后的所有内容，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/39617679/