我正在使用 ant 任务“junit”和“junitreport”来运行我的 JUnit 测试并在最后生成报告(=>“单元测试结果”)。

是否有一些简单的方法可以以某种方式扩展此输出以在报告中显示更多信息？例如，添加一个附加列，其中包含指向测试截取的屏幕截图的链接。

我看到有人可以编写自己的 ant junit 测试运行程序，例如 EclipseTestRunner。 但这是相当大的努力。是否没有 API 可以访问单元报告的元素？

最佳答案

junitreport 任务使用 XSLT从 junit 生成的 XML 文件生成报告任务。

您可以通过使用 styledir 指定您自己的 XSLT 来自定义输出。嵌套 report 的属性元素:

<!-- use reportstyle/junit-frames.xsl to produce the report -->
<report styledir="reportstyle" format="frames" todir="testreport"/>

要自定义输出，一种选择是复制 default XSLT并修改它。或者，您可以寻找更容易根据您的目的进行定制的替代 XSLT。

对于小的更改，最简单的方法是导入默认 XSLT 并覆盖您需要自定义的任何模板。例如，要为每个测试添加一列，您需要覆盖生成表头的模板和生成表行的模板。下面，我刚刚复制了这些模板并对其进行了一些修改以添加一列(查找标记为 <!-- ADDED --> 的两个添加项)。

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- import the default stylesheet -->
  <xsl:import href="jar:file:lib/ant-junit.jar!/org/apache/tools/ant/taskdefs/optional/junit/xsl/junit-frames.xsl"/>

  <!-- override the template producing the test table header --> 
  <xsl:template name="testcase.test.header">
    <xsl:param name="show.class" select="''"/>
    <tr valign="top">
      <xsl:if test="boolean($show.class)">
        <th>Class</th>
      </xsl:if>
      <th>Name</th>
      <th>Status</th>
      <th width="80%">Type</th>
      <th nowrap="nowrap">Time(s)</th>

      <!-- ADDED -->
      <th>Screenshot</th>

    </tr>
  </xsl:template>

  <!-- override the template producing a test table row -->
  <xsl:template match="testcase" mode="print.test">
    <xsl:param name="show.class" select="''"/>
    <tr valign="top">
      <xsl:attribute name="class">
        <xsl:choose>
          <xsl:when test="error">Error</xsl:when>
          <xsl:when test="failure">Failure</xsl:when>
          <xsl:otherwise>TableRowColor</xsl:otherwise>
        </xsl:choose>
      </xsl:attribute>
      <xsl:variable name="class.href">
        <xsl:value-of select="concat(translate(../@package,'.','/'), '/', ../@id, '_', ../@name, '.html')"/>
      </xsl:variable>
      <xsl:if test="boolean($show.class)">
        <td><a href="{$class.href}"><xsl:value-of select="../@name"/></a></td>
      </xsl:if>
      <td>
        <a name="{@name}"/>
        <xsl:choose>
          <xsl:when test="boolean($show.class)">
            <a href="{concat($class.href, '#', @name)}"><xsl:value-of select="@name"/></a>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="@name"/>
          </xsl:otherwise>
        </xsl:choose>
      </td>
      <xsl:choose>
        <xsl:when test="failure">
          <td>Failure</td>
          <td><xsl:apply-templates select="failure"/></td>
        </xsl:when>
        <xsl:when test="error">
          <td>Error</td>
          <td><xsl:apply-templates select="error"/></td>
        </xsl:when>
        <xsl:otherwise>
          <td>Success</td>
          <td></td>
        </xsl:otherwise>
      </xsl:choose>
      <td>
        <xsl:call-template name="display-time">
          <xsl:with-param name="value" select="@time"/>
        </xsl:call-template>
      </td>

      <!-- ADDED -->
      <td>
        <a href="link/to/screenshot/for/test/{@name}">screenshot</a>
      </td>

    </tr>
  </xsl:template>

</xsl:stylesheet>

结果如下所示:

关于java - 自定义 JUnit 报告？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/1727616/