我试图访问我的 XML 文件中的一些节点，但我无法让它工作，因为我可能不理解 Delphi 中的 XML-Namepsaces。

<gesmes:Envelope xmlns:gesmes="http://www.gesmes.org/xml/2002-08-01" xmlns="http://www.ecb.int/vocabulary/2002-08-01/eurofxref">
    <gesmes:subject>Reference rates</gesmes:subject>
    <gesmes:Sender>
        <gesmes:name>European Central Bank</gesmes:name>
    </gesmes:Sender>
    <Cube>
        <Cube time="2018-01-18">
            <Cube currency="USD" rate="1.2235"/>
            <Cube currency="JPY" rate="136.07"/>
            <Cube currency="BGN" rate="1.9558"/>
            <Cube currency="CZK" rate="25.365"/>
            <Cube currency="DKK" rate="7.4475"/>
            <Cube currency="GBP" rate="0.88208"/>
            <Cube currency="HUF" rate="308.51"/>
            <Cube currency="PLN" rate="4.1665"/>
            <Cube currency="RON" rate="4.6480"/>
            <Cube currency="SEK" rate="9.8305"/>
            <Cube currency="CHF" rate="1.1748"/>
            <Cube currency="NOK" rate="9.6013"/>
            <Cube currency="HRK" rate="7.4409"/>
            <Cube currency="RUB" rate="69.2126"/>
            <Cube currency="TRY" rate="4.6374"/>
            <Cube currency="AUD" rate="1.5311"/>
            <Cube currency="BRL" rate="3.9321"/>
            <Cube currency="CAD" rate="1.5229"/>
            <Cube currency="CNY" rate="7.8582"/>
            <Cube currency="HKD" rate="9.5648"/>
            <Cube currency="IDR" rate="16325.38"/>
            <Cube currency="ILS" rate="4.1950"/>
            <Cube currency="INR" rate="78.1210"/>
            <Cube currency="KRW" rate="1306.61"/>
            <Cube currency="MXN" rate="22.8174"/>
            <Cube currency="MYR" rate="4.8396"/>
            <Cube currency="NZD" rate="1.6759"/>
            <Cube currency="PHP" rate="62.068"/>
            <Cube currency="SGD" rate="1.6175"/>
            <Cube currency="THB" rate="39.054"/>
            <Cube currency="ZAR" rate="15.0035"/>
        </Cube>
    </Cube>
</gesmes:Envelope>

我试过像那样访问立方体节点:

procedure TForm2.Button1Click(Sender: TObject);
var
  Doc: IXMLDocument;
  Node: IXMLNode;
  sl: TStringList;
begin
  Doc := LoadXMLDocument('C:\Users\Kevin\Desktop\test.xml');
  node := Doc.DocumentElement;

  ShowMessage(Node.ChildNodes['Cube']);
end;

我意识到我的输出是:“gesmes:Cube”。 我认为那是不对的……我期望获得第一个“立方体”节点。 我不确定 Delphi 中的命名空间是如何工作的，所以如果我能在这里得到一些帮助就太好了。

最好的问候!

最佳答案

您正在将 IXMLNode 接口(interface)指针传递给 ShowMessage()，它需要一个 string。因此，据推测，在您的真实代码中，您实际上已经完成了 ShowMessage(Node.ChildNodes['Cube'].NodeName);。

它确实报告了 'gesmes:Cube'，这不是您所期望的。你要的Cube在http://www.ecb.int/vocabulary/2002-08-01/eurofxref命名空间里，和它的命名空间不一样父级 信封 (http://www.gesmes.org/xml/2002-08-01)。所以实际发生的是 DocumentElement.ChildNodes['Cube'] 试图在 Envelope 的命名空间中找到一个 Cube，但没有找到元素，所以 TXMLDocument 创建一个新的 因为 doNodeAutoCreate 标志在 Doc.Options 属性中默认启用.那是 DocumentElement.ChildNodes['Cube'] 返回的 Cube，而不是您想要的 Cube。

因为 Envelope 和它的直接 Cube child 在不同的命名空间中，你不能在DocumentElement，您必须改用 ChildNodes.FindNode()，指定 Cube 的实际命名空间:

Node := Doc.DocumentElement;
Node := Node.ChildNodes.FindNode('Cube', 'http://www.ecb.int/vocabulary/2002-08-01/eurofxref');

下一个 Cube 与其父 Cube 在同一个命名空间中，因此您可以使用 ChildNodes['Cube'] 来获取它:

Node := Node.ChildNodes['Cube'];

如果需要，您可以访问 time 属性:

Node.Attributes['time']

然后遍历剩余的子 Cube:

Node := Node.ChildNodes.First;
while Node <> nil do
begin
  if Node.LocalName = 'Cube' then
  begin
    // use Node.Attributes['currency'] and Node.Attributes['rate'] as needed...
  end;
  Node := Node.NextSibling;
end;

完整代码如下:

procedure TForm2.Button1Click(Sender: TObject);
var
  Doc: IXMLDocument;
  Node: IXMLNode;
  sl: TStringList;
begin
  sl := TStringList.Create;
  try
    Doc := LoadXMLDocument('C:\Users\Kevin\Desktop\test.xml');
    try
      Node := Doc.DocumentElement;
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes.FindNode('Cube', 'http://www.ecb.int/vocabulary/2002-08-01/eurofxref');
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes['Cube'];
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes.First;
      while Node <> nil do
      begin
        if Node.LocalName = 'Cube' then
          sl.Add(Node.Attributes['currency'] + '=' + Node.Attributes['rate']);
        Node := Node.NextSibling;
      end;
    finally
      Node := nil;
      Doc := nil;
    end;

    // use sl as needed...

  finally
    sl.Free;
  end;
end;

关于Delphi 中的 XML 命名空间，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/48343141/