我有一个结构非常简单的 Jenkins Multijob 项目:

• 兼职
  • 童工 1
  • 打工 2
  • 打工 3
  • 童工 4 等...

我想按如下方式设置Multijob状态:

• 如果所有子作业都通过，我想要一个绿球
• 如果有任何被跳过或 < 25%="">
• 如果 >= 25% 失败，我想要一个红球

我知道我可以将 Groovy 后期构建操作与如下脚本一起使用，但我不知道如何设置所需的阈值级别:

void log(msg) {
manager.listener.logger.println(msg)
}

threshold = Result.SUCCESS

void aggregate_results() {
    failed = false

    mainJob = manager.build.getProject().getName()
    job = hudson.model.Hudson.instance.getItem(mainJob)

    log '-------------------------------------------------------------------------------------'
    log 'Aggregated status report'
    log '-------------------------------------------------------------------------------------'

log('${mainJob}    #${manager.build.getNumber()} - ${manager.build.getResult()}')

job.getLastBuild().getSubBuilds().each { subBuild->
  subJob = subBuild.getJobName() 
  subJobNumber = subBuild.getBuildNumber()
  job = hudson.model.Hudson.instance.getItem(subBuild.getJobName())
  log '${subJob}   #${subJobNumber} - ${job.getLastCompletedBuild().getResult()}'
  log job.getLastCompletedBuild().getLog()

  //println subBuild
  dePhaseJob = hudson.model.Hudson.instance.getItem(subBuild.getJobName())
  dePhaseJobBuild = dePhaseJob.getBuildByNumber(subBuild.getBuildNumber())
  dePhaseJobBuild.getSubBuilds().each { childSubBuild ->
    try {
        log '   ${childSubBuild.jobName}'

        job = hudson.model.Hudson.instance.getItem(childSubBuild.getJobName())
        build = job.getBuildByNumber(childSubBuild.getBuildNumber())

        indent = '  '    
        log '${indent} #${build.getNumber()}  - ${build.getResult()}' 
        log build.getLog()

        if(!failed && build.getResult().isWorseThan(threshold) ) {
          failed = true
        }
    } catch (Exception e) {    
        log('ERROR: ${e.getMessage()}')
        failed = true
    }
  }
}

if(failed) {manager.build.setResult(hudson.model.Result.FAILURE)}
}

try {
  aggregate_results()
} catch(Exception e) {
  log('ERROR: ${e.message}')
  log('ERROR: Failed Status report aggregation')
  manager.build.setResult(hudson.model.Result.FAILURE)
}

任何人都可以帮助调整脚本来实现我需要的吗？

最佳答案

不确定这是否真的可以作为答案。可能更像是评论，但评论并不真正适合长代码片段，所以这里是。

为了使您的代码更具可读性和更容易理解，我做了以下操作:

• 用常规属性访问替换了 getXX 和 setYY 的所有实例，例如 build.getResult() 变成了 build.result
• 删除了函数调用中不必要的括号使用，例如log('ERROR: ${e.getMessage()}') 变为 log 'ERROR: ${e.getMessage()}'
• 将单引号中的字符串插值替换为双引号，因为字符串插值在单引号中不起作用。例如。 log 'ERROR: ${e.message}' 变为 log "ERROR: ${e.message}"
• 从声明脚本全局绑定(bind)范围中的所有变量切换到本地，例如subJob = ... 变为 def subJob = ...。在全局范围内声明所有内容会导致难以发现问题，尤其是当您重复使用 job 等变量名时。

我也清理了一些冗余，一个例子:

job.getLastBuild().getSubBuilds().each { subBuild->
  subJob = subBuild.getJobName() 
  subJobNumber = subBuild.getBuildNumber()
  job = hudson.model.Hudson.instance.getItem(subBuild.getJobName())  // <---
  ...
  //println subBuild
  dePhaseJob = hudson.model.Hudson.instance.getItem(subBuild.getJobName()) // <---
  dePhaseJobBuild = dePhaseJob.getBuildByNumber(subBuild.getBuildNumber())

所以在这里我们将 job 和 dePhaseJob 设置为相同的值。像这样将相同的值分配给两个单独的变量是多余的，只会使代码更难阅读。

此外(我对 jenkins 内部 api 并不十分熟悉，所以我在这里可能是错误的)上面代码中的以下流程似乎不正确:

• 我们有 subBuild 实例
• 然后我们将相应的作业实例检索到 job 和 dePhaseJob
• 然后我们使用 dePHaseJob.getBuildByNumber(subBuild.buildNumer)
将构建检索到 dePhaseJobBuild

但这不是给我们留下了 subBuild == dePhaseJobBuild 吗？ IE。我们用了所有这些代码只是为了检索我们已经拥有的值。我们从构建到工作再回到构建。除非我在 jenkins api 中遗漏了一些深奥的东西，否则这似乎也多余。

通过所有这些更改和其他一些小的更改，我们得到了以下代码:

def job(name) {
  hudson.model.Hudson.instance.getItem(name) 
}

def aggregateResults() {
  def mainJobName = manager.build.project.name
  log '-------------------------------------------------------------------------------------'
  log 'Aggregated status report'
  log '-------------------------------------------------------------------------------------'
  log "${mainJobName}    #${manager.build.number} - ${manager.build.result}"

  def failed = false
  job(mainJobName).lastBuild.subBuilds.each { subBuild ->
    log "${subBuild.jobName}   #${subBuild.buildNumber} - ${subBuild.result}"
    log subBuild.log

    subBuild.subBuilds.each { subSubBuild ->
      try {
        log "   ${subSubBuild.jobName}   #${subSubBuild.buildNumber} - ${subSubBuild.result}"
        log "   " + subSubBuild.getLog(Integer.MAX_VALUE).join("\n   ") //indent the log lines

        if(!failed && subSubBuild.result.isWorseThan(threshold)) {
          failed = true
        }
      } catch (Exception e) {
        log "ERROR: ${e.message}"
        failed = true
      }
    }
  }

  if(failed) {
    manager.build.result = hudson.model.Result.FAILURE
  }
}

再一次，我没有 jenkins 实例来测试它，所以我在黑暗中飞行，并提前为拼写错误、语法错误或其他滥用代码和 jenkins api 的行为道歉。

您的代码中的问题(例如我看不到的字符串插值问题)让我认为原始代码不起作用，而是一个示例模式。

这让我进一步怀疑你是否真的需要在这里做两层嵌套，即如下:

job(mainJobName).lastBuild.subBuilds.each { subBuild ->
  subBuild.subBuilds.each { subSubBuild ->
    ...
  }
}

真的有必要还是一级就够了？从您问题中的快速图表看来，我们似乎只需要关心主要工作及其子工作，而不是子工作。

如果是这种情况，您可以按照以下逻辑行事:

def aggregateResults() {
  def mainJob = job(manager.build.project.name)
  def subs    = mainJob.lastBuild.subBuilds
  def total   = subs.size()
  def failed  = subs.findAll { sub -> sub.result.isWorseThan(threshold) }.size()

  if(failed > 0) {
    manager.build.result = hudson.model.Result.FAILURE
  }

  failed == 0 ? "green" : (failed/total < 0.25 ? "yellow" : "red")
}

关于java - 使用基于百分比通过/失败子作业的 Groovy 脚本设置 Jenkins 多作业构建结果，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/49259603/