Arduino模块学习笔记（一）——GSP模块的使用

文章目录

• Arduino模块学习笔记（一）——GSP模块的使用
• • 所需组件
  • 一、模块使用介绍
  • • 1.GPS模块（在室内时，一般获取不到位置信息）
    • 2.接线
    • 3.NMEA协议
  • 二、示例演示
  • • 1.示例1：简单通讯，获取NMEA协议信息
    • 2.示例2：导入TinyGPSPlus库，获取解码信息
    • 3.示例3：获取指定解码信息

所需组件

• Arduino UNO开发板
• Arduino IDE环境
• 数据线
• NEO-6M GPS模块（+配套的陶瓷天线 可选）

一、模块使用介绍

1.GPS模块（在室内时，一般获取不到位置信息）

常见的GPS模块的参数都差不多，除了有些个别输出格式不同。
● 接口：RS232 TTL
● 电源：3.3V至5V均可（内置降压模块）
● 默认波特率：9600 bps（有些可能是4800）
● 支持标准的NMEA

本实验也是第一次使用，购买的是维特智能的ATK-NEO-6M GPS模块以及配套的陶瓷天线

2.接线

这里使用了Arduino自带的SoftwareSerial库，把引脚7，8定义为一组软串口来使用

GPS模块	Arduino UNO
RX	8
TX	7
VCC	5V / 3.3V
GND	GND

3.NMEA协议

需要了解可参考 GPS NMEA-0183标准详解（常用的精度以及经纬度坐标），非常详细

二、示例演示

1.示例1：简单通讯，获取NMEA协议信息

源码展示——示例1：

#include<SoftwareSerial.h>
#define gpsTX 7
#define gpsRX 8
#define gpsBand 9600

SoftwareSerial gpsSerial(gpsRX,gpsTX);

void setup(){
  Serial.begin(9600);
  gpsSerial.begin(gpsBand);
}

void loop(){
  if(gpsSerial.available()){
    char c =gpsSerial.read();
    Serial.write(c);
  }
}

2.示例2：导入TinyGPSPlus库，获取解码信息

导入TinyGPSPlus库

使用TinyGPSPlus库的示例FullExample

接线保持不变，修改软串口定义和波特率

上传即得到如下效果（因为目前在室内，所以没有位置信息）

源码展示——示例2：

#include <TinyGPSPlus.h>
#include <SoftwareSerial.h>
/*
   This sample code demonstrates the normal use of a TinyGPSPlus (TinyGPSPlus) object.
   It requires the use of SoftwareSerial, and assumes that you have a
   4800-baud serial GPS device hooked up on pins 4(rx) and 3(tx).
*/
static const int RXPin = 8, TXPin = 7;
static const uint32_t GPSBaud = 9600;

// The TinyGPSPlus object
TinyGPSPlus gps;

// The serial connection to the GPS device
SoftwareSerial ss(RXPin, TXPin);

void setup()
{
  Serial.begin(9600);
  ss.begin(GPSBaud);

  Serial.println(F("FullExample.ino"));
  Serial.println(F("An extensive example of many interesting TinyGPSPlus features"));
  Serial.print(F("Testing TinyGPSPlus library v. ")); Serial.println(TinyGPSPlus::libraryVersion());
  Serial.println(F("by Mikal Hart"));
  Serial.println();
  Serial.println(F("Sats HDOP  Latitude   Longitude   Fix  Date       Time     Date Alt    Course Speed Card  Distance Course Card  Chars Sentences Checksum"));
  Serial.println(F("           (deg)      (deg)       Age                      Age  (m)    --- from GPS ----  ---- to London  ----  RX    RX        Fail"));
  Serial.println(F("----------------------------------------------------------------------------------------------------------------------------------------"));
}

void loop()
{
  static const double LONDON_LAT = 51.508131, LONDON_LON = -0.128002;

  printInt(gps.satellites.value(), gps.satellites.isValid(), 5);
  printFloat(gps.hdop.hdop(), gps.hdop.isValid(), 6, 1);
  printFloat(gps.location.lat(), gps.location.isValid(), 11, 6);
  printFloat(gps.location.lng(), gps.location.isValid(), 12, 6);
  printInt(gps.location.age(), gps.location.isValid(), 5);
  printDateTime(gps.date, gps.time);
  printFloat(gps.altitude.meters(), gps.altitude.isValid(), 7, 2);
  printFloat(gps.course.deg(), gps.course.isValid(), 7, 2);
  printFloat(gps.speed.kmph(), gps.speed.isValid(), 6, 2);
  printStr(gps.course.isValid() ? TinyGPSPlus::cardinal(gps.course.deg()) : "*** ", 6);

  unsigned long distanceKmToLondon =
    (unsigned long)TinyGPSPlus::distanceBetween(
      gps.location.lat(),
      gps.location.lng(),
      LONDON_LAT, 
      LONDON_LON) / 1000;
  printInt(distanceKmToLondon, gps.location.isValid(), 9);

  double courseToLondon =
    TinyGPSPlus::courseTo(
      gps.location.lat(),
      gps.location.lng(),
      LONDON_LAT, 
      LONDON_LON);

  printFloat(courseToLondon, gps.location.isValid(), 7, 2);

  const char *cardinalToLondon = TinyGPSPlus::cardinal(courseToLondon);

  printStr(gps.location.isValid() ? cardinalToLondon : "*** ", 6);

  printInt(gps.charsProcessed(), true, 6);
  printInt(gps.sentencesWithFix(), true, 10);
  printInt(gps.failedChecksum(), true, 9);
  Serial.println();
  
  smartDelay(1000);

  if (millis() > 5000 && gps.charsProcessed() < 10)
    Serial.println(F("No GPS data received: check wiring"));
}

// This custom version of delay() ensures that the gps object
// is being "fed".
static void smartDelay(unsigned long ms)
{
  unsigned long start = millis();
  do 
  {
    while (ss.available())
      gps.encode(ss.read());
  } while (millis() - start < ms);
}

static void printFloat(float val, bool valid, int len, int prec)
{
  if (!valid)
  {
    while (len-- > 1)
      Serial.print('*');
    Serial.print(' ');
  }
  else
  {
    Serial.print(val, prec);
    int vi = abs((int)val);
    int flen = prec + (val < 0.0 ? 2 : 1); // . and -
    flen += vi >= 1000 ? 4 : vi >= 100 ? 3 : vi >= 10 ? 2 : 1;
    for (int i=flen; i<len; ++i)
      Serial.print(' ');
  }
  smartDelay(0);
}

static void printInt(unsigned long val, bool valid, int len)
{
  char sz[32] = "*****************";
  if (valid)
    sprintf(sz, "%ld", val);
  sz[len] = 0;
  for (int i=strlen(sz); i<len; ++i)
    sz[i] = ' ';
  if (len > 0) 
    sz[len-1] = ' ';
  Serial.print(sz);
  smartDelay(0);
}

static void printDateTime(TinyGPSDate &d, TinyGPSTime &t)
{
  if (!d.isValid())
  {
    Serial.print(F("********** "));
  }
  else
  {
    char sz[32];
    sprintf(sz, "%02d/%02d/%02d ", d.month(), d.day(), d.year());
    Serial.print(sz);
  }
  
  if (!t.isValid())
  {
    Serial.print(F("******** "));
  }
  else
  {
    char sz[32];
    sprintf(sz, "%02d:%02d:%02d ", t.hour(), t.minute(), t.second());
    Serial.print(sz);
  }

  printInt(d.age(), d.isValid(), 5);
  smartDelay(0);
}

static void printStr(const char *str, int len)
{
  int slen = strlen(str);
  for (int i=0; i<len; ++i)
    Serial.print(i<slen ? str[i] : ' ');
  smartDelay(0);
}

3.示例3：获取指定解码信息

源码展示——示例3：

#include <TinyGPSPlus.h>
#include <SoftwareSerial.h>

static const int RXPin = 8, TXPin = 7;
static const uint32_t GPSBaud = 9600;

// The TinyGPS++ object
TinyGPSPlus gps;

// The serial connection to the GPS device
SoftwareSerial gpsSerial(RXPin, TXPin);

void setup(){
  Serial.begin(9600);
  gpsSerial.begin(GPSBaud);
}

void loop(){
  // This sketch displays information every time a new sentence is correctly encoded.
  while (gpsSerial.available() > 0){
    if (gps.encode(gpsSerial.read())){
       displayInfo();
    }
    if(millis() > 5000 && gps.charsProcessed() < 10)
    {
      Serial.println("No GPS detected:check wiring.");
      while(true);
    }
  }
}

void displayInfo(){
  Serial.print("Location:");
  if(gps.location.isValid()){
    Serial.print(gps.location.lat(),6);
    Serial.print(",");
    Serial.print(gps.location.lng(),6);
  }
  else{
    Serial.print("INVALID");
  }

  Serial.print("  Date");
  if(gps.date.isValid()){
    Serial.print(gps.date.month());
    Serial.print("/");
    Serial.print(gps.date.day());
    Serial.print("/");
    Serial.print(gps.date.year());
  }
  else{
    Serial.print("INVALID");
  }

  Serial.println();
}