我在 MySQL 中有一个这样的表:

+-------+--------+-------------+
| child | parent | data        |
+-------+--------+-------------+
|     1 |      0 | house       |
|     2 |      0 | car         |
|     3 |      1 | door        |
|     4 |      2 | door        |
|     5 |      2 | windscreen  |
|    11 |      5 | wiper       |
+-------+--------+-------------+

我根据 this 从 Excel 2007 连接到 MySQL教程除了我在系统 DSN 中创建 DSN 而不是在用户 DSN 中，这对我有用。

我对公式知之甚少，但我不知道如何获取此表格数据:

house | door
house | wall
car   | door
car   | windscreen | wiper  

MySQL 的部分在这里不是问题。那个 MySQL 表很可能是一个 Excel 表。现在我意识到甚至没有必要说这里有一个 MySQL 表只是一个 Excel 表。但这可能会启发/帮助某些人。

在一些文档之后，我设法解决了问题中最重要的方面。工作表数据库中的范围:

child    parent     data
1        0          car
2        0          house
3        1          door
4        2          door
5        1          window
6        2          window
7        1          windscreen
8        7          wiper
9        4          color
10        2          color

我有一个名称 db 指的是:

=db!$A$2:OFFSET(db!$C$2,COUNTA(db!$C:$C)-2,0) 

一个名字的 child :

=db!$A$2:OFFSET(db!$A$2,COUNTA(db!$A:$A)-2,0)

在另一个名为 construct 的工作表中，我从 B2 开始并使用了以下公式:

=IFERROR(
    IF(ISBLANK(B1),
        LARGE(child,COUNTA($A$2:A$2)+1),
        VLOOKUP(B1,db,2,0)
    ),".") 

在名为输出的第三张表中，我从 A1 开始并使用了公式:

=IFERROR(VLOOKUP(construct!B2,db,3,0),".")

现在最后一个挑战是让构造和输出的公式在新条目添加到主表时自动扩展，但我认为不可能。

当从 db sheet 中的 SQL 导入时，将有一个表而不是范围，因此公式看起来会有点不同。单击表中的任意位置，单击设计选项卡并重命名表基，然后在从 b2 开始的构造表中使用以下公式:

=IFERROR(
    IF(ISBLANK(B1),
    LARGE(INDIRECT("base[child]"),COUNTA($A$2:A$2)+1),
    VLOOKUP(B1,base,2,0)
),".")

最佳答案

以下是我使用 VBA 的方法:首先创建一个类模块并将其命名为 CDatum。将此代码放在那里。

Option Explicit

Private msID As String
Private msData As String
Private msParentID As String


Public Property Get ID() As String

    ID = msID

End Property

Public Property Let ID(ByVal sID As String)

    msID = sID

End Property

Public Property Get Data() As String

    Data = msData

End Property

Public Property Let Data(ByVal sData As String)

    msData = sData

End Property

Public Property Get ParentID() As String

    ParentID = msParentID

End Property

Public Property Let ParentID(ByVal sParentID As String)

    msParentID = sParentID

End Property

Public Property Get ChildCount() As Long

    Dim i As Long
    Dim lReturn As Long

    For i = 1 To gclsData.Count
        If gclsData.Data(i).ParentID = Me.ID Then
            lReturn = lReturn + 1
        End If
    Next i

    ChildCount = lReturn

End Property

Public Property Get Tree() As Variant

    Dim vaReturn As Variant
    Dim vaChild As Variant
    Dim i As Long, j As Long
    Dim lChildCount As Long
    Dim lRowCount As Long
    Dim lOldUbound As Long

    If Me.ChildCount = 0 Then
        lRowCount = 1
    Else
        lRowCount = Me.ChildCount
    End If

    ReDim vaReturn(1 To lRowCount, 1 To 1)

    For i = 1 To lRowCount
        vaReturn(i, 1) = Me.Data
    Next i

    For i = 1 To gclsData.Count
        If gclsData.Data(i).ParentID = Me.ID Then
            lChildCount = lChildCount + 1
            vaChild = gclsData.Data(i).Tree
            lOldUbound = UBound(vaReturn, 2)
            ReDim Preserve vaReturn(1 To lRowCount, 1 To UBound(vaReturn, 2) + UBound(vaChild, 2))
            For j = 1 To UBound(vaChild, 2)
                vaReturn(lChildCount, j + 1) = vaChild(1, j)
            Next j
        End If
    Next i

    Tree = vaReturn

End Property

接下来制作一个类模块并命名为CData并将这段代码放入其中

Option Explicit

Private mcolCDatas As Collection

Private Sub Class_Initialize()

    Set mcolCDatas = New Collection

End Sub

Private Sub Class_Terminate()

    Set mcolCDatas = Nothing

End Sub

Public Sub Add(clsDatum As CDatum)

    mcolCDatas.Add clsDatum, clsDatum.ID

End Sub

Public Property Get Count() As Long

    Count = mcolCDatas.Count

End Property

Public Property Get Data(vItem As Variant) As CDatum

    Set Data = mcolCDatas.Item(vItem)

End Property

Public Property Get FilterByTopLevel() As CData

    Dim clsReturn As CData
    Dim i As Long
    Dim clsDatum As CDatum

    Set clsReturn = New CData

    For i = 1 To Me.Count
        Set clsDatum = Me.Data(i)
        If clsDatum.ParentID = 0 Then
            clsReturn.Add clsDatum
        End If
    Next i

    Set FilterByTopLevel = clsReturn

End Property

接下来插入一个标准模块，把这段代码放进去

Option Explicit

Public gclsData As CData

Sub FillClass()

    Dim clsDatum As CDatum
    Dim rCell As Range

    Set gclsData = New CData

    For Each rCell In Sheet1.Range("A2:A7").Cells
        Set clsDatum = New CDatum
        clsDatum.ID = rCell.Value
        clsDatum.Data = rCell.Offset(0, 2).Value
        clsDatum.ParentID = rCell.Offset(0, 1).Value
        gclsData.Add clsDatum
    Next rCell

End Sub

Sub PrintTree()

    Dim clsDatum As CDatum
    Dim clsTopLevel As CData
    Dim i As Long
    Dim ws As Worksheet
    Dim vaData As Variant
    Dim lRowCount As Long

    FillClass

    Set clsTopLevel = gclsData.FilterByTopLevel
    Set ws = ThisWorkbook.Worksheets.Add

    lRowCount = 1

    For i = 1 To clsTopLevel.Count
        Set clsDatum = clsTopLevel.Data(i)
        vaData = clsDatum.Tree
        ws.Cells(lRowCount, 1).Resize(UBound(vaData, 1), UBound(vaData, 2)).Value = vaData
        lRowCount = lRowCount + UBound(vaData, 1)
    Next i

End Sub

然后运行 ​​PrintTree 子程序。或者您可以下载我用来测试它的工作簿并在其中进行操作。

http://www.dailydoseofexcel.com/excel/TestDataClass.zip

关于mysql - 在 Excel 中格式化 MySQL 数据，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/3184705/