我有一个由 GoDaddy 托管的网站，包括后端的 MySQL 数据库。该站点是斯洛文尼亚站点，因此使用了特殊字符。

该网站是用经典的 ASP 构建的，我在 Notepad++ 中创建了所有页面，其中使用了 utf-8 编码。在每个页面的顶部，我还有 Session.CodePage=65001、Session.LCID=1060 和 Response.Charset="utf-8"。 MySQL 数据库和所有表也是 utf8 编码的。

如果我通过 Workbench 界面直接在 db 中查看数据，一切正常，包括我使用的一些特殊的斯洛文尼亚字符，例如:č

如果我去我的网站，斯洛文尼亚字符也打印得很好，包括 č

唯一的问题是，在同一页面上，从 MySQL 检索的数据编码不正确，所以字母 č 变成了？

可能是什么问题以及如何解决？

首先我以为是 MySQL ODBC 3.51 驱动程序，我用它来连接数据库。我尝试将 charset=utf8 添加到连接字符串，但没有成功。我还尝试将 charset=ucs2 添加到连接字符串，这是我在另一个网站上找到的提示，但也没有帮助。 GoDaddy 不支持 MySQL ODBC 5.1 驱动程序，这可能是一个解决方案。

我的选项用完了，所以请帮忙。

最佳答案

你有机会根据这个 mapping 得到斯洛文尼亚字母和 Windows-1252 wiki article 的摘录:

According to the information on Microsoft's and the Unicode Consortium's websites, positions 81, 8D, 8F, 90, and 9D are unused; however, the Windows API MultiByteToWideChar maps these to the corresponding C1 control codes.

The euro character at position 80 was not present in earlier versions of this code page, nor were the S, s, Z, and z with caron (háček).

以下是要做的事情:

1. 使用 UTF-8(无 BOM)编码的文件以防止包含硬编码文本的可能性。 (✔ 已经完成)

2. 在服务器端使用 ASP 或在客户端使用元标记为响应字符集指定 UTF-8。 (✔ 已经完成)

3. 告诉 MySQL 服务器您的命令在字符集 utf-8 中，并且您期望 utf-8 编码的结果集。向连接字符串添加初始语句:...;stmt=SET NAMES 'utf8';...

4. 将 Response.CodePage 设置为 1252。

我已经测试了以下脚本，它的效果非常好。

DDL: http://sqlfiddle.com/#!8/c2c35/1

ASP:

<%@Language=VBScript%>
<% 
Option Explicit

Response.CodePage = 1252
Response.LCID = 1060
Response.Charset = "utf-8"

Const adCmdText = 1, adVarChar = 200, adParamInput = 1, adLockOptimistic = 3

Dim Connection
Set Connection = Server.CreateObject("Adodb.Connection")
    Connection.Open "Driver={MySQL ODBC 3.51 Driver};Server=localhost;Database=myDb;User=myUsr;Password=myPwd;stmt=SET NAMES 'utf8';"
    
If Request.Form("name").Count = 1 And Len(Request.Form("name")) Then 'add new
    Dim rsAdd
    Set rsAdd = Server.CreateObject("Adodb.Recordset")
        rsAdd.Open "names", Connection, ,adLockOptimistic
        rsAdd.AddNew
        rsAdd("name").Value = Left(Request.Form("name"), 255)
        rsAdd.Update
        rsAdd.Close
    Set rsAdd = Nothing
End If

Dim Command
Set Command = Server.CreateObject("Adodb.Command")
    Command.CommandType = adCmdText
    Command.CommandText = "Select name From `names` Order By id Desc"
    
    If Request.QueryString("name").Count = 1 And Len(Request.QueryString("name")) Then
        Command.CommandText = "Select name From `names` Where name = ? Order By id Desc"
        Command.Parameters.Append Command.CreateParameter(, adVarChar, adParamInput, 255, Left(Request.QueryString("name"), 255))
    End If
    
    Set Command.ActiveConnection = Connection
    With Command.Execute
        While Not .Eof
            Response.Write "<a href=""?name=" & .Fields("name").Value & """>" & .Fields("name").Value & "</a><br />"
            .MoveNext
        Wend
        .Close
    End With
    
    Set Command.ActiveConnection = Nothing
    Set Command = Nothing
    
Connection.Close
%><hr />
<a href="?">SHOW ALL</a><hr />
<form method="post" action="<%=Request.ServerVariables("SCRIPT_NAME")%>">
Name : <input type="text" name="name" maxlength="255" /> <input type="submit" value="Add" />
</form>

最后一句话:

当您需要对从数据库中获取的字符串应用 html 编码时，您不应再使用 Server.HTMLEncode，因为服务器端的 Response.Codepage 是 1252，并且由于 Server.HTMLEncode 是依赖上下文代码页，这将导致乱码输出。
所以你需要编写自己的 html 编码器来处理这种情况。

Function MyOwnHTMLEncode(ByVal str)
    str = Replace(str, "&", "&")
    str = Replace(str, "<", "&lt;")
    str = Replace(str, ">", "&gt;")
    str = Replace(str, """", "&quot;")
    MyOwnHTMLEncode = str
End Function
'Response.Write MyOwnHTMLEncode(rs("myfield").value)

关于mysql - 经典 ASP、MySQL 或 ODBC UTF8 编码，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/18269039/