基本上我想要实现的是当用户在应用程序的某个部分根据需要更改屏幕旋转时，我已经为 Andriod 工作，但我不明白为什么它不应该为 iOS 工作

procedure TForm1.Button1Click(Sender: TObject);
var
  ScreenService: IFMXScreenService;
  OrientSet: TScreenOrientations;
begin
    if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 
    then
    begin
        OrientSet := [TScreenOrientation.soLandscape];//<- Break point set here and line is executed
        ScreenService.SetScreenOrientation(OrientSet);
    end;
end;

取自此处:How to prevent screen rotation with android development in delphi xe5 Firemonkey

ScreenService.SetScreenOrientation 被执行并且没有引发异常但方向没有改变，我还在 Project>Options>Application>Orientation 中设置了 Enable custom orientation 但这也没有有什么影响。

令我感到奇怪的是，如果它不受支持，那么这不应该吗

if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 

返回错误？甚至不输入开始

我添加了一个测试按钮来检查屏幕方向后我将它设置为仅横向

if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 
then
begin
    case ScreenService.GetScreenOrientation of
        TScreenOrientation.Portrait: ShowMessage('Portrait');
        TScreenOrientation.Landscape: ShowMessage('landscape');
        TScreenOrientation.InvertedPortrait: ShowMessage('Inverted-Portrait');
        TScreenOrientation.InvertedLandscape: ShowMessage('Inverted-Landscape');
        else ShowMessage('not set');
    end;
end;

如果它在设置为横向后是纵向的，它仍然显示纵向

更新 1 :我也试过改变

OrientSet := [TScreenOrientation.soLandscape] // <- Deprecated

到

OrientSet := [TScreenOrientation.Landscape]

但是行为还是一样

最佳答案

好的，这次轮换让我深入研究了 iOS API 以弄清楚 iOS 如何管理方向。

因为你不能在 iOS 中伪造旋转或强制设备某些设备方向 在 iOS 中你有很多方向需要考虑

• 设备方向
• 状态栏方向
• UIViewcontroller 方向

不能强制或更改设备方向，这将始终显示您的设备当前的方向。

然而，状态栏方向始终具有 setStatusBarOrientation 过程，您可以调用并指定您想要的方向，但这被标记为已弃用，因此无法正常工作，但我没有得到当我调用该函数时出现外部异常，表明它仍然存在，只是无法正常工作。

然后我读了这个:

The setStatusBarOrientation:animated: method is not deprecated outright. It now works only if the supportedInterfaceOrientations method of the top-most full-screen view controller returns 0

然后我决定试试这个

Application.FormFactor.Orientations := []; //the supportedInterfaceOrientations returns 0
App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
win := TUIWindow.Wrap(App.windows.objectAtIndex(0));
App.setStatusBarOrientation(UIInterfaceOrientationLandscapeLeft);

它可以改变状态栏方向，但如上所述，该协议(protocol)已被弃用，因此在某个阶段它可能/将会消失，这将不再有效。

但这只是改变了状态栏和所有警报 View 等的旋转，但在我想要更改为横向的情况下，rootviewcontroller 中的实际内容仍在纵向中。

然后我想如果我在 Delphi 中会去 Application->Orientation->Enable custom rotation 并说 landscape only 然后应用程序将只显示在 landscape 中，它做得很好，因为当创建表单然后 rootViewcontroller 是使返回的 supportedInterface 方向仅为横向，Viewcontroller 变为横向。

因为当您的设备更改设备方向时，将根据 Viewcontroller 支持的界面方向评估方向，如果不支持方向，则不会旋转。

但是，当分配了一个新的 rootviewcontroller 时，GUI 必须更新以显示在该 Viewcontrollers 支持的方向上，考虑到这一点，这是我的修复/技巧，可以将您的应用程序的方向更改为您想要的方向。

长话短说

Uses: iOSapi.UIKit; 

procedure ChangeiOSorientation(toOrientation: UIInterfaceOrientation;
possibleOrientations: TScreenOrientations);
var
    win : UIWindow;
    App : UIApplication;
    viewController : UIViewController;
    oucon: UIViewController;
begin
    Application.FormFactor.Orientations := []; //Change supported orientations
    App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
    win := TUIWindow.Wrap(App.windows.objectAtIndex(0)); //The first Windows is always the main Window

    App.setStatusBarOrientation(toOrientation);
    {After you have changed your statusbar orientation set the
    Supported orientation/orientations to whatever you need}
    Application.FormFactor.Orientations := possibleOrientations;
    viewController := TUIViewController.Wrap(TUIViewController.alloc.init);//dummy ViewController
    oucon := TUIViewController.Wrap(TUIViewController.alloc.init);
    {Now we are creating a new Viewcontroller now when it is created
     it will have to check what is the supported orientations}
    oucon := win.rootViewController;//we store all our current content to the new ViewController
    Win.setRootViewController(viewController);
    Win.makeKeyAndVisible;// We display the Dummy viewcontroller

    win.setRootViewController(oucon);
    win.makeKeyAndVisible; 
    {And now we Display our original Content in a new Viewcontroller 
     with our new Supported orientations} 
end;

您现在要做的就是调用 ChangeiOSorientation(toOrientation,possibleOrientations)

如果你想让它变成纵向但有横向选项

 ChangeiOSorientation(UIInterfaceOrientationPortrait,[TScreenOrientation.Portrait,TScreenOrientation.Landscape,TScreenOrientation.InvertedLandscape]);    

正在处理

• 西雅图德尔福 10 号
• 运行 iOS 9.0 的 iPhone 5
• PA 服务器 17.0
• Xcode 7.1
• iPhoneOS 9.1 SDK

关于ios - Delphi/Firemonkey 在运行时更改 iOS 屏幕旋转，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/33387402/