我使用的 Oracle 版本是:

BANNER
Oracle Database 10g Enterprise Edition Release 10.2.0.4.0 - 64bi
PL/SQL Release 10.2.0.4.0 - Production
CORE    10.2.0.4.0  Production
TNS for IBM/AIX RISC System/6000: Version 10.2.0.4.0 - Productio
NLSRTL Version 10.2.0.4.0 - Production

在上一个问题中，我问过如何将 clob 转换为表，请参见:

From XML to list of paths in Oracle PL/SQL environment

我收到的答案很好，它适用于不太大的 XML。

但是如果我有一个名为 MY_TABLE_ONE 的表，其中有一个名为 MY_FIELD 的字段，它是一个内容非常大(例如 500 KB)的 CLOB，则以下语句不会在合理的时间内退出:

CREATE TABLE MY_TABLE_TWO
AS
   WITH PARAMS AS (SELECT   XMLTYPE (MY_FIELD) FROM MY_TABLE_ONE)
   SELECT   ELEMENT_PATH, ELEMENT_TEXT
     FROM   XMLTABLE (
               '              
      for $i in $doc/descendant-or-self::*
        return <element>
                 <element_path> {$i/string-join(ancestor-or-self::*/name(.), ''/'')} </element_path>
                 <element_content> {$i/text()}</element_content>
               </element>  
    '
                  PASSING (SELECT   * FROM PARAMS) AS "doc"
                  COLUMNS ELEMENT_PATH VARCHAR2 (4000) PATH '//element_path',
                          ELEMENT_TEXT VARCHAR2 (4000) PATH '//element_content'
            );

有没有其他方法可以更有效地转换存储在 CLOB 列中的 XML，在具有路径列表和相应值的 Oracle 表中？

上面的说法是对的，但是需要太多的时间来敲定。

非常感谢您考虑我的请求。

编辑:

我已经尝试过这个迭代解决方案，但没有成功:-(

BEGIN
   DECLARE
      CURSOR S_CUR
      IS
         WITH PARAMS AS (SELECT   XMLTYPE (MY_FIELD) FROM MY_TABLE_ONE)
         SELECT   ELEMENT_PATH, ELEMENT_TEXT
           FROM   XMLTABLE (
                     '              
      for $i in $doc/descendant-or-self::*
        return <element>
                 <element_path> {$i/string-join(ancestor-or-self::*/name(.), ''/'')} </element_path>
                 <element_content> {$i/text()}</element_content>
               </element>  
    '
                        PASSING (SELECT   * FROM PARAMS where rownum < 101) AS "doc"
                        COLUMNS ELEMENT_PATH VARCHAR2 (4000) PATH '//element_path',
                                ELEMENT_TEXT VARCHAR2 (4000) PATH '//element_content'
                  );

      TYPE FETCH_ARRAY IS TABLE OF S_CUR%ROWTYPE;

      S_ARRAY   FETCH_ARRAY;
   BEGIN
      EXECUTE IMMEDIATE 'ALTER SESSION SET DB_FILE_MULTIBLOCK_READ_COUNT=256';

      EXECUTE IMMEDIATE 'TRUNCATE TABLE GOOFY99 DROP STORAGE';

      OPEN S_CUR;

      LOOP
         FETCH S_CUR
         BULK COLLECT INTO   S_ARRAY
         LIMIT 500;

         FORALL I IN 1 .. S_ARRAY.COUNT
            INSERT                                                  /*+APPEND */
                  INTO GOOFY99
            VALUES   S_ARRAY (I);

         COMMIT;
         EXIT WHEN S_CUR%NOTFOUND;
      END LOOP;

      CLOSE S_CUR;

      COMMIT;
   END;
END;

最佳答案

UPD 我发现了相当大的 xml 文件 (140 KB)。我的系统:配备核心 i5 处理器(2400 MHz)的笔记本电脑，虚拟机内的 oracle 12c，处理时间 - 0.38 秒。 这种方法是我所知道的唯一选择。我在 w3schools.com 上找到的 xml 示例。

declare
  xml_str clob := q'[<?xml version="1.0" encoding="UTF-8"?>
<CATALOG>
 <CD>
  <TITLE>Empire Burlesque</TITLE>
  <ARTIST>Bob Dylan</ARTIST>
  <COUNTRY>USA</COUNTRY>
  <COMPANY>Columbia</COMPANY>
  <PRICE>10.90</PRICE>
  <YEAR>1985</YEAR>
 </CD>
 <CD>
  <TITLE>Hide your heart</TITLE>
  <ARTIST>Bonnie Tyler</ARTIST>
  <COUNTRY>UK</COUNTRY>
  <COMPANY>CBS Records</COMPANY>
  <PRICE>9.90</PRICE>
  <YEAR>1988</YEAR>
 </CD>
</CATALOG>]';

v_doc  dbms_xmldom.domdocument;
node   dbms_xmldom.domnode;
txt    varchar2(4000);
type   t_list is table of number index by varchar2(4000);
v_list t_list;
  procedure enum_nodes(n dbms_xmldom.domnode, tag_name varchar2) is
    chn  dbms_xmldom.domnode;
    nl   dbms_xmldom.domnodelist;
  begin
    nl := dbms_xmldom.getchildnodes(n);
    for i in 0..dbms_xmldom.getlength(nl) loop
      chn := dbms_xmldom.item(nl, i);

      if dbms_xmldom.getnodetype(chn) = 1 then
         enum_nodes(chn, tag_name || dbms_xmldom.getnodeName(chn) || '/');
      elsif dbms_xmldom.getnodetype(chn) = 3 then
         v_list(tag_name || dbms_xmldom.getnodevalue(chn)) := 1;
      end if;
    end loop;
  end;
begin
  v_doc := dbms_xmldom.newdomdocument(xml_str);
  node := dbms_xmldom.makenode(v_doc);

  enum_nodes(node, '/');

  txt := v_list.first;
  while txt is not null loop
     dbms_output.put_line(txt);
     txt := v_list.next(txt);
  end loop;
end;
/

关于xml - 从 CLOB 中的 XML，到带有路径列表的 Oracle 表，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/26753055/