使用 Delphi XE7 Update 1 和 Delphi XE8 测试

在 Windows 操作系统 (7 SP1 x64)、MACOSX (10.10.3) 和 Android (5.0.2) 上创建订单:

    "class constructor TGlobalClass.Create;" -> "constructor TfmMain.Create;" -> "procedure TfmMain.FormCreate(Sender: TObject);"

Windows 操作系统和 MACOSX 上的发布顺序:

    "TfmMain.FormDestroy" -> "destructor TfmMain.Destroy" -> "class destructor TGlobalClass.Destroy;"

Android 上的发布顺序:

    "class destructor TGlobalClass.Destroy;" -> "TfmMain.FormDestroy" -> "destructor TfmMain.Destroy"

问题是:为什么在Android平台上CLASS VAR先于main form发布？

代码示例:

unit uClassVar;

interface

type
  TGlobalClass = class
    class var F1: Integer;

    class constructor Create;
    class destructor Destroy;
  end;

implementation

{ TX }

class constructor TGlobalClass.Create;
begin
  { Breakpoint there }
  F1 := 100;
end;

class destructor TGlobalClass.Destroy;
begin
  { Breakpoint there }
  F1 := 200;
end;

end.

主要单位:

unit ufmMain;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics;

type
  TfmMain = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;

var
  fmMain: TfmMain;
  z: Integer;

implementation

uses
  uClassVar;

{$R *.fmx}

constructor TfmMain.Create;
begin
  { Breakpoint there }
  inherited;
end;

destructor TfmMain.Destroy;
begin
  { Breakpoint there }
  inherited;
end;

procedure TfmMain.FormCreate(Sender: TObject);
begin
  { Breakpoint there }
  TGlobalClass.F1 := -99999;
end;

procedure TfmMain.FormDestroy(Sender: TObject);
begin
  { Breakpoint there }
  z := 200;
end;

end.

项目文件:

program ClassVar;

uses
  System.StartUpCopy,
  FMX.Forms,
  ufmMain in 'ufmMain.pas' {fmMain},
  uClassVar in 'uClassVar.pas';

{$R *.res}

begin
  Application.Initialize;
  Application.CreateForm(TfmMain, fmMain);
  Application.Run;
end.

最佳答案

桌面编译器

当应用程序对象销毁其组件时，您的主窗体也被销毁。这发生在 DoneApplication 过程中的 FMX.Forms 中。

procedure DoneApplication;
begin
  if Screen <> nil then
    Screen.ActiveForm := nil;
  Application.DestroyComponents;  <-- this is destroying your main form
end;

并且 DoneApplication 在关闭期间作为退出过程被调用。该退出过程是从 TApplication.Run 注册的，如下所示:

{$IFNDEF ANDROID}
  AddExitProc(DoneApplication);
{$ENDIF}

类构造函数从定义它们的单元的初始化部分调用。因此，TGlobalClass.Create 从 uClassVar 的初始化中调用。从同一单元的终结部分调用类析构函数。

系统关闭由 _Halt0 中的 System 单元执行。它在执行单元终结之前执行所有退出过程。因此，您的表单在调用类析构函数之前被销毁。

移动编译器

请注意 DoneApplication 在 Android 上根本不会被调用。

{$IFNDEF ANDROID}
  AddExitProc(DoneApplication);
{$ENDIF}

这意味着主窗体的销毁是从单元终结中调用的。当每个单元完成时，它的完成部分将被执行，这会导致任何全局变量离开范围。最终，不再有对您的主窗体的引用，因此它的析构函数被执行。

如上所述，类析构函数也从单元终结中调用。由于在 Android 上，您的类析构函数在主窗体被销毁之前执行，可以清楚地看到 uClassVar 在主窗体的最终引用被释放之前完成。

现在，这很有意义，因为 uClassVar 是初始化顺序中的最后一个单元，因此也是最终化顺序中的第一个单元。如果你想确保 uClassVar 稍后完成，你需要安排它尽快初始化。例如，通过像这样更改 .dpr 文件的 uses 子句:

uses
  uClassVar in 'uClassVar.pas',  
  System.StartUpCopy,
  FMX.Forms,
  ufmMain in 'ufmMain.pas' {fmMain};

现在 uClassVar 是第一个初始化的单元，因此是最后一个完成的单元。

关于android - 德尔福XE8。调音台。为什么Android平台上CLASS VAR的发布顺序不同？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/31067795/