我是 php 新手，想从命令行运行 php。我已经安装了 WAMP 并将“系统变量”设置为我的 php 文件夹(即 C:\wamp\bin\php\php5.4.3)。

当我转到 Run -> CMD -> 输入 php -a 并按回车键时，它说 interactive mode enabled 。但是当我写 echo 'Hi'; 它什么也没显示。

当我输入 php -a 并按回车键时，我什至看不到任何类似“php >”的内容。

最佳答案

PHP CLI(命令行界面的 php)称为 php.exe 它位于 c:\wamp\bin\php\php5.x.y\php.exe (其中 x 和 y 是您安装的 php 的版本号)

如果您想创建 php 脚本以从命令行运行，那么它非常简单且非常有用。

自己创建一个像这样的批处理文件，我们称之为 phppath.cmd :

PATH=%PATH%;c:\wamp\bin\php\phpx.y.z
php -v

将 x.y.z 更改为您在 WAMPServer 中安装的 PHP 版本的有效文件夹名称

将其保存到 PATH 中已经存在的文件夹中，以便您可以从任何地方运行它。

现在从命令窗口，cd 进入你的源文件夹并运行 >phppath。

然后运行

php your_script.php

它应该像梦一样工作。

这是一个配置 PHP Composer 和 PEAR 的示例(如果需要并且它们存在)

@echo off

REM **************************************************************
REM * PLACE This file in a folder that is already on your PATH
REM * Or just put it in your C:\Windows folder as that is on the
REM * Search path by default
REM * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
REM * EDIT THE NEXT 3 Parameters to fit your installed WAMPServer
REM **************************************************************


set baseWamp=D:\wamp
set defaultPHPver=7.4.3
set composerInstalled=%baseWamp%\composer
set phpFolder=\bin\php\php

if %1.==. (
    set phpver=%baseWamp%%phpFolder%%defaultPHPver%
) else (
    set phpver=%baseWamp%%phpFolder%%1
)

PATH=%PATH%;%phpver%
php -v
echo ---------------------------------------------------------------


REM IF PEAR IS INSTALLED IN THIS VERSION OF PHP

IF exist %phpver%\pear (
    set PHP_PEAR_SYSCONF_DIR=%baseWamp%%phpFolder%%phpver%
    set PHP_PEAR_INSTALL_DIR=%baseWamp%%phpFolder%%phpver%\pear
    set PHP_PEAR_DOC_DIR=%baseWamp%%phpFolder%%phpver%\docs
    set PHP_PEAR_BIN_DIR=%baseWamp%%phpFolder%%phpver%
    set PHP_PEAR_DATA_DIR=%baseWamp%%phpFolder%%phpver%\data
    set PHP_PEAR_PHP_BIN=%baseWamp%%phpFolder%%phpver%\php.exe
    set PHP_PEAR_TEST_DIR=%baseWamp%%phpFolder%%phpver%\tests

    echo PEAR INCLUDED IN THIS CONFIG
    echo ---------------------------------------------------------------
) else (
    echo PEAR DOES NOT EXIST IN THIS VERSION OF php
    echo ---------------------------------------------------------------
)

REM IF A GLOBAL COMPOSER EXISTS ADD THAT TOO
REM **************************************************************
REM * IF A GLOBAL COMPOSER EXISTS ADD THAT TOO
REM *
REM * This assumes that composer is installed in /wamp/composer
REM *
REM **************************************************************
IF EXIST %composerInstalled% (
    ECHO COMPOSER INCLUDED IN THIS CONFIG
    echo ---------------------------------------------------------------
    set COMPOSER_HOME=%baseWamp%\composer
    set COMPOSER_CACHE_DIR=%baseWamp%\composer

    PATH=%PATH%;%baseWamp%\composer

    rem echo TO UPDATE COMPOSER do > composer self-update
    echo ---------------------------------------------------------------
) else (
    echo ---------------------------------------------------------------
    echo COMPOSER IS NOT INSTALLED
    echo ---------------------------------------------------------------
)

set baseWamp=
set defaultPHPver=
set composerInstalled=
set phpFolder=
set phpver=
set phpFolder=

像这样调用这个命令文件来使用PHP的默认版本

> phppath

或者像这样获取特定版本的PHP

> phppath 5.6.30

关于php - 如何在 WAMPServer 中从 Windows 命令行运行 PHP，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/15597067/