草庐IT

xml - 如何根据节点属性动态更改 xslt 页面序列？

coder 2024-06-25 原文

我遇到的问题的简化版本是这样的。对于像这样的 XML 文件:

<?xml version="1.0" encoding="UTF-8"?>
<items>
    <item cols="1">Item 1</item>
    <item cols="1">Item 2</item>
    <item cols="1">Item 3</item>
    <item cols="1">Item 4</item>
    <item cols="1">Item 5</item>
    <item cols="1">Item 6</item>
    <item cols="1">Item 7</item>
    <item cols="1">Item 8</item>
    <item cols="1">Item 9</item>
    <item cols="2">Item 10</item>
    <item cols="1">Item 11</item>
    <item cols="1">Item 12</item>
    <item cols="1">Item 13</item>
    <item cols="1">Item 14</item>
    <item cols="1">Item 15</item>
    <item cols="1">Item 16</item>
    <item cols="1">Item 17</item>
    <item cols="1">Item 18</item>
</items>

我需要能够在单列页面布局中打印具有“cols=1”的“项目”，以及在双列页面布局中打印具有“cols=2”的“项目”。必须保留项目的顺序。所有具有相同 @cols 值的连续“项目”都需要显示为连续流。每当 @cols 值发生变化时，我都需要跳转到一个新页面并根据需要更改布局。

我正在做这样的事情:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:fo="http://www.w3.org/1999/XSL/Format">

    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
            <fo:layout-master-set>

                <fo:simple-page-master master-name="one-column-page-master">
                    <fo:region-body margin-top="3cm" region-name="body" column-count="1"/>
                </fo:simple-page-master>

                <fo:simple-page-master master-name="two-column-page-master">
                    <fo:region-body margin-top="3cm" region-name="body" column-count="2"/>
                    <fo:region-before region-name="header" extent="2cm"/>
                </fo:simple-page-master>

                <fo:page-sequence-master master-name="one-column-page">
                    <fo:repeatable-page-master-reference master-reference="one-column-page-master"/>
                </fo:page-sequence-master>

                <fo:page-sequence-master master-name="two-column-page">
                    <fo:repeatable-page-master-reference master-reference="two-column-page-master"/>
                </fo:page-sequence-master>

            </fo:layout-master-set>

            <xsl:for-each select="//item">
                <xsl:choose>
                    <xsl:when test="@cols = preceding-sibling::item[1]/@cols">
                        <!--cols value hasn't changed, don't create a new page-sequence-->
                        <!--But we cannot directly add fo:flow as the child of fo:root! -->
                        <xsl:call-template name="itemtemplate"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:choose>
                            <xsl:when test="@cols = 1">
                                <fo:page-sequence master-reference="one-column-page">
                                    <xsl:call-template name="itemtemplate"/>
                                </fo:page-sequence>
                            </xsl:when>
                            <xsl:otherwise>
                                <fo:page-sequence master-reference="two-column-page">
                                    <xsl:call-template name="itemtemplate"/>
                                </fo:page-sequence>
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </fo:root>

    </xsl:template>

    <xsl:template name="itemtemplate">
            <fo:flow flow-name="body">
                <fo:block margin-bottom="5cm">
                    <xsl:apply-templates/>
                </fo:block>
            </fo:flow>

    </xsl:template>

</xsl:stylesheet>

当然，问题是我要么必须在我的样式表中包含 ，要么不，我不能“动态地”决定根据注释属性放入一个。 (除非我有一个首先动态创建样式表的元程序，但我希望仅使用普通静态样式表来完成此操作)。

最佳答案

这是一个使用 xsl:for-each-group 的 XSLT 2.0 解决方案与 group-adjacent:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:fo="http://www.w3.org/1999/XSL/Format">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:template match="/">
      <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
        <fo:layout-master-set>

          <fo:simple-page-master master-name="one-column-page-master">
            <fo:region-body margin-top="3cm" region-name="body" 
                            column-count="1"/>
          </fo:simple-page-master>

          <fo:simple-page-master master-name="two-column-page-master">
            <fo:region-body margin-top="3cm" region-name="body" 
                            column-count="2"/>
            <fo:region-before region-name="header" extent="2cm"/>
          </fo:simple-page-master>

          <fo:page-sequence-master master-name="one-column-page">
            <fo:repeatable-page-master-reference 
                master-reference="one-column-page-master"/>
          </fo:page-sequence-master>

          <fo:page-sequence-master master-name="two-column-page">
            <fo:repeatable-page-master-reference 
                master-reference="two-column-page-master"/>
          </fo:page-sequence-master>

        </fo:layout-master-set>
        <xsl:apply-templates/>
      </fo:root>
    </xsl:template>

    <xsl:template match="items">
      <xsl:for-each-group select="item" 
                          group-adjacent="@cols">

        <xsl:choose>
          <xsl:when test="@cols = 1">
            <fo:page-sequence master-reference="one-column-page">
              <fo:flow flow-name="body">
                <xsl:for-each select="current-group()">
                  <xsl:apply-templates select="."/>
                </xsl:for-each>
              </fo:flow>
            </fo:page-sequence>
          </xsl:when>

          <xsl:otherwise>
            <fo:page-sequence master-reference="two-column-page">
              <fo:flow flow-name="body">
                <xsl:for-each select="current-group()">
                  <xsl:apply-templates select="."/>
                </xsl:for-each>
              </fo:flow>
            </fo:page-sequence>
          </xsl:otherwise>

        </xsl:choose>
      </xsl:for-each-group>
    </xsl:template>

    <xsl:template match="item">
      <fo:block margin-bottom="5cm">
        <xsl:apply-templates/>
      </fo:block>
    </xsl:template>

</xsl:stylesheet>

输出:

<?xml version="1.0" encoding="UTF-8"?>
<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:layout-master-set>
      <fo:simple-page-master master-name="one-column-page-master">
         <fo:region-body margin-top="3cm" region-name="body" column-count="1"/>
      </fo:simple-page-master>
      <fo:simple-page-master master-name="two-column-page-master">
         <fo:region-body margin-top="3cm" region-name="body" column-count="2"/>
         <fo:region-before region-name="header" extent="2cm"/>
      </fo:simple-page-master>
      <fo:page-sequence-master master-name="one-column-page">
         <fo:repeatable-page-master-reference master-reference="one-column-page-master"/>
      </fo:page-sequence-master>
      <fo:page-sequence-master master-name="two-column-page">
         <fo:repeatable-page-master-reference master-reference="two-column-page-master"/>
      </fo:page-sequence-master>
   </fo:layout-master-set>
   <fo:page-sequence master-reference="one-column-page">
      <fo:flow flow-name="body">
         <fo:block margin-bottom="5cm">Item 1</fo:block>
         <fo:block margin-bottom="5cm">Item 2</fo:block>
         <fo:block margin-bottom="5cm">Item 3</fo:block>
         <fo:block margin-bottom="5cm">Item 4</fo:block>
         <fo:block margin-bottom="5cm">Item 5</fo:block>
         <fo:block margin-bottom="5cm">Item 6</fo:block>
         <fo:block margin-bottom="5cm">Item 7</fo:block>
         <fo:block margin-bottom="5cm">Item 8</fo:block>
         <fo:block margin-bottom="5cm">Item 9</fo:block>
      </fo:flow>
   </fo:page-sequence>
   <fo:page-sequence master-reference="two-column-page">
      <fo:flow flow-name="body">
         <fo:block margin-bottom="5cm">Item 10</fo:block>
      </fo:flow>
   </fo:page-sequence>
   <fo:page-sequence master-reference="one-column-page">
      <fo:flow flow-name="body">
         <fo:block margin-bottom="5cm">Item 11</fo:block>
         <fo:block margin-bottom="5cm">Item 12</fo:block>
         <fo:block margin-bottom="5cm">Item 13</fo:block>
         <fo:block margin-bottom="5cm">Item 14</fo:block>
         <fo:block margin-bottom="5cm">Item 15</fo:block>
         <fo:block margin-bottom="5cm">Item 16</fo:block>
         <fo:block margin-bottom="5cm">Item 17</fo:block>
         <fo:block margin-bottom="5cm">Item 18</fo:block>
      </fo:flow>
   </fo:page-sequence>
</fo:root>

关于xml - 如何根据节点属性动态更改 xslt 页面序列？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/6836142/

xsltxml34ltgtxsl-foapache-fop

有关xml - 如何根据节点属性动态更改 xslt 页面序列？的更多相关文章

  1. ruby - 如何使用 Nokogiri 的 xpath 和 at_xpath 方法 - 2

    我正在学习如何使用Nokogiri，根据这段代码我遇到了一些问题:require'rubygems'require'mechanize'post_agent=WWW::Mechanize.newpost_page=post_agent.get('http://www.vbulletin.org/forum/showthread.php?t=230708')puts"\nabsolutepathwithtbodygivesnil"putspost_page.parser.xpath('/html/body/div/div/div/div/div/table/tbody/tr/td/div

  2. ruby - 如何从 ruby​​ 中的字符串运行任意对象方法？ - 2

    总的来说，我对ruby​​还比较陌生，我正在为我正在创建的对象编写一些rspec测试用例。许多测试用例都非常基础，我只是想确保正确填充和返回值。我想知道是否有办法使用循环结构来执行此操作。不必为我要测试的每个方法都设置一个assertEquals。例如:describeitem,"TestingtheItem"doit"willhaveanullvaluetostart"doitem=Item.new#HereIcoulddotheitem.name.shouldbe_nil#thenIcoulddoitem.category.shouldbe_nilendend但我想要一些方法来使用

  3. ruby-on-rails - Ruby on Rails 迁移，将表更改为 MyISAM - 2

    如何正确创建Rails迁移，以便将表更改为MySQL中的MyISAM？目前是InnoDB。运行原始执行语句会更改表，但它不会更新db/schema.rb，因此当在测试环境中重新创建表时，它会返回到InnoDB并且我的全文搜索失败。我如何着手更改/添加迁移，以便将现有表修改为MyISAM并更新schema.rb，以便我的数据库和相应的测试数据库得到相应更新？ 最佳答案 我没有找到执行此操作的好方法。您可以像有人建议的那样更改您的schema.rb，然后运行:rakedb:schema:load，但是，这将覆盖您的数据。我的做法是(假设

  4. python - 如何使用 Ruby 或 Python 创建一系列高音调和低音调的蜂鸣声？ - 2

    关闭。这个问题是opinion-based.它目前不接受答案。想要改进这个问题？更新问题，以便editingthispost可以用事实和引用来回答它.关闭4年前。Improvethisquestion我想在固定时间创建一系列低音和高音调的哔哔声。例如:在150毫秒时发出高音调的蜂鸣声在151毫秒时发出低音调的蜂鸣声200毫秒时发出低音调的蜂鸣声250毫秒的高音调蜂鸣声有没有办法在Ruby或Python中做到这一点？我真的不在乎输出编码是什么(.wav、.mp3、.ogg等等)，但我确实想创建一个输出文件。

  5. ruby-on-rails - 如何验证 update_all 是否实际在 Rails 中更新 - 2

    给定这段代码defcreate@upgrades=User.update_all(["role=?","upgraded"],:id=>params[:upgrade])redirect_toadmin_upgrades_path,:notice=>"Successfullyupgradeduser."end我如何在该操作中实际验证它们是否已保存或未重定向到适当的页面和消息？ 最佳答案 在Rails3中，update_all不返回任何有意义的信息，除了已更新的记录数(这可能取决于您的DBMS是否返回该信息)。http://ar.ru

  6. ruby-on-rails - 'compass watch' 是如何工作的/它是如何与 rails 一起使用的 - 2

    我在我的项目目录中完成了compasscreate.和compassinitrails。几个问题:我已将我的.sass文件放在public/stylesheets中。这是放置它们的正确位置吗？当我运行compasswatch时，它不会自动编译这些.sass文件。我必须手动指定文件:compasswatchpublic/stylesheets/myfile.sass等。如何让它自动运行？文件ie.css、print.css和screen.css已放在stylesheets/compiled。如何在编译后不让它们重新出现的情况下删除它们？我自己编译的.sass文件编译成compiled/t

  7. ruby - 如何将脚本文件的末尾读取为数据文件(Perl 或任何其他语言) - 2

    我正在寻找执行以下操作的正确语法(在Perl、Shell或Ruby中):#variabletoaccessthedatalinesappendedasafileEND_OF_SCRIPT_MARKERrawdatastartshereanditcontinues. 最佳答案 Perl用__DATA__做这个:#!/usr/bin/perlusestrict;usewarnings;while(){print;}__DATA__Texttoprintgoeshere 关于ruby-如何将脚

  8. ruby - 如何指定 Rack 处理程序 - 2

    Rackup通过Rack的默认处理程序成功运行任何Rack应用程序。例如:classRackAppdefcall(environment)['200',{'Content-Type'=>'text/html'},["Helloworld"]]endendrunRackApp.new但是当最后一行更改为使用Rack的内置CGI处理程序时，rackup给出“NoMethodErrorat/undefinedmethod`call'fornil:NilClass”:Rack::Handler::CGI.runRackApp.newRack的其他内置处理程序也提出了同样的反对意见。例如Rack

  9. ruby - 如何每月在 Heroku 运行一次 Scheduler 插件？ - 2

    在选择我想要运行操作的频率时，唯一的选项是“每天”、“每小时”和“每10分钟”。谢谢!我想为我的Rails3.1应用程序运行调度程序。 最佳答案 这不是一个优雅的解决方案，但您可以安排它每天运行，并在实际开始工作之前检查日期是否为当月的第一天。 关于ruby-如何每月在Heroku运行一次Scheduler插件？，我们在StackOverflow上找到一个类似的问题： https://stackoverflow.com/questions/8692687/

  10. ruby-on-rails - 如何从 format.xml 中删除 <hash></hash> - 2

    我有一个对象has_many应呈现为xml的子对象。这不是问题。我的问题是我创建了一个Hash包含此数据，就像解析器需要它一样。但是rails自动将整个文件包含在.........我需要摆脱type="array"和我该如何处理？我没有在文档中找到任何内容。 最佳答案 我遇到了同样的问题；这是我的XML:我在用这个:entries.to_xml将散列数据转换为XML，但这会将条目的数据包装到中所以我修改了:entries.to_xml(root:"Contacts")但这仍然将转换后的XML包装在“联系人”中，将我的XML代码修改为

随机推荐