最近我正在将我的编程环境从 CentOS 切换到 Windows。我是Emacs的粉丝，所以我也想用Emacs在Windows上编程。一切都进行得很顺利，但是当我使用 emacs 语义来解析系统包含时，问题就来了。

似乎 emacs semantic 会选择要解析的文件和不解析的文件。我指定了 MS Visual Studio include 目录供 emacs 解析，但它不会。我还尝试了 MinGW header ，但 emacs 只解析了一些文件。我的init.el文件是这样的

(defun my-semantic-hook()
  (semantic-add-system-include "C:\\Program Files (x86)\\Microsoft Visual Studio 10.0\\VC\\include")
  )

我不知道是否应该在 Windows 上的 emacs 中使用/或\，但似乎两者都可以。如果我使用 semantic-c-describe-environment输出是

This file’s project include is handled by:
    EDE : #<ede-cpp-root-target ede-cpp-root-target>
     with the system path:
    C:\Program Files (x86)\Microsoft Visual Studio 10.0\VC\include
    D:/WorkSpace/

  This file’s system include path is:
    /usr/include
    c:/Program Files (x86)/Microsoft Visual Studio 10.0/VC/include/

你可以看到我也试过EDE来指定系统包含路径，但它也不起作用。然而，语义的其他特性工作得很好。如果我写 #include "lib1.h"或 #include "headers/lib1.h"或使用 EDE #include <myproj/headers/lib1.h> ，它们都运行良好。但是，当涉及到 VS 包含文件或 MinGW 包含文件时，事情就出错了。 我想如果语义首先检查文件，发现有问题然后它就跳过文件？那我该如何解决这个问题呢？

现在问题有了新的进展。我已经尝试使用 SDL2 库在我的旧项目上使用语义。在我为 EDE 编写项目配置并打开其中一个源文件后，发生了一些事情。语义解析一些系统包含文件，如 stdio.h。然后我可以通过语义跳转到它。

然后我尝试使用 iostream 的另一个文件。但是语义仍然不解析它。但我可以使用 C-c , u命令跳转到文件，我手动调用语义来解析它。然后我使用 iostream 返回到我的原始文件，使用语义的公司后端现在可以很好地工作。

所以现在我可以确定问题是语义不解析文件本身。也许是因为它只解析文件名末尾带有 .h 或 .c 的文件？但是在 linux 上它可以很好地处理 iostream 之类的文件，为什么在 windows 上它不能？如何解决？

最佳答案

1. 添加系统包含示例:

       (semantic-reset-system-include 'c-mode)
       (dolist (x 'your-system-includes)
         (semantic-add-system-include x 'c-mode))
   

2. 添加项目根:

   (setq semanticdb-project-roots 'your-project-roots)
   

在More Reasonable Emacs中有一个实现有关如何找到正确系统的信息，请在 cc.el 的 system-cc-include 中包含 Windows、Darwin 和 Linux 上的路径

;;;; -*- lexical-binding:t -*-
;;;;
;; More reasonable Emacs on MacOS, Windows and Linux
;; https://github.com/junjiemars/.emacs.d
;;;;
;; cc.el
;;;;


(platform-supported-when windows-nt

  (defun check-vcvarsall-bat ()
    "Return the path of vcvarsall.bat if which exists."
    (let* ((pfroot (windows-nt-posix-path (getenv "PROGRAMFILES")))
           (vsroot (concat pfroot " (x86)/Microsoft Visual Studio/"))
           (vswhere (concat vsroot "Installer/vswhere.exe")))
      (windows-nt-posix-path
       (or (let* ((cmd (shell-command* (shell-quote-argument vswhere)
                         "-nologo -latest -property installationPath"))
                  (bat (and (zerop (car cmd))
                            (concat (string-trim> (cdr cmd))
                                    "/VC/Auxiliary/Build/vcvarsall.bat"))))
             (when (file-exists-p bat) bat))
           (let* ((ver (car (directory-files vsroot t "[0-9]+" #'string-greaterp)))
                  (bat (concat ver "/BuildTools/VC/Auxiliary/Build/vcvarsall.bat")))
             (when (file-exists-p bat) bat)))))))


(platform-supported-when windows-nt

  (defun make-cc-env-bat ()
    "Make cc-env.bat in `exec-path'."
    (let ((vcvarsall (check-vcvarsall-bat))
          (arch (downcase (getenv "PROCESSOR_ARCHITECTURE"))))
      (when vcvarsall
        (save-str-to-file 
         (concat "@echo off\n"
                 "rem generated by More Reasonable Emacs https://github.com/junjiemars/.emacs.d\n\n"
                 "pushd %cd%\n"
                 "cd /d \"" (file-name-directory vcvarsall) "\"\n"
                 "\n"
                 "call vcvarsall.bat " arch "\n"
                 "set CC=cl" "\n"
                 "set AS=ml" (if (string-match "[_a-zA-Z]*64" arch) "64" "") "\n"
                 "\n"
                 "popd\n"
                 "echo \"%INCLUDE%\"\n")
         (v-home% ".exec/cc-env.bat"))))))


(defun check-cc-include ()
  "Return cc include paths list."
  (platform-supported-if windows-nt
      ;; Windows: msvc
      (let ((cmd (shell-command* (make-cc-env-bat))))
        (when (zerop (car cmd))
          (mapcar (lambda (x) (windows-nt-posix-path x))
                  (var->paths
                   (car (nreverse 
                         (split-string* (cdr cmd) "\n" t "\"")))))))
    ;; Darwin/Linux: clang or gcc
    (let ((cmd (shell-command* "echo '' | cc -v -E 2>&1 >/dev/null -")))
      (when (zerop (car cmd))
        (take-while
         (lambda (p)
           (string-match "End of search list." p))
         (drop-while
          (lambda (p)
            (string-match "#include <...> search starts here:" p))
          (split-string* (cdr cmd) "\n" t "[ \t\n]")))))))


(defvar system-cc-include nil
  "The system include paths used by C compiler.

This should be set with `system-cc-include'")


(defun system-cc-include (&optional cached)
  "Returns a list of system include directories. 

Load `system-cc-include' from file when CACHED is t, 
otherwise check cc include on the fly."
  (let ((c (v-home% "config/.cc-inc.el")))
    (if (and cached (file-exists-p (concat c "c")))
        (progn
          (load (concat c "c"))
          system-cc-include)
      (let ((paths (platform-supported-if darwin
                       (mapcar (lambda (x)
                                 (string-trim> x " (framework directory)"))
                               (check-cc-include))
                     (check-cc-include))))
        (when (save-sexp-to-file
               `(setq system-cc-include ',paths) c)
          (byte-compile-file c))
        (setq system-cc-include paths)))))



(provide 'cc)

调用 system-cc-include 函数应该返回系统包含路径列表:

(defun set-semantic-cc-env! (&optional project-includes project-roots preprocessors)
    "Use `semantic-mode' in`c-mode'.

PROJECT-INCLUDES specify C include directories
via `semantic-add-system-include',
check it by `semantic-dependency-system-include-path'.'

PROJECT-ROOTS specify C project root directories
via `semanticdb-_project-roots'.

PREPROCESSORS specify C preprocessors
via `semantic-lex-c-preprocessor-symbol-map'

Use `semantic-c-describe-environment' to describe the current C environment."
    (semantic-reset-system-include 'c-mode)

    (dolist (x (append (when-fn% system-cc-include cc
                         (system-cc-include t))
                       project-includes))
      (semantic-add-system-include x 'c-mode))

    (setq% semanticdb-project-roots project-roots semantic/db)

    (when-fn% global-semantic-idle-summary-mode semantic
      (global-semantic-idle-summary-mode))

    (when-fn% semantic-ia-fast-jump semantic
      (define-key semantic-mode-map (kbd "C-c , f") #'semantic-ia-fast-jump))

    (when-fn% semantic-ia-complete-symbol semantic
      (define-key semantic-mode-map (kbd "C-c , TAB") #'semantic-ia-complete-symbol))

    (setq% semantic-lex-c-preprocessor-symbol-map
           preprocessors semantic/bovine/c)))

关于c++ - Emacs 语义无法在 Windows 上正确解析文件，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/45416526/