草庐IT

关于python：如何在Fortran中获取先前未知的数组作为函数的输出

codeneng 2023-03-28 原文

How to get priorly-unknown array as the output of a function in Fortran

在 Python 中：

1
2
3
4
5
6
def select(x):
    y = []
    for e in x:
        if e!=0:
            y.append(e)
    return y

的作用是：

1
2
3
x = [1,0,2,0,0,3]
select(x)
[1,2,3]

要翻译成Fortran：

1
2
3
4
5
6
7
8
9
10
11
function select(x,n) result(y)
    implicit none
    integer:: x(n),n,i,j,y(?)
    j = 0
    do i=1,n
        if (x(i)/=0) then
            j = j+1
            y(j) = x(i)
        endif
    enddo
end function

问题在 Fortran 中：

  • 如何声明 y(?)？
  • 如何声明 x 的预定义值
  • 如何避免维度信息 n

    • 对于 1，如果它被定义为 y(n)，输出将是：

    1
    2
    3
    x = (/1,0,2,0,0,3/)
    print *,select(x,6)
    1,2,3,0,0,0

    这是不希望的！
    !--------------------------------
    评论：
    1-所有给出的答案在这篇文章中都很有用。特别是 M.S.B 和 eryksun 的。
    2-我尝试针对我的问题调整想法并使用 F2Py 进行编译，但是没有成功。我已经使用 GFortran 对它们进行了调试，并且一切都成功了。这可能是 F2Py 中的一个错误，或者我不知道如何正确使用它。我将尝试在另一篇文章中讨论这个问题。

    更新：
    可以在此处找到链接的问题。

    • 您究竟是如何将自己置于从 Python 向后移植到 Fortran 的位置的？ o_O 这似乎很不寻常。或者您只是将 Fortran 作为一项学术练习来学习？
    • 一般声明：不是唯一的原因，但至少出于性能考虑，我总是必须考虑将一些代码转换为 Fortran，然后在 Python 中调用它们(通过 F2Py)。到目前为止，这对我来说是最好的匹配，同时具有质量和生产力 (Python) 以及速度和性能 (Fortran)。

    我希望有一个真正的 Fortran 程序员来，但在没有更好的建议的情况下，我只会指定 x(:) 的形状而不是大小，使用临时数组 temp(size(x))，并使输出 y 。然后在第一遍之后， allocate(y(j)) 并从临时数组中复制值。但是我不能强调我不是 Fortran 程序员，所以我不能说该语言是否具有可增长的数组或者是否存在用于后者的库。

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    program test
        implicit none
        integer:: x(10) = (/1,0,2,0,3,0,4,0,5,0/)
        print"(10I2.1)", select(x)

    contains

        function select(x) result(y)
            implicit none
            integer, intent(in):: x(:)
            integer:: i, j, temp(size(x))
            integer, allocatable:: y(:)

            j = 0
            do i = 1, size(x)
                if (x(i) /= 0) then
                    j = j + 1
                    temp(j) = x(i)
                endif
            enddo

            allocate(y(j))
            y = temp(:j)
        end function select

    end program test

    编辑：

    根据 M.S.B.\\ 的回答，这里是函数的修订版本，该函数通过过度分配增加 temp y。 和之前一样，它在最后将结果复制到 y。 事实证明，我没有必要以最终大小显式分配一个新数组。相反，它可以通过赋值自动完成。

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
        function select(x) result(y)
            implicit none
            integer, intent(in):: x(:)
            integer:: i, j, dsize
            integer, allocatable:: temp(:), y(:)

            dsize = 0; allocate(y(0))

            j = 0
            do i = 1, size(x)
                if (x(i) /= 0) then
                    j = j + 1

                    if (j >= dsize) then         !grow y using temp
                        dsize = j + j / 8 + 8
                        allocate(temp(dsize))
                        temp(:size(y)) = y
                        call move_alloc(temp, y) !temp gets deallocated
                    endif

                    y(j) = x(i)
                endif
            enddo
            y = y(:j)
        end function select

    • 感谢您与社区分享您的知识。您的答案和 M.S.B 的答案非常接近，并且都非常有帮助。顺便说一句，部分 j+j/8+8 是整数的大小，因此它需要更改其他类型的数据！
    • @Supporter：也许不清楚。我添加了更新作为 M.S.B. 的替代答案的替代方案。我没有一个一个地增长数组，我认为这涉及到过多的复制，而是让它过度分配。当前需要的大小是 j 个项目，所以我分配了这个加上八分之一(当它很小的时候也加上一个常数 8)。因此，过度分配的大小与数组的当前大小成正比增长，这最大限度地减少了必须重新分配的次数。最后，我将其缩小，希望编译器对其进行优化以不需要副本。
    • 对我来说，这两个答案都是有用且正确的。只是我仔细检查了发送答案的时间，然后发现你是第一个(7.19 < 7.26)。所以现在选择你的答案。

    这是一个返回可变长度数组的 Fortran 函数示例。这是 Fortran 2003 的一个功能。测试驱动程序中还使用了自动分配分配，这是 Fortran 2003 的另一个功能。

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    module my_subs

    contains

    function select(x) result(y)
        implicit none
        integer, dimension (:), intent (in) :: x
        integer, dimension (:), allocatable :: y
        integer :: i, j

        j = 0
        do i=1, size (x)
            if (x(i)/=0) j = j+1
        enddo

        allocate ( y (1:j) )

        j = 0
        do i=1, size (x)
            if (x(i)/=0) then
                j = j+1
                y(j) = x(i)
            endif
        enddo

        return

    end function select

    end module my_subs

    program test

    use my_subs

    implicit none
    integer, dimension (6) :: array = [ 5, 0, 3, 0, 6, 1 ]
    integer, dimension (:), allocatable :: answer

    answer = select (array)

    write (*, *) size (array), size (answer)
    write (*, *) array
    write (*, *) answer

    stop


    end program test

    这是一个替代解决方案，它使用临时数组根据需要"增长"输出数组(函数返回)。虽然避免了两次通过输入数组，但需要数组副本。 Fortran 2003 的另一个特性 move_alloc 减少了所需的副本数量。 move_alloc 还负责输出数组(此处为 "y")的(重新)分配和输入数组(此处为 "temp")的解除分配。也许这更优雅，但由于使用了多个副本，因此效率可能较低。这个版本可能更具教育意义然后有用。 @eryksun\\ 的版本使用一次传递和一份副本，代价是使临时数组变满。

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    function select(x) result(y)
        implicit none
        integer, dimension (:), intent (in) :: x
        integer, dimension (:), allocatable :: y, temp
        integer :: i, j

        j = 0
        do i=1, size (x)
            if (x(i)/=0) then
                j = j+1
                allocate (temp (1:j))
                if ( allocated (y) ) temp (1:j-1) = y
                call move_alloc (temp, y)
                y(j) = x(i)
            endif
        enddo

        return

    end function select

    • 进行 2 次全通是另一种方法。我选择了一个临时数组，认为函数中完成的工作(不是这个，而是一般来说)可能比复制结果更昂贵。另外，可分配数组不是 Fortran 90/95 的特性吗？
    • 可分配数组是 Fortran 90 的一部分。Fortran 95 和 2003 已进行了改进。在此示例中，在 Fortran 2003 之前不支持可分配的函数返回。与在赋值语句中发生的自动分配一样测试驱动程序，"答案 = 选择(数组)"。
    • 感谢您的回答。然而，它非常接近 eryksun 的答案。这篇文章对我帮助找出 Fortran 2003 中的一些改进也很有用。
    • 在第一个代码块中，您还可以将结果声明为 integer :: y(count(x /= 0))。 (这实际上可能是有效的 Fortran 95，但我不确定自动函数的结果。)我猜该程序将构建一个中间逻辑数组，这取决于编译器的聪明程度。

    如果您问题中的示例确实是您想要做的，您可以使用 Fortran90 内在 `pack\\':

    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    program pack_example

    implicit none

    integer, dimension(6) :: x

    x = (/ 1,0,2,0,0,3 /)

    ! you can also use other masks than 'x/=0'
    write(*,*) pack(x, x/=0)

    end program pack_example

    示例程序的输出为：1 2 3

    • 感谢您的提示。然而，问题中的示例只是为了演示问题。无论如何，您的提示对于您提供的其他简单情况非常有用。实际上，问题是指 pack 如何实现根据条件返回不同大小的数组作为输出，例如，基于 x 的 'x/=0' 没有给定大小信息！另一点是"pack"输出是输入"x"的子集，例如，大小不能更大。毕竟这是一个很好的提示。

    何在Fortranspanclassnbsparraysdynamic-arraysfortranpython

    有关关于python：如何在Fortran中获取先前未知的数组作为函数的输出的更多相关文章

    1. ruby - 如何在 Ruby 中顺序创建 PI - 2

      出于纯粹的兴趣，我很好奇如何按顺序创建PI，而不是在过程结果之后生成数字，而是让数字在过程本身生成时显示。如果是这种情况，那么数字可以自行产生，我可以对以前看到的数字实现垃圾收集，从而创建一个无限系列。结果只是在Pi系列之后每秒生成一个数字。这是我通过互联网筛选的结果:这是流行的计算机友好算法，类机器算法:defarccot(x,unity)xpow=unity/xn=1sign=1sum=0loopdoterm=xpow/nbreakifterm==0sum+=sign*(xpow/n)xpow/=x*xn+=2sign=-signendsumenddefcalc_pi(digits

    2. python - 如何使用 Ruby 或 Python 创建一系列高音调和低音调的蜂鸣声？ - 2

      关闭。这个问题是opinion-based.它目前不接受答案。想要改进这个问题？更新问题，以便editingthispost可以用事实和引用来回答它.关闭4年前。Improvethisquestion我想在固定时间创建一系列低音和高音调的哔哔声。例如:在150毫秒时发出高音调的蜂鸣声在151毫秒时发出低音调的蜂鸣声200毫秒时发出低音调的蜂鸣声250毫秒的高音调蜂鸣声有没有办法在Ruby或Python中做到这一点？我真的不在乎输出编码是什么(.wav、.mp3、.ogg等等)，但我确实想创建一个输出文件。

    3. ruby-on-rails - 在 Ruby 中循环遍历多个数组 - 2

      我有多个ActiveRecord子类Item的实例数组，我需要根据最早的事件循环打印。在这种情况下，我需要打印付款和维护日期，如下所示:ItemAmaintenancerequiredin5daysItemBpaymentrequiredin6daysItemApaymentrequiredin7daysItemBmaintenancerequiredin8days我目前有两个查询，用于查找maintenance和payment项目(非排他性查询)，并输出如下内容:paymentrequiredin...maintenancerequiredin...有什么方法可以改善上述(丑陋的)代

    4. ruby - 如何在 buildr 项目中使用 Ruby 代码？ - 2

      如何在buildr项目中使用Ruby？我在很多不同的项目中使用过Ruby、JRuby、Java和Clojure。我目前正在使用我的标准Ruby开发一个模拟应用程序，我想尝试使用Clojure后端(我确实喜欢功能代码)以及JRubygui和测试套件。我还可以看到在未来的不同项目中使用Scala作为后端。我想我要为我的项目尝试一下buildr(http://buildr.apache.org/)，但我注意到buildr似乎没有设置为在项目中使用JRuby代码本身!这看起来有点傻，因为该工具旨在统一通用的JVM语言并且是在ruby中构建的。除了将输出的jar包含在一个独特的、仅限ruby​​

    5. ruby - 什么是填充的 Base64 编码字符串以及如何在 ruby​​ 中生成它们？ - 2

      我正在使用的第三方API的文档状态:"[O]urAPIonlyacceptspaddedBase64encodedstrings."什么是“填充的Base64编码字符串”以及如何在Ruby中生成它们。下面的代码是我第一次尝试创建转换为Base64的JSON格式数据。xa=Base64.encode64(a.to_json) 最佳答案 他们说的padding其实就是Base64本身的一部分。它是末尾的“=”和“==”。Base64将3个字节的数据包编码为4个编码字符。所以如果你的输入数据有长度n和n%3=1=>"=="末尾用于填充n%

    6. ruby - 多次弹出/移动 ruby​​ 数组 - 2

      我的代码目前看起来像这样numbers=[1,2,3,4,5]defpop_threepop=[]3.times{pop有没有办法在一行中完成pop_three方法中的内容？我基本上想做类似numbers.slice(0,3)的事情，但要删除切片中的数组项。嗯...嗯，我想我刚刚意识到我可以试试slice! 最佳答案 是numbers.pop(3)或者numbers.shift(3)如果你想要另一边。 关于ruby-多次弹出/移动ruby​​数组，我们在StackOverflow上找到一

    7. ruby - 将数组的内容转换为 int - 2

      我需要读入一个包含数字列表的文件。此代码读取文件并将其放入二维数组中。现在我需要获取数组中所有数字的平均值，但我需要将数组的内容更改为int。有什么想法可以将to_i方法放在哪里吗？ClassTerraindefinitializefile_name@input=IO.readlines(file_name)#readinfile@size=@input[0].to_i@land=[@size]x=1whilex 最佳答案 只需将数组映射为整数:@land边注如果你想得到一条线的平均值，你可以这样做:values=@input[x]

    8. ruby-on-rails - 如何在 ruby​​ 中使用两个参数异步运行 exe？ - 2

      exe应该在我打开页面时运行。异步进程需要运行。有什么方法可以在ruby​​中使用两个参数异步运行exe吗？我已经尝试过ruby​​命令-system()、exec()但它正在等待过程完成。我需要用参数启动exe，无需等待进程完成是否有任何ruby​​gems会支持我的问题？ 最佳答案 您可以使用Process.spawn和Process.wait2:pid=Process.spawn'your.exe','--option'#Later...pid,status=Process.wait2pid您的程序将作为解释器的子进程执行。除

    9. ruby - 通过 erb 模板输出 ruby​​ 数组 - 2

      我正在使用puppet为ruby​​程序提供一组常量。我需要提供一组主机名，我的程序将对其进行迭代。在我之前使用的bash脚本中，我只是将它作为一个puppet变量hosts=>"host1,host2"我将其提供给bash脚本作为HOSTS=显然这对ruby​​不太适用——我需要它的格式hosts=["host1","host2"]自从phosts和putsmy_array.inspect提供输出["host1","host2"]我希望使用其中之一。不幸的是，我终其一生都无法弄清楚如何让它发挥作用。我尝试了以下各项:我发现某处他们指出我需要在函数调用前放置“function_”……这

    10. ruby - 如何在续集中重新加载表模式？ - 2

      鉴于我有以下迁移:Sequel.migrationdoupdoalter_table:usersdoadd_column:is_admin,:default=>falseend#SequelrunsaDESCRIBEtablestatement,whenthemodelisloaded.#Atthispoint,itdoesnotknowthatusershaveais_adminflag.#Soitfails.@user=User.find(:email=>"admin@fancy-startup.example")@user.is_admin=true@user.save!ende

    随机推荐