编辑:我几乎没有对问题进行编辑，最后描述了问题的原因。

我已经使用 Inno 构建了一个设置。执行开始的主文件是一个 vbs 文件。我已将 Inno 设置为使用自定义图标在桌面上创建快捷方式。但是安装后快捷方式给出了文件丢失的vbs错误。如果我转到主 vbs 文件并直接运行或在桌面上手动创建该 vbs 文件的另一个快捷方式，我可以多次运行该快捷方式。那么问题出在哪里。是 Inno 的问题还是某些脚本问题。

这是 vbs 脚本(它的目的是启动一个批处理文件，但在打开批处理命令时不显示 cmd 窗口)

Set WshShell = CreateObject("WScript.Shell") 
WshShell.Run chr(34) & "run.bat" & Chr(34), 0
Set WshShell = Nothing

我不会vbs，这个脚本在网上流传。所以如果脚本有什么明显的问题，请帮我改正。

我得到的确切错误是:

Script: C:\Admin\start.vbs
Line:   2
Char:   1
Error:  The system cannot find the file specified.
Code:   80070002
Source: (null)

这是我在 Inno 中使用的脚本

  ; Script generated by the Inno Setup Script Wizard.
  ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

  [Setup]
  ; NOTE: The value of AppId uniquely identifies this application.
  ; Do not use the same AppId value in installers for other applications.
  ; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
  AppName=Test
  AppVersion=1.0
  AppVerName=Test 1.0
  AppPublisher=USV
  DefaultDirName=C:\Test
  DisableDirPage=yes
  DefaultGroupName=Test
  DisableProgramGroupPage=yes
  OutputDir=C:\Users\Ashu\Desktop
  OutputBaseFilename=Test
  SetupIconFile=C:\Test\logo2.ico
  Compression=lzma
  SolidCompression=yes
  ; "ArchitecturesAllowed=x64" specifies that Setup cannot run on
  ; anything but x64.
  ArchitecturesAllowed=x64
  ; "ArchitecturesInstallIn64BitMode=x64" requests that the install be
  ; done in "64-bit mode" on x64, meaning it should use the native
  ; 64-bit Program Files directory and the 64-bit view of the registry.
  ArchitecturesInstallIn64BitMode=x64

  [Languages]
  Name: "english"; MessagesFile: "compiler:Default.isl"

  [Tasks]
  Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

  [Files]
  Source: "C:\Test\start.vbs"; DestDir: "{app}"; Flags: ignoreversion
  Source: "C:\Test\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
  ; NOTE: Don't use "Flags: ignoreversion" on any shared system files

  [Icons]
  Name: "{group}\Test"; Filename: "{app}\start.vbs"; IconFilename: {app}\logo2.ico;
  Name: "{group}\{cm:UninstallProgram,Test}"; Filename: "{uninstallexe}"; IconFilename: {app}\logo2.ico;
  Name: "{commondesktop}\Test"; Filename: "{app}\start.vbs"; Tasks: desktopicon; IconFilename: {app}\logo2.ico;

  [Run]
  Filename: "{app}\importstarter.bat";
  Filename: "{app}\start.vbs"; Description: "{cm:LaunchProgram,Test}"; Flags: shellexec postinstall skipifsilent

编辑: 我已经更新了与问题非常相似的脚本。问题的原因是在快捷方式属性中，设置了目标属性，但属性中的开始设置为空白。将其更正到所需目录即可解决问题。程序在第一次尝试时运行，因为安装程序直接从主文件而不是快捷方式运行。所以这一定是Inno Script的问题。

最佳答案

您的问题是由于缺少特定的工作/当前路径和使用相对路径引起的。

当 vbs 文件运行时，工作/当前目录将是安装程序的目录，c:\Windows\, j:\MyData\等。当它试图运行run.bat时，在当前目录下找不到它，导致“系统找不到指定的文件”。来自脚本引擎的错误。

解决这个问题的最好方法是强制运行脚本的当前目录到包含它的文件夹。 (我不知道该怎么做)

或者，您可以在快捷方式和 [Run] 条目上设置当前目录:

[Icons]
Name: "{group}\Test"; Filename: "{app}\start.vbs"; IconFilename: {app}\logo2.ico; WorkingDir: "{app}";
Name: "{group}\{cm:UninstallProgram,Test}"; Filename: "{uninstallexe}"; IconFilename: {app}\logo2.ico;
Name: "{commondesktop}\Test"; Filename: "{app}\start.vbs"; Tasks: desktopicon; IconFilename: {app}\logo2.ico; WorkingDir: "{app}";

[Run]
Filename: "{app}\importstarter.bat"; WorkingDir: "{app}";
Filename: "{app}\start.vbs"; WorkingDir: "{app}"; Description: "{cm:LaunchProgram,Test}"; Flags: shellexec postinstall skipifsilent

您也可以将它放在批处理文件的顶部，这样它们就不需要特定的当前目录:

cd /d %~dp0

请注意，最近 ( since 2010 ) 版本的 Inno Setup 会强制设置工作目录以防止出现此错误。

关于windows - inno setup创建的vb脚本快捷方式出错，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/25107788/