我的问题与这个问题有些相关:Explicitly implemented interface and generic constraint .

但是，我的问题是编译器如何启用泛型约束以消除对显式实现接口(interface)的值类型进行装箱的需要。

我想我的问题可以归结为两个部分:

1. 在访问显式实现的接口(interface)成员时要求对值类型进行装箱的幕后 CLR 实现发生了什么，以及

2. 删除此要求的通用约束会发生什么情况？

一些示例代码:

internal struct TestStruct : IEquatable<TestStruct>
{
    bool IEquatable<TestStruct>.Equals(TestStruct other)
    {
        return true;
    }
}

internal class TesterClass
{
    // Methods
    public static bool AreEqual<T>(T arg1, T arg2) where T: IEquatable<T>
    {
        return arg1.Equals(arg2);
    }

    public static void Run()
    {
        TestStruct t1 = new TestStruct();
        TestStruct t2 = new TestStruct();
        Debug.Assert(((IEquatable<TestStruct>) t1).Equals(t2));
        Debug.Assert(AreEqual<TestStruct>(t1, t2));
    }
}

以及由此产生的 IL:

.class private sequential ansi sealed beforefieldinit TestStruct
    extends [mscorlib]System.ValueType
    implements [mscorlib]System.IEquatable`1<valuetype TestStruct>
{
    .method private hidebysig newslot virtual final instance bool System.IEquatable<TestStruct>.Equals(valuetype TestStruct other) cil managed
    {
        .override [mscorlib]System.IEquatable`1<valuetype TestStruct>::Equals
        .maxstack 1
        .locals init (
            [0] bool CS$1$0000)
        L_0000: nop 
        L_0001: ldc.i4.1 
        L_0002: stloc.0 
        L_0003: br.s L_0005
        L_0005: ldloc.0 
        L_0006: ret 
    }

}

.class private auto ansi beforefieldinit TesterClass
    extends [mscorlib]System.Object
{
    .method public hidebysig specialname rtspecialname instance void .ctor() cil managed
    {
        .maxstack 8
        L_0000: ldarg.0 
        L_0001: call instance void [mscorlib]System.Object::.ctor()
        L_0006: ret 
    }

    .method public hidebysig static bool AreEqual<([mscorlib]System.IEquatable`1<!!T>) T>(!!T arg1, !!T arg2) cil managed
    {
        .maxstack 2
        .locals init (
            [0] bool CS$1$0000)
        L_0000: nop 
        L_0001: ldarga.s arg1
        L_0003: ldarg.1 
        L_0004: constrained !!T
        L_000a: callvirt instance bool [mscorlib]System.IEquatable`1<!!T>::Equals(!0)
        L_000f: stloc.0 
        L_0010: br.s L_0012
        L_0012: ldloc.0 
        L_0013: ret 
    }

    .method public hidebysig static void Run() cil managed
    {
        .maxstack 2
        .locals init (
            [0] valuetype TestStruct t1,
            [1] valuetype TestStruct t2,
            [2] bool areEqual)
        L_0000: nop 
        L_0001: ldloca.s t1
        L_0003: initobj TestStruct
        L_0009: ldloca.s t2
        L_000b: initobj TestStruct
        L_0011: ldloc.0 
        L_0012: box TestStruct
        L_0017: ldloc.1 
        L_0018: callvirt instance bool [mscorlib]System.IEquatable`1<valuetype TestStruct>::Equals(!0)
        L_001d: stloc.2 
        L_001e: ldloc.2 
        L_001f: call void [System]System.Diagnostics.Debug::Assert(bool)
        L_0024: nop 
        L_0025: ldloc.0 
        L_0026: ldloc.1 
        L_0027: call bool TesterClass::AreEqual<valuetype TestStruct>(!!0, !!0)
        L_002c: stloc.2 
        L_002d: ldloc.2 
        L_002e: call void [System]System.Diagnostics.Debug::Assert(bool)
        L_0033: nop 
        L_0034: ret 
    }

}

关键调用是constrained !!T而不是 box TestStruct , 但后续调用仍然是 callvirt在这两种情况下。

所以我不知道进行虚拟调用所需的装箱是什么，我尤其不明白如何使用受限于值类型的泛型来消除装箱操作的需要。

先谢谢大家了...

最佳答案

My question, however, is how the compiler enables a generic constraint to eliminate the need for boxing a value type that explicitly implements an interface.

“编译器”不清楚您指的是抖动还是 C# 编译器。 C# 编译器通过在虚拟调用上发出受约束的前缀来做到这一点。参见 the documentation of the constrained prefix了解详情。

What is going on with the behind-the-scenes CLR implementation that requires a value type to be boxed when accessing an explicitly implemented interface member

被调用的方法是否是显式实现的接口(interface)成员并不特别相关。一个更普遍的问题是为什么任何虚拟调用都需要装箱的值类型？

传统上认为虚调用是对虚函数表中方法指针的间接调用。这并不是接口(interface)调用在 CLR 中的确切工作方式，但对于本次讨论而言，这是一个合理的心智模型。

如果这就是调用虚拟方法的方式，那么虚表从哪里来？值类型中没有 vtable。值类型只是在它的存储中有它的值。装箱创建对对象的引用，该对象具有设置为指向所有值类型的虚方法的虚表。 (再次提醒您，这不是完全接口(interface)调用的工作方式，但这是一种很好的思考方式。)

What happens with a generic constraint that removes this requirement?

抖动将为泛型方法的每个不同值类型参数构造生成新代码。如果您要为每种不同的值类型生成新代码，那么您可以针对该特定值类型定制该代码。这意味着您不必构建一个 vtable 然后查找 vtable 的内容是什么!您知道 vtable 的内容是什么，因此只需生成代码以直接调用该方法即可。

关于c# - 通用约束如何防止使用隐式实现的接口(interface)对值类型进行装箱？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/5531948/