在 C# 中，只读成员可以减少为只读自动属性/不可变成员的表达式体成员是表达式体成员比使用只读关键字更好吗？

使用只读键:

public static readonly string  COMPANY_NAME= "XYZ";

使用 Expression-bodied 成员:

public  static  string  COMPANY_NAME => "XYZ";

我遇到过各种论坛和解决方案，这些论坛和解决方案建议将表达式主体成员用于速记，但我找不到它在性能上有何不同。

最佳答案

让我们深入了解一下编译器对不同类型的字段做了什么。

class Program
{
    public const string ConstString = "mesa const";
    public static readonly string ReadonlyStatic = "mesa readonly";
    public static string ExpressionBodied => "mesa expression";
    public static string GetInitialized {get;} =  "mesa get";
    public static string GetWithBody { get { return "mesa get"; } } 

    static void Main(string[] args)
    {
        Console.WriteLine("Hello World!");

        System.Console.WriteLine("readonly:" + ReadonlyStatic);
        System.Console.WriteLine("const:" + ConstString);
        System.Console.WriteLine("expression bodied:" + ExpressionBodied);
        System.Console.WriteLine("get initialized:" + GetInitialized);
        System.Console.WriteLine("get with body:" + GetWithBody);
    }
}

const string 创建一个 literal string 并将在调用站点进行评估:

.field public static literal string ConstString = "mesa const"

// call site:
IL_0021: ldstr        "const:mesa const"
IL_0026: call         void [System.Console]System.Console::WriteLine(string)

static readonly 创建一个在 ctor 中初始化的字段，使用时仅表示一个字段引用:

.field public static initonly string ReadonlyStatic

// call site:
IL_000c: ldstr        "readonly:"
IL_0011: ldsfld       string readonly_props.Program::ReadonlyStatic
IL_0016: call         string [System.Runtime]System.String::Concat(string, string)
IL_001b: call         void [System.Console]System.Console::WriteLine(string)

表达式体成员生成一个getter，返回常量值:

.method public hidebysig static specialname string 
get_ExpressionBodied() cil managed 
{
  .maxstack 8

  // [9 50 - 9 67]
  IL_0000: ldstr        "mesa expression"
  IL_0005: ret          
} // end of method Program::get_ExpressionBodied

// call site:
IL_002c: ldstr        "expression bodied:"
IL_0031: call         string readonly_props.Program::get_ExpressionBodied()
IL_0036: call         string [System.Runtime]System.String::Concat(string, string)
IL_003b: call         void [System.Console]System.Console::WriteLine(string)

带有初始化的只读属性为初始化值生成一个额外的支持字段。

.field private static initonly string '<GetInitialized>k__BackingField'    
.method public hidebysig static specialname string 
  get_GetInitialized() cil managed 
{
  .custom instance void [System.Runtime]System.Runtime.CompilerServices.CompilerGeneratedAttribute::.ctor() 
  = (01 00 00 00 )
  .maxstack 8
  // [10 46 - 10 50]
  IL_0000: ldsfld       string readonly_props.Program::'<GetInitialized>k__BackingField'
  IL_0005: ret          
} // end of method Program::get_GetInitialized

// call site:
IL_0041: ldstr        "get initialized:"
IL_0046: call         string readonly_props.Program::get_GetInitialized()
IL_004b: call         string [System.Runtime]System.String::Concat(string, string)
IL_0050: call         void [System.Console]System.Console::WriteLine(string)

具有完整主体的 Property getter 有点长:

.method public hidebysig static specialname string 
  get_GetWithBody() cil managed 
{
  .maxstack 1
  .locals init (
    [0] string V_0
  )

  // [11 48 - 11 49]
  IL_0000: nop          

  // [11 50 - 11 68]
  IL_0001: ldstr        "mesa get"
  IL_0006: stloc.0      // V_0
  IL_0007: br.s         IL_0009

  // [11 69 - 11 70]
  IL_0009: ldloc.0      // V_0
  IL_000a: ret          

} // end of method Program::get_GetWithBody

// call site:
IL_0056: ldstr        "get with body:"
IL_005b: call         string readonly_props.Program::get_GetWithBody()
IL_0060: call         string [System.Runtime]System.String::Concat(string, string)
IL_0065: call         void [System.Console]System.Console::WriteLine(string)

据此，我们可以根据它们生成的代码(和调用)数量对它们进行排序:

• const string 绝对是最快的，但是当从其他组件使用时(如其他答案所述)，在发生变化时可能会导致意外行为
• static readonly紧随其后，只有一个字段访问
• static string ExpressionBodied => "xxx" 将引起一个只返回常量的方法调用(getter)
• static string GetInitialized {get;} = "xxx" 将导致方法调用和字段访问
• 静态字符串 GetWithBody { get { return "xxx"; } } 会导致一个返回常量的方法调用，但是如果有额外的内存分配，看起来

在实践中，性能差异可能无法观察到。正如所指出的，IL 代码可以通过 JIT 进一步优化，因此您最终可以获得有效的相同性能。 不过，我更愿意选择选项 1。或 2。

关于c# - c#中readonly关键字/Expression-bodied成员之间的区别？哪个更好？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/51780736/