当我尝试使用以下 Cython 代码时，我收到了我在最后发布的有关未定义 operator() 的错误。看来，当我尝试使用运算符时，Cython 不会将其解释为成员函数(注意 C++ 源代码中没有成员访问权限)。如果我尝试调用 prng.operator()()，那么 Cython 将无法转换。

在 Cython 中使用运算符重载是否需要一些特殊的东西？

import numpy as np
cimport numpy as np

cdef extern from "ratchet.hpp" namespace "ratchet::detail":
    cdef cppclass Ratchet:
        Ratchet()
        unsigned long get64()

cdef extern from "float.hpp" namespace "prng":
    cdef cppclass FloatPRNG[T]:
        double operator()()



cdef FloatPRNG[Ratchet] prng

def ratchet_arr(np.ndarray[np.float64_t, ndim=1] A):
    cdef unsigned int i
    for i in range(len(A)):
        A[i] = prng()


def ratchet_arr(np.ndarray[np.float64_t, ndim=2] A):
    cdef unsigned int i, j
    for i in range(len(A)):
        for j in range(len(A[0])):
            A[i][j] = prng()

ratchet.cpp:在函数“PyObject* __pyx_pf_7ratchet_ratchet_arr(PyObject*, PyArrayObject*)”中: ratchet.cpp:1343:162: 错误:‘operator()’ 未定义 *__Pyx_BufPtrStrided1d(__pyx_t_5numpy_float64_t *, __pyx_pybuffernd_A.rcbuffer->pybuffer.buf, __pyx_t_3, __pyx_pybuffernd_A.diminfo[0].strides) = operator()();

一些受 Ianh 启发的信息。当对象是堆栈分配时，似乎不能使用 operator()

cat thing.pyx
cdef extern from 'thing.hpp':
    cdef cppclass Thing:
        Thing(int)
        Thing()
        int operator()()

# When this function doesn't exist, thing.so compiles fine
cpdef ff():
    cdef Thing t
    return t()

cpdef gg(x=None):
    cdef Thing* t
    if x:
        t = new Thing(x)
    else:
        t = new Thing()
    try:
        return t[0]()
    finally:
        del t

cat thing.hpp
#pragma once

class Thing {
    int val;

    public:
    Thing(int v): val(v) {}
    Thing() : val(4) {}

    int operator()() { return val; }
};

最佳答案

更新:这应该在 Cython 0.24 及更高版本中得到修复。为了完整起见，我将解决方法留在这里。

在仔细查看像您这样的示例的 C++ 编译器错误之后，似乎发生的情况是 Cython 在为堆栈分配的对象重载 operator() 时存在错误。 它似乎试图调用 operator() ，就好像它是您定义的某种函数而不是您定义的 C++ 对象的方法。 有两种可能的解决方法。 您可以为调用运算符起别名，并在 Cython 中为其指定一个与在 C 中不同的名称。 您也可以只在堆上分配对象。

根据您的用例，只修补 Cython 生成的 C 文件可能是个好主意。 您基本上只需搜索对 operator() 的挂起调用，将它们更改为对正确 C++ 对象的方法调用。 我在下面的示例中尝试了这个并且它起作用了，并且跟踪我需要将哪些对象插入到代码中并不是非常困难。 如果您只是尝试将 Python 绑定(bind)写入库并且不会在 Cython 级别对 operator() 进行大量调用，则此方法会很有效，但它可能会变得非常痛苦如果您打算在 Cython 中进行大量开发。

您也可以尝试报告错误。 无论您采用哪条路线让它工作，这都会很好。 看起来应该也很容易修复，但我不是 Cython 内部的专家。

这是一个最小的工作示例，说明如何在 Cython 中为堆分配对象使用 operator()。它适用于 Cython 0.21。

Thing.hpp

#pragma once

class Thing{
    public:
        int val;
        Thing(int);
        int operator()(int);};

Thing.cpp

#include "Thing.hpp"

Thing::Thing(int val){
    this->val = val;}

int Thing::operator()(int num){
    return this->val + num;}

Thing.pxd

cdef extern from "Thing.hpp":
    cdef cppclass Thing:
        Thing(int val) nogil
        int operator()(int num) nogil

test_thing.pyx

from Thing cimport Thing

cpdef test_thing(int val, int num):
    cdef Thing* t = new Thing(val)
    print "initialized thing"
    print "called thing."
    print "value was: ", t[0](num)
    del t
    print "deleted thing"

setup.py

from distutils.core import setup
from distutils.extension import Extension
from Cython.Distutils import build_ext
from os import system

# First compile an object file containing the Thing class.
system('g++ -c Thing.cpp -o Thing.o')

ext_modules = [Extension('test_thing',
                         sources=['test_thing.pyx'],
                         language='c++',
                         extra_link_args=['Thing.o'])]

# Build the extension.
setup(name = 'cname',
      packages = ['cname'],
      cmdclass = {'build_ext': build_ext},
      ext_modules = ext_modules)

运行安装文件后，我在同一目录中启动Python解释器并运行

from test_thing import test_thing
test_thing(1, 2)

打印输出

initialized thing
called thing.
value was:  3
deleted thing

表明运营商工作正常。

现在，如果你想为分配给堆栈的对象执行此操作，你可以按如下方式更改 Cython 接口(interface):

Thing.pxd

cdef extern from "Thing.hpp":
    cdef cppclass Thing:
        Thing(int val) nogil
        int call "operator()"(int num) nogil

test_thing.pyx

from Thing cimport Thing

cpdef test_thing(int val, int num):
    cdef Thing t = Thing(val)
    print "initialized thing"
    print "called thing."
    print "value was: ", t.call(num)
    print "thing is deleted when it goes out of scope."

C++ 文件和设置文件仍然可以按原样使用。

关于c++ - Cython 不能使用 operator()，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/25898568/