Unity的阴影

        一条光线遇到一个不透明物体就不可以继续照亮其他物体，因此这个物体就会向该方向的物体投射阴影。实时渲染中使用一种ShadowMap技术，首先把相机的位置放置光源的位置，阴影区域就是摄像机看不到的地方。unity会为光源计算其阴影映射纹理，本质上是一张深度图，用一个额外的pass专门更新映射纹理而非在bass/additional中完成，LightMode为”ShadowCaster“，找到一个这样的pass才可以投射阴影。

屏幕空间的阴影映射技术

        延迟渲染中的方法，需要显卡支持MRT。

流程：首先通过调用lightmode为shadowcaster的pass来得到可投射阴影的光源的阴影映射纹理以及摄像机的深度纹理，然后根据这两个纹理得到屏幕空间的阴影图。如果深度图中记录的表面深度大于转换到阴影映射纹理中的深度值，说明可见但在阴影中，即得到阴影图。阴影图再屏幕空间中，所以把表面坐标变换到屏幕坐标中再使用这个坐标对阴影图采样即可。

一个物体接收来自其他物体的阴影，和 它向其他物体投射阴影是两个过程。

 ①想要接收阴影，就要再shader中对阴影映射纹理采样，将结果与最后的光照结果相乘。

②投射纹理，需要将其添加到光源的阴影映射纹理的计算中，让其他物体对该纹理的采样时可以得到它的信息。

不透明物体的阴影

        先前写的shader赋给材质，即使没有一个pass的lightmode为shadowcaster，但是cube依然向平面投射了阴影，这是因为fallback了specular，specular本身fallback了vertexLit，内置的着色器中对其完成了实现。使物体完成阴影的投射。

让物体接收阴影：

shadow_coords(2)宏的作用是，声明一个用于对阴影纹理采样的坐标。

 transfer_shadow宏用于在顶点着色器中计算上一步声明的阴影纹理坐标。

最后shadow_attenuation用于计算阴影值，并将结果乘进光照结果。

上面三个宏在AutoLight.cginc中可以找到声明。结果效果如下：

        要注意的是，这些宏会使用上下文变量进行相关计算，所以需要使自定义的变量名与这些宏中使用的变量名一致，如a2f中顶点坐标变量必须交vertex，vert输出必须为v2f且命名为v，顶点位置变量需要叫pos。 

统一管理光照衰减和阴影

这个宏接受三个参数，第一个参数atten无需声明，该宏会帮我们声明，v2f i 传入用于计算阴影值，最终会得到atten为光照衰减和阴影的乘积。

UNITY_LIGHT_AATENUATION(atten,i,i.worldPos);
//i --> v2f i ，为frag的输入变量。

透明度物体的阴影 

        前面投射阴影使用的fallback中的vertexlit中提供的shadowcaster的实现往往不能实现透明物体的阴影，透明度测试中需要舍弃某些片元。因此我们在之前透明度测试的shader中，加入关于阴影的计算,计算和上面没什么区别，要注意的是要修改fallback为vertexlit。 

 

 如果出现不应该透过光的部分，是因为默认情况下把物体渲染到深度图和阴影映射纹理中仅考虑正面，由于有一些面完全背对光源，他们的深度信息并没有被加入阴影映射纹理的计算中，可以将正方体meshrenderer中cast shadows 设置为two sided，强制unity计算所有面的信息。

透明度混合 

当仅对透明度混合的shader加入阴影计算的部分的话，半透明物体并不会向下方平面投射阴影，也不会接受右侧平面的阴影，看起来像完全透明一样，unity这样为了优化性能，可以强制为半透明物体生成音乐，通过把他们的fallback设置为vertexlit、diffuse等不透明物体用的，就可以找到阴影投射的pass，并且在mesh renderer组件上cast shadows 和receive shadows 选择是否投射或接收。

一个标准的光照着色器：

Shader "Unity Shaders Book/Common/Bumped Specular" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		_BumpMap ("Normal Map", 2D) = "bump" {}
		_Specular ("Specular Color", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}
		
		Pass { 
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma multi_compile_fwdbase	
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float4 TtoW0 : TEXCOORD1;  
                float4 TtoW1 : TEXCOORD2;  
                float4 TtoW2 : TEXCOORD3; 
				SHADOW_COORDS(4)
			};
			
			v2f vert(a2v v) {
			 	v2f o;
			 	o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
			 
			 	o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
			 	o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				TANGENT_SPACE_ROTATION;
				
				float3 worldPos = mul(_Object2World, v.vertex).xyz;  
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
                fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
                fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 
                
                o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);  
                o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);  
                o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);  
  				
  				TRANSFER_SHADOW(o);
			 	
			 	return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
				
				fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
				bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));

				fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
			 	fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
			 	
			 	fixed3 halfDir = normalize(lightDir + viewDir);
			 	fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
			
				UNITY_LIGHT_ATTENUATION(atten, i, worldPos);

				return fixed4(ambient + (diffuse + specular) * atten, 1.0);
			}
			
			ENDCG
		}
		
		Pass { 
			Tags { "LightMode"="ForwardAdd" }
			
			Blend One One
		
			CGPROGRAM
			
			#pragma multi_compile_fwdadd
			// Use the line below to add shadows for point and spot lights
//			#pragma multi_compile_fwdadd_fullshadows
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			float _BumpScale;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float4 TtoW0 : TEXCOORD1;  
                float4 TtoW1 : TEXCOORD2;  
                float4 TtoW2 : TEXCOORD3;
				SHADOW_COORDS(4)
			};
			
			v2f vert(a2v v) {
			 	v2f o;
			 	o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
			 
			 	o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
			 	o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				float3 worldPos = mul(_Object2World, v.vertex).xyz;  
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
                fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
                fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 
	
  				o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
			  	o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
			  	o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);  
			 	
			 	TRANSFER_SHADOW(o);
			 	
			 	return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
				
				fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
				bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
				
				fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;
				
			 	fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
			 	
			 	fixed3 halfDir = normalize(lightDir + viewDir);
			 	fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
			
				UNITY_LIGHT_ATTENUATION(atten, i, worldPos);

				return fixed4((diffuse + specular) * atten, 1.0);
			}
			
			ENDCG
		}
	} 
	FallBack "Specular"
}