我正在使用 XSLT 将 XML 转换为 XML，目标是读取标签 <node1> 的值, 如果它为 null 则必须为其分配值 <node2> , 如果柜面 <node2> , 也为 null，则必须将默认文本“Default”分配给 .. 两个标签 ..
编辑如果<node2>为空且 <node1>不是 .. 那么代码不应该更新 <node2>与 'Default'文本，但必须按原样进行转换..

这是我正在尝试的测试 XML:

<root>
    <node1></node1>
    <node2></node2>
  <parent>
    <node1>data1</node1>
    <node2></node2>
  </parent>
  <parent>
    <node1></node1>
    <node2>data2</node2>
  </parent>
  <parent>
    <node1>data1</node1>
    <node2>data2</node2>
  </parent>
</root>

这是我设计的 XSLT 代码:

   <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
  <xsl:template name="template1" match="node2[(following-sibling::node1[.='']|preceding-sibling::node1[.=''])]">
    <xsl:choose>
      <xsl:when test=".=''">
        <node1><xsl:text>Default</xsl:text></node1>
        <node2><xsl:text>Default</xsl:text></node2>
      </xsl:when>
      <xsl:otherwise>
        <node1>
          <xsl:value-of select="text()"/>
        </node1>
        <xsl:copy>
          <xsl:apply-templates select="node()"/>
        </xsl:copy>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="template2" match="node1[.='']"/>

虽然我的代码有效，但我对其庞大的代码不满意。是否有办法去除多余的(如果有的话)行....是否有其他方法可以使用 2 个模板来完成此操作(即template1和template2)，是否可以减少模板的数量？

最佳答案

我。 XSLT 1.0 解决方案:

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:variable name="vReplacement">Default</xsl:variable>

       <xsl:variable name="vRep" select=
        "document('')/*/xsl:variable[@name='vReplacement']/text()"/>

     <xsl:template match="node()|@*">
        <xsl:copy>
          <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
     </xsl:template>

     <xsl:template match="node1[not(node())] | node2[../node1[not(node())]]">
      <xsl:copy>
          <xsl:copy-of select="../node2/text() | $vRep[not(current()/../node2/text())]"/>
      </xsl:copy>
     </xsl:template>
</xsl:stylesheet>

它比当前的解决方案更短、更简单 -- 比当前选择的解决方案少 7 行，更重要的是，少一个模板。

更重要的是，这个解决方案是完全声明式和推送式的——没有调用命名模板，唯一的 <xsl:apply-templates>在身份规则中。

二。 XSLT 2.0 解决方案

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
        <xsl:copy>
          <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
 </xsl:template>

 <xsl:template match="node1[not(node())] | node2[../node1[not(node())]]">
  <xsl:copy>
      <xsl:sequence select="(../node2/text(), 'Default')[1]"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

利用 XPath 2.0 序列的强大功能，此解决方案比 XSLT 1.0 解决方案短得多。

类似的东西在 XSLT 1.0 中是不可能的(例如选择两个节点并集的第一个而不指定谓词以使两个节点互斥)，因为具有默认文本的节点和node1/node2 节点属于不同的文档，众所周知，不同文档的节点之间的节点顺序是特定于实现的，无法保证/规定。

这个解决方案是完全声明式的(没有 if/then/else)并且完全是推送式:唯一的 <xsl:apply-templates>在身份规则中。

关于xml - (XSLT，代码优化)如何输出引用兄弟节点值的节点..？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/2287740/