我有以下语法来解析应用于图形的一阶逻辑公式:

grammar Graph;


/*------------------------------------------------------------------
* PARSER RULES
*------------------------------------------------------------------*/

input
: 
formula EOF
;

formula
:
TRUE 
| FALSE 
| formula AND formula
| formula OR formula
| quantifier formula
| ST condition
;


condition
:
atom EQUALS QUOTE? (assignment | atom) QUOTE?
;

quantifier 
:
(FOREACH | EXISTS) variable IN domain
;

domain
:
(GRAPH_A | GRAPH_B)
;

atom
:
variable DOT property
;


variable
:   
(nodev | edgev)
;


nodev
:
(NODE | NODE1)
;

edgev
:
(EDGE | EDGE1)
;

property
:
(COLOR | VALUE)
;

assignment
:
(COLORTYPE | NUMBER)
;


/*------------------------------------------------------------------
* LEXER RULES
*------------------------------------------------------------------*/

TRUE : 'True' ;

FALSE : 'False' ;

AND : '&' ;

OR : '|' ;

ST : '->' ; 

EXISTS  : 'Exists' ;

FOREACH : 'Foreach' ;

NODE : 'node' ;

NODE1 : 'node1' ;

EDGE : 'edge' ;

EDGE1 : 'edge1' ;

IN : 'in' ;

GRAPH_A : 'GraphA' ;

GRAPH_B : 'GraphB' ;

EQUALS : '=' ;

DOT : '.' ;

COLOR : 'color' ;

VALUE : 'value' ;

NUMBER : ('0'..'9')+ (DOT ('0'..'9')+)? ;

QUOTE : '\'' ;

COLORTYPE : ('a'..'z')+ ;

WS : [ \t\r\n]+ -> skip ;

我相信这是我的语法的最终版本，所以现在我想为输入指定一些错误处理。问题是我不知道怎么做。我所知道的是，在解析输入后，我可以迭代生成的 AST，这是添加错误处理的地方。

如果解析失败，返回解析异常；否则，我指定了以下情况来返回错误消息。

1. 不能有 1 个量词后跟 -> condition(这是一个公式元素)，其中 condition 等于 atom=atom。换句话说，如果只有 quantifier，则 condition 应该等于 atom EQUALS assignment。

2. 如果有 2 个量词，第一个应该以 FOREACH

   开头

3. condition 语句中应使用量词中的变量

4. 表达式左侧的量词不能超过两个(因为在我开发的应用程序中只有两个图表)。因此，如果量词的数量大于两个，也会返回错误

5. 如果有 2 个量词，那么它们应该绑定(bind)不同的变量

例如，当我们有输入时应该引发第一种情况

Exists node in GraphA -> node.color = node1.color 

因为 node1 没有在表达式的左侧指定。

第二种情况的示例是以下输入

Exists node in GraphA Exists node1 in GraphB -> node.color = node1.color

所以我的问题是我是否必须对生成的解析树实现所有错误检查，或者我可以使用一些 Java 代码在语法中指定其中的一些。如果在解析输入后应该进行错误处理，我可以使用 ANTLR 4 的哪些功能来实现错误情况？任何帮助或建议将不胜感激!

最佳答案

您可能希望在监听器中结合帮助访问者来实现这些语义检查。以下是一些示例。

规则:量词中的变量应该在条件中使用

实现:

1. 创建一个返回指定解析树节点使用的变量的访问者。你会想要覆盖 defaultResult()和 aggregateResult(T, T)为您完成大部分工作，然后覆盖 visitNodev 和 visitEdgev 以处理正在使用的特定变量。
2. 在您的监听器中，覆盖 enterFormula 方法。在这个方法中，如果ctx.quantifier()不为null，那么使用你的visitor获取在ctx.quantifier()中声明的变量列表和变量列表在 ctx.formula() 中使用。
3. 根据这两个结果酌情报告错误。

规则:如果有 2 个量词，那么它们应该绑定(bind)不同的变量

实现:

1. 从前面规则实现的第 1 步中描述的访客开始。
2. 在您的监听器中，覆盖 enterFormula 方法。在该方法中，如果 ctx.quantifier() 不为空，则需要获取 ctx 返回的树下所有其他 QuantifierContext 实例的集合.公式()。您可以通过调用 XPath.findAll(ctx.formula(), "//quantifier", parser) 来完成此操作.
3. 使用上述访问器收集在每个链接的 QuantifierContext 实例中声明的变量列表。如果有任何集合重叠，请酌情报告错误。

规则:如果有 2 个量词，第一个应该以 FOREACH

实现:

使用上一步中描述的监听器模式来定位公式包含多个量词 的情况。如果这些公式中的第一个具有 ctx.quantifier().FOREACH() == null，则相应地发出错误。

规则:量词不能超过两个...

实现:

如果 XPath.findAll 在 formula 中返回多个 QuantifierContext ，则更新上面第二条规则的实现以报告错误量词。

规则:量词条件限制

实现:

首先，创建一个 ParseTreePattern对象。

String patternString = "<quantifier> -> <condition>";
ParseTreePattern pattern =
    parser.compileParseTreePattern(patternString, GraphParser.RULE_formula);

然后，在您的解析树中找到该模式的所有实例。

List<ParseTreeMatch> matches = pattern.findAll(tree, "//formula");

然后验证匹配就相当简单了。

for (ParseTreeMatch match : matches) {
  ConditionContext condition = (ConditionContext)match.get("condition");
  if (condition.assignment() == null) {
    // TODO: report error here
  }
}

关于java - 如何在ANTLR4中实现错误处理，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/21613421/