我正在尝试了解有关 QtQuick 和 QML 的更多信息。我当前的目标是了解如何将数据从 C++ 模型绑定(bind)到我的 View 。到目前为止，我已经能够在我的 QML 中设置模型并从模型中获取数据，但我不知道如何更新我的数据。

如何为我的 C++ 模型设置双向绑定(bind)？以下是我到目前为止编写的代码。

message.h

class Message : public QObject
{
    Q_OBJECT

    Q_PROPERTY(QString author READ getAuthor WRITE setAuthor NOTIFY authorChanged)
    Q_PROPERTY(QString message READ getMessage WRITE setMessage NOTIFY messageChanged)

    Q_SIGNALS:
        void authorChanged(QString author);
        void messageChanged(QString message);

    public:
        Message(QObject *parent = 0);

        QString getAuthor();
        void setAuthor(QString author);

        QString getMessage();
        void setMessage(QString message);

    private:
        QString _author;
        QString _message;
};

消息.cpp

#include "message.h"

Message::Message(QObject *parent) : QObject(parent)
{
}

QString Message::getAuthor()
{
    return _author;
}

void Message::setAuthor(QString author)
{
    if(author != _author)
    {
        _author = author;
        emit authorChanged(author);
    }
}

QString Message::getMessage()
{
    return _message;
}

void Message::setMessage(QString message)
{
    if(message != _message)
    {
        _message = message;
        emit messageChanged(message);
    }
}

ma​​in.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0
import com.butts.messaging 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: "Test"

    Message {
        id: testMessage
        author: "Batman"
        message: "Hello World!"
    }

    Flow {
        TextField {
            text: testMessage.message
        }

        Label {
            text: testMessage.message
        }
    }
}

main.cpp

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include "message.h"

int main(int argc, char *argv[])
{
    qmlRegisterType<Message>("com.butts.messaging", 1, 0, "Message");

    //Message msg = Message();

    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);
    QGuiApplication app(argc, argv);

    QQmlApplicationEngine engine;
    engine.load(QUrl(QLatin1String("qrc:/main.qml")));

    return app.exec();
}

附言我在这方面是个菜鸟，所以请随时指出我代码中的任何其他问题(格式、标准等)，我需要以某种方式学习，哈哈

编辑 1

阅读@derM 的回答后，我更改了代码以实现我想要的

TextField {
    id: editor

    //Binding model -> view
    text: testMessage.message

    //Binding model <- view
    Binding {
        target: testMessage
        property: "message"
        value: editor.text
    }
}

Label {
    id: display

    //Binding model -> view
    text: testMessage.message
}

最佳答案

双向绑定(bind)在 QML 中是一件复杂的事情，因为它通常作为一些赋值工作。

因此，如果您使用 propertyname: valuetobeboundto 绑定(bind)一个属性，然后再次将某些内容分配给 propertyname，则此绑定(bind)将丢失。

解决方法有两种:使用 Binding -对象或不使用绑定(bind)，但手动处理所有属性更改信号(理想情况下您的模型会正确发出)。

首先，您可以找到详细说明 here. 在这里，他们为每个方向使用一个 Binding-Object。好消息是，那些 Binding 不会被分配新的 Binding 覆盖。

考虑:

Row {
    spacing: 2
    Rectangle {
        id: r0
        width: 50
        height: 30
    }

    Rectangle {
        id: r1
        width: 50
        height: 30
        color: b2.pressed ? 'red' : 'blue'
    }

    Button {
        id: b2
    }

    Button {
        id: b3
        onPressed: r1.color = 'black'
        onReleased: r1.color = 'green'
    }

    Binding {
        target: r0
        property: 'color'
        value: b2.pressed ? 'red' : 'blue'
    }


    Binding {
        target: r0
        property: 'color'
        value: (b3.pressed ? 'black' : 'green')
    }
}

一开始 r1 的值绑定(bind)到 b2 的状态，但是一旦 b3 被按下一次，r1 不会再通过点击 b2 来更新。对于 r0，更新将由两个 Binding 对象完成，因此 Binding 不会丢失。但是，您可以看到绑定(bind)是如何工作的:只要 Button 的状态发生变化，Binding 就会更新。 所以 press AND 释放 b2 将触发信号，该信号将由第一个 Binding 处理，同样适用于 press AND 发布 b3。

现在介绍双向绑定(bind)。这里重要的是要避免绑定(bind)循环。

Row {
    Button {
        id: count0
        property int count: 0
        onClicked: count += 1
        text: count
    }

    Button {
        id: count1
        property int count: 0
        onClicked: count += 1
        text: count
    }

    Binding {
        target: count0
        property: 'count'
        value: count1.count
    }

    Binding {
        target: count1
        property: 'count'
        value: count0.count
    }
}

虽然这个例子非常好。 count0.count 的变化将触发 count1.count 的变化。现在检查 count0.count 是否需要更新，但值已经正确，因此递归结束，并且没有绑定(bind)循环发生。

将第二个绑定(bind)更改为

    Binding {
        target: count1
        property: 'count'
        value: count0.count + 1
    }

彻底改变了情况:现在随着 count0.count 的每次更改，都需要增加 count1.count。第一个 Binding 然后尝试将 count0.count 设置为与 count1.count 相同的值，但是没有办法让两个 Binding 将得到满足，并且不需要进行任何更改，在其他 Binding 完成它的工作之后。它将导致绑定(bind)循环。幸运的是，在 QML 中可以很好地检测到这些，因此避免了锁定。

现在只有最后一件事需要处理: 考虑这个组件定义:

// TestObj.qml
Item {
    width: 150
    height: 40
    property alias color: rect.color
    Row {
        spacing: 10
        Rectangle {
            id: rect
            width: 40
            height: 40
            radius: 20
            color: butt.pressed ? 'green' : 'red'
        }
        Button {
            id: butt
            text: 'toggle'
        }
    }
}

在这里，我们通过使用 propertyname: valueToBeBoundTo 语法对 color 属性进行了内部绑定(bind)。这意味着，内部绑定(bind)可能会被 color 属性的任何外部赋值覆盖。 将此绑定(bind)替换为 Binding-Object，您应该没问题。

反之亦然:color 在外部绑定(bind)到某个值，然后你在内部处理一个信号并为其赋值，外部绑定(bind)将丢失，如果没有由 Binding-Object 创建。

This is only a general overview. There are way more details that might alter the behavior of Binding. But I think I have shown, how you can create a Two-Way-Binding and mentioned quite some pitfalls, you might encounter.

关于c++ - QML 中的两种方式绑定(bind) C++ 模型，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/41232999/