我目前已经设法让我的 LED 循环显示我选择的八种颜色。一切正常，除了我想要一种更自然的感觉，并希望从一种颜色淡出/过渡到另一种颜色，而不是让它们只是相互替换。

到目前为止，这是我的代码:

int redPin = 11;
int greenPin = 10;
int bluePin = 9;

void setup()
{
    pinMode(redPin, OUTPUT);
    pinMode(greenPin, OUTPUT);
    pinMode(bluePin, OUTPUT);
}

void loop()
{
    setColor(250, 105, 0);   // Yellow
    delay(1000);

    setColor(250, 40, 0);    // Orange
    delay(1000);

    setColor(255, 0, 0);     // Red
    delay(1000);

    setColor(10, 10, 255);   // Blue
    delay(1000);

    setColor(255, 0, 100);   // Pink
    delay(1000);

    setColor(200, 0, 255);   // Purple
    delay(1000);

    setColor(0, 255, 0);     // Green
    delay(1000);

    setColor(255, 255, 255); // White
    delay(1000);
}

void setColor(int red, int green, int blue)
{
    analogWrite(redPin, 255-red);
    analogWrite(greenPin, 255-green);
    analogWrite(bluePin, 255-blue);
}

最佳答案

关于这个话题，其他答案忽略的事实是人类对光强度的感知是 logarithmic, not linear . analogWrite() 例程正在设置输出引脚的 PWM占空比，并且是线性的。因此，通过采用最小占空比(比如 0)和最大占空比(比如，为了简单的数学，这是 10)并将其分成相等的 block ，你将控制强度线性，这不会产生令人满意的结果。

您需要做的是以指数方式设置您的强度。假设您的最大强度是 255。您可以通过将强度视为提高某个数字的力量来产生此结果。在我们的例子中，考虑到我们正在处理喜欢二进制的计算机，2 的幂很方便。所以，

2^0 =1
2^8=256

所以我们可以有 8 个强度级别。实际上，请注意最小值现在没有完全关闭(它是 1 而不是 0)并且我们的最大值超出了范围(256 不是 255)。所以我们修改公式为

output = 2 ^ intensity - 1

或者在代码中

int output = 1<<intensity - 1;

对于从 0 到 8(含)的强度级别，这会产生从 0 到 255 的值，因此我们实际上得到了九个强度级别。如果您想要更平滑的过渡(即更多级别的强度)，并且仍然使用对数强度，您将需要 float 学。

如果您将这种计算强度的方法应用于每个 channel (R、G、B)，那么您的感知将与您的代码所说的一致。

至于如何在各种颜色之间平滑过渡，答案取决于您希望如何导航颜色空间。最简单的做法是将色彩空间想象成一个三角形，以 R、G 和 B 为顶点:

接下来的问题是如何导航这个三角形:你可以沿着边走，从 R 到 G，再到 B。这样你就永远不会看到白色(所有 channel 完全打开)或“黑色”(所有 channel 完全关闭) ).您可以将色彩空间想象成一个六边形，具有额外的紫色 (R+B)、黄色 (G+B) 和棕色 (R+G) 颜色，并且还可以在周边导航(同样，没有白色或黑色)。衰落的可能性与在这些以及我们可能想到的其他数字中导航的方式一样多。

当我构建这样的褪色程序时，我喜欢的颜色空间和遍历如下:将每个 channel 视为一个二进制位，所以现在你有三个(R、G 和 B)。如果您认为每种颜色都有这些 channel 的某种组合完全打开，那么您将得到 7 种颜色(不包括黑色，但包括白色)。选择这些颜色中的第一种，从黑色逐渐变回黑色，然后转到下一种颜色。这是一些执行类似操作的代码:

int targetColor = 1;
int nIntensity = 0;
int nDirection = 1;         // When direction is 1 we fade towards the color (fade IN)
                            // when 0 we fade towards black (fade OUT)
#define MAX_INTENSITY 8
#define MIN_INTENSITY 0
#define MAX_TARGETCOLOR 7

void loop() {
    for (;;) {

        // Update the intensity value
        if (nDirection) {
            // Direction is positive, fading towards the color
            if (++nIntensity >= MAX_INTENSITY) {
                // Maximum intensity reached
                nIntensity = MAX_INTENSITY;  // Just in case
                nDirection = 0;             // Now going to fade OUT
            } // else : nothing to do
        } else {
            if (--nIntensity <= MIN_INTENSITY) {
                nIntensity = MIN_INTENSITY; // Just in case
                // When we get back to black, find the next target color
                if (++targetColor>MAX_TARGETCOLOR) 
                    targetColor=1;          // We'll skip fading in and out of black
                nDirection = 1;             // Now going to fade IN
            } // else: nothing to do
        }

        // Compute the colors
        int colors[3];
        for (int i=0;i<3;i++) {
            // If the corresponding bit in targetColor is set, it's part of the target color
            colors[i] = (targetColor & (1<<i)) ? (1<<nIntensity) -1 : 0;
        }

        // Set the color
        setColor(colors[0], colors[1], colors[2]);

        // Wait
        delay(100);     
    }
}

关于c++ - 将 Arduino RGB LED 从一种颜色褪色到另一种颜色？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/15803986/