我是 xslt 的新手，我试图处理嵌套无序或有序列表项的情况 例如:

*  Dresses
          # Formal
                -  Men
                -  Women
                - Children
          # Casual
     *  FootWear
     *  Other Accessories

基本上，列表项是相互嵌套的，但我们可以将它们嵌套得尽可能深。你能给我一个关于如何实现这一目标的总体思路吗..

Edith 说:感谢您的快速回复。这是我的 xml:

<?xml version="1.0" encoding="utf-8"?>
<emailmessage>
    <ul>
        <li>Dresses</li>
        <ul>
            <li>Professional</li>
            <ul>
                <li>Mens</li>
                <li>Womens</li>
            </ul>
            <li>Causual </li>
        </ul>
        <li>FootWear</li>
        <li>Other Accessories</li>
    </ul>
</emailmessage>

这是我的 html 类型的 xml，格式是我想以纯文本形式获得的格式，即

• 一个标签和*如果它是 <li>没有任何祖先
• 两个标签和#如果它是第一个的子列表，即具有一个祖先的子列表
• 三个选项卡 -如果它的子列表的子列表即有两个祖先。

格式重复..

* Dresses
    # Formal
        - Men
        - Women
        - Children
    # Casual
* FootWear
* Other Accessories

最佳答案

此转换适用于任何级别的嵌套，最多 20:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vIndent"
  select="'&#10;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;&#9;'"/>

 <xsl:template match="li">
  <xsl:value-of select=
   "concat(substring($vIndent,1, count(ancestor::ul)+1),.)"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时:

<emailmessage>
    <ul>
        <li>* Dresses</li>
        <ul>
            <li># Professional</li>
            <ul>
                <li>- Mens</li>
                <li>- Womens</li>
            </ul>
            <li># Causual </li>
        </ul>
        <li>* FootWear</li>
        <li>* Other Accessories</li>
    </ul>
</emailmessage>

产生想要的、正确的结果:

* Dresses
    # Professional
        - Mens
        - Womens
    # Causual 
* FootWear
* Other Accessories

更新:无限嵌套:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="li">
  <xsl:text>&#10;</xsl:text>
  <xsl:for-each select="ancestor::ul"><xsl:text>&#9;</xsl:text></xsl:for-each>
  <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

更新 2:OP 指出 XML 文档中不存在标记字符(*、* 和 -)。这是适用于无限嵌套的解决方案:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vDelims" select="'- * # '"/>

 <xsl:template match="li">
  <xsl:text>&#10;</xsl:text>
  <xsl:for-each select="ancestor::ul"><xsl:text>&#9;</xsl:text></xsl:for-each>
  <xsl:value-of select=
   "substring($vDelims,
              2*(1+count(ancestor::ul) mod 3) -1,
              2)"/>
  <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时(如上所述，但删除了项目符号):

<emailmessage>
    <ul>
        <li>Dresses</li>
        <ul>
            <li>Professional</li>
            <ul>
                <li>Mens</li>
                <li>Womens</li>
            </ul>
            <li>Causual </li>
        </ul>
        <li>FootWear</li>
        <li>Other Accessories</li>
    </ul>
</emailmessage>

产生了相同的、想要的和正确的结果:

* Dresses
    # Professional
        - Mens
        - Womens
    # Causual 
* FootWear
* Other Accessories

关于html - XSLT 嵌套列表项，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/7222481/