我正在尝试生成 Ninja makefile 以使用 Clang 为 ARM Cortex A5 CPU 交叉编译 C++ 项目。我为 CMake 创建了一个工具链文件，但似乎有错误或缺少我找不到的东西。当使用下面的工具链文件调用 CMake 时，出现以下错误。

CMake 命令:

cmake -DCMAKE_TOOLCHAIN_FILE="..\Src\Build\Toolchain-clang-arm.cmake" -GNinja ..\Src\

输出:

-- The C compiler identification is Clang 7.0.0 CMake Error at C:/Users/user/scoop/apps/cmake/3.13.4/share/cmake-3.13/Modules/CMakeDetermineCompilerId.cmake:802 (message): The Clang compiler tool

"C:/Program Files/LLVM/bin/clang.exe"

targets the MSVC ABI but has a GNU-like command-line interface. This is not supported. Use 'clang-cl' instead, e.g. by setting 'CC=clang-cl' in the environment. Furthermore, use the MSVC command-line environment. Call Stack (most recent call first):
C:/Users/user/scoop/apps/cmake/3.13.4/share/cmake-3.13/Modules/CMakeDetermineCCompiler.cmake:113 (CMAKE_DIAGNOSE_UNSUPPORTED_CLANG) CMakeLists.txt:2 (PROJECT)

-- Configuring incomplete, errors occurred!

CMake 工具链文件(Toolchain-clang-arm.cmake):

set(CMAKE_CROSSCOMPILING TRUE)
SET(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR arm)

# Clang target triple
SET(TARGET armv7-none-eabi)

# specify the cross compiler
SET(CMAKE_C_COMPILER_TARGET ${TARGET})
SET(CMAKE_C_COMPILER clang)
SET(CMAKE_CXX_COMPILER_TARGET ${TARGET})
SET(CMAKE_CXX_COMPILER clang++)
SET(CMAKE_ASM_COMPILER_TARGET ${TARGET})
SET(CMAKE_ASM_COMPILER clang)

# C/C++ toolchain
SET(TOOLCHAIN "C:/Program Files (x86)/GNU Tools ARM Embedded/7 2018-q2-update")
SET(CMAKE_C_COMPILER_EXTERNAL_TOOLCHAIN ${TOOLCHAIN})
SET(CMAKE_CXX_COMPILER_EXTERNAL_TOOLCHAIN ${TOOLCHAIN})

# specify compiler flags
SET(ARCH_FLAGS "-target armv7-none-eabi -mcpu=cortex-a5")
SET(CMAKE_C_FLAGS "-Wall -Wextra ${ARCH_FLAGS}" CACHE STRING "Common flags for C compiler")
SET(CMAKE_CXX_FLAGS "-Wall -Wextra -std=c++11 -fno-exceptions -fno-threadsafe-statics ${ARCH_FLAGS}" CACHE STRING "Common flags for C++ compiler")

我使用了 CMake和 Clang文档和一些 random link从网上创建工具链文件。整个项目使用 ARM GCC for Windows 编译良好，因此工具链文件似乎是唯一缺失的部分。

编辑

我试图通过强制编译器来绕过 CMake 编译器检查。我将 SET(CMAKE_C_COMPILER clang)、SET(CMAKE_CXX_COMPILER clang++) 等行替换为:

CMAKE_FORCE_C_COMPILER(clang Clang)
CMAKE_FORCE_CXX_COMPILER(clang++ Clang)

错误保持不变。

编辑

我可以使用 clang -target arm-none-eabi 成功编译一个 hello world 示例。所以问题似乎出在 CMake 中。我创建了一个 bug在 CMake 问题跟踪器中。

工具版本:

• clang 版本 7.0.0 (tags/RELEASE_700/final)
• cmake 版本 3.13.4

最佳答案

我的问题已通过 reply 得到解答添加到我的错误报告中，但我在此处添加了答案，以便将所有信息集中在一个地方以供将来引用。

简而言之: 如果您从 llvm.org 安装 Clang，CMake 当前不支持使用 clang/clang++ 命令行界面.如果你想使用 clang/clang++ 接口(interface)(这是为 ARM 交叉编译所必需的)你必须通过 msys2 安装 Clang .

详细

Windows 上的 Clang 有两种不同的命令行界面:

• clang/clang++尝试与 GCC gcc/g++ 兼容并以 GNU ABI 为目标的默认接口(interface)
• clang-cl试图与 Microsoft 的 Visual C++ 编译器 cl.exe 兼容并以 MSVC ABI 为目标

为了针对 ARM 进行交叉编译，您需要 clang/clang++ 接口(interface)。问题是 CMake 支持不同的接口(interface)，具体取决于您安装 Clang 的方式(有关更多详细信息，请参阅 CMake 问题跟踪器中的 bug):

• 如果您从 llvm.org 安装 Clang CMake 仅支持 clang-cl 接口(interface)。
• 如果您通过 msys2 安装 Clang CMake 支持 clang/clang++ 接口(interface)。

这就是我所做的:

1. 安装 msys2
2. 使用 pacman 安装 Clang 和 CMake . msys2中有两个clang包，一个mingw32和一个mingw64版本。我使用了 mingw64 包 (mingw-w64-x86_64-clang)。
3. 启动 mingw64 shell 并运行 CMake 并从那里构建。

工具链文件

我的原始工具链文件有两个问题，我花了很长时间才修复。所以我希望这会为其他人节省一些时间:

1. target triple (例如 arm-none-eabi)需要 完全 匹配 GCC binutils 的前缀。我的 binutils 的前缀是 arm-none-eabi(例如 arm-none-eabi-ar)，所以我必须相应地更改目标三元组。
2. CMAKE_TRY_COMPILE_TARGET_TYPE需要更改为 STATIC_LIBRARY 以防止 CMake 在编译检查期间运行链接器。

这是我使用的最终工具链文件(您还可以在此 GitHub repo 中找到工具链文件的一个很好的示例):

cmake_minimum_required(VERSION 3.13)

set(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR ARM)

if(DEFINED ENV{GCC_ARM_TOOLCHAIN})
    set(GCC_ARM_TOOLCHAIN $ENV{GCC_ARM_TOOLCHAIN})
else()
    set(GCC_ARM_TOOLCHAIN "C:/Users/user/tools/gcc-arm-none-eabi-7-2018-q2-update-win32")
endif()

LIST(APPEND CMAKE_PROGRAM_PATH ${GCC_ARM_TOOLCHAIN})

# Specify the cross compiler
# The target triple needs to match the prefix of the binutils exactly
# (e.g. CMake looks for arm-none-eabi-ar)
set(CLANG_TARGET_TRIPLE arm-none-eabi)
set(GCC_ARM_TOOLCHAIN_PREFIX ${CLANG_CLANG_TARGET_TRIPLE})
set(CMAKE_C_COMPILER clang)
set(CMAKE_C_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})
set(CMAKE_CXX_COMPILER clang++)
set(CMAKE_CXX_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})
set(CMAKE_ASM_COMPILER clang)
set(CMAKE_ASM_COMPILER_TARGET ${CLANG_TARGET_TRIPLE})

# Don't run the linker on compiler check
set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)

# Specify compiler flags
set(ARCH_FLAGS "-mcpu=cortex-a5 -mthumb -mfpu=neon-vfpv4 -mfloat-abi=hard -mno-unaligned-access")
set(CMAKE_C_FLAGS "-Wall ${ARCH_FLAGS}" CACHE STRING "Common flags for C compiler")
set(CMAKE_CXX_FLAGS "-Wall -std=c++17 -fno-exceptions -fno-rtti -fno-threadsafe-statics ${ARCH_FLAGS}" CACHE STRING "Common flags for C++ compiler")
set(CMAKE_ASM_FLAGS "-Wall ${ARCH_FLAGS} -x assembler-with-cpp" CACHE STRING "Common flags for assembler")
set(CMAKE_EXE_LINKER_FLAGS "-nostartfiles -Wl,-Map,kernel.map,--gc-sections -fuse-linker-plugin -Wl,--use-blx --specs=nano.specs --specs=nosys.specs" CACHE STRING "")

# C/C++ toolchain
set(GCC_ARM_SYSROOT "${GCC_ARM_TOOLCHAIN}/${GCC_ARM_TOOLCHAIN_PREFIX}")
# set(CMAKE_SYSROOT ${GCC_ARM_SYSROOT})
set(CMAKE_FIND_ROOT_PATH ${GCC_ARM_SYSROOT})

# Search for programs in the build host directories
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
# For libraries and headers in the target directories
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)

关于c++ - 如何设置 CMake 与 clang 交叉编译 Windows 上嵌入的 ARM？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/54539682/