草庐IT

windows - 批处理脚本读取连续写入的文件

coder 2024-06-16 原文

我有一个文件正在不断写入这样的信息

HU/gen/tcfg/target/jacinto/starter/starter_b1.cfg

32.77 34% 141.59kB/s 0:00:00

94.64 100% 405.35kB/s 0:00:00 (xfer#60, to-check=1002/1097)

这是rsync工具的输出，将文件夹复制到另一个路径

我正在尝试编写一个批处理脚本来读取此文件并计算要复制的数据总量，重点放在这一行

94.64 100% 405.35kB/s 0:00:00 (xfer#60, to-check=1002/1097)

数字 94.64 是以字节为单位的文件大小，所以我猜我应该从行中提取“100%”之前的任何内容并添加它

但是我不知道如何在写入文件的同时连续读取文件

有人可以帮忙吗？

谢谢

最佳答案

这是一个示例，说明如何在另一个进程正在写入文件时读取文件。这与 jeb 显示的内容非常相似，只是我添加了一个通用测试来查看该过程是否完成。它假定进程在整个执行过程中保持对文件的锁定，并且还假定 20 个连续的空行表示文件结束，或者我们正在等待进程的更多输出。 20 个空行阈值可以设置为适合您的任何数字。

如果进程将部分行写入文件，则此解决方案可能无法正常工作。我相信如果进程总是在一次操作中完整地写入每一行，那是可靠的。此外，行必须小于或等于 1021 字节长，并且必须以回车换行结束。

@echo off
setlocal enableDelayedExpansion
set "file=test.txt"

set emptyCount=0
del "%file%

:: For this test, I will start an asynchronous process in a new window that
:: writes a directory listing to an output file 3 times, with a 5 second pause
:: between each listing.
start "" cmd /c "(for /l %%N in (1 1 3) do @dir & ping localhost -n 6 >nul) >"%file%""

:wait for the output file to be created and locked
if not exist "%file%" goto :wait

:: Now read and process the file, as it is being written.
call :read <"%file%"
exit /b

:read
set "ln="
set /p "ln="
if defined ln (

  REM Process non-empty line here - test if correct line, extract size, and add
  REM I will simply echo the line instead
  echo(!ln!

  REM Reset emptyCount for end of file test and read next line
  set /a emptyCount=0
  goto :read

) else ( REM End of file test

  REM Count how many consecutive empty lines have been read.
  set /a emptyCount+=1

  REM Assume that 20 consecutive empty lines signifies either end of file
  REM or else waiting for output. If haven't reached 20 consectutive
  REM empty lines, then read next line.
  if !emptyCount! lss 20 goto :read

  REM Test if output file is still locked by attempting to redirect an unused
  REM stream to the file in append mode. If the redirect fails, then the file
  REM is still locked, meaning we are waiting for the process to finish and have
  REM not reached the end. So wait 1 sec so as not to consume 100% of CPU, then
  REM reset count and try to read the next line again.
  REM If the file is not locked, then we are finished, so simply fall through
  REM and exit.
  (echo off 9>>"%file%")2>nul || (
     set emptyCount=0
     ping localhost -n 2 >nul
     goto :read
  )
)
exit /b

关于windows - 批处理脚本读取连续写入的文件，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/14829657/

windows批处理fileREMsectionbatch-file

有关windows - 批处理脚本读取连续写入的文件的更多相关文章

  1. ruby - 使用 RubyZip 生成 ZIP 文件时设置压缩级别 - 2

    我有一个Ruby程序，它使用rubyzip压缩XML文件的目录树。gem。我的问题是文件开始变得很重，我想提高压缩级别，因为压缩时间不是问题。我在rubyzipdocumentation中找不到一种为创建的ZIP文件指定压缩级别的方法。有人知道如何更改此设置吗？是否有另一个允许指定压缩级别的Ruby库？ 最佳答案 这是我通过查看ruby​​zip内部创建的代码。level=Zlib::BEST_COMPRESSIONZip::ZipOutputStream.open(zip_file)do|zip|Dir.glob("**/*")d

  2. ruby - 其他文件中的 Rake 任务 - 2

    我试图在一个项目中使用rake，如果我把所有东西都放到Rakefile中，它会很大并且很难读取/找到东西，所以我试着将每个命名空间放在lib/rake中它自己的文件中，我添加了这个到我的rake文件的顶部:Dir['#{File.dirname(__FILE__)}/lib/rake/*.rake'].map{|f|requiref}它加载文件没问题，但没有任务。我现在只有一个.rake文件作为测试，名为“servers.rake”，它看起来像这样:namespace:serverdotask:testdoputs"test"endend所以当我运行rakeserver:testid时

  3. ruby-on-rails - 在 Rails 中将文件大小字符串转换为等效千字节 - 2

    我的目标是转换表单输入，例如“100兆字节”或“1GB”，并将其转换为我可以存储在数据库中的文件大小(以千字节为单位)。目前，我有这个:defquota_convert@regex=/([0-9]+)(.*)s/@sizes=%w{kilobytemegabytegigabyte}m=self.quota.match(@regex)if@sizes.include?m[2]eval("self.quota=#{m[1]}.#{m[2]}")endend这有效，但前提是输入是倍数(“gigabytes”，而不是“gigabyte”)并且由于使用了eval看起来疯狂不安全。所以，功能正常，

  4. ruby - 在 Ruby 程序执行时阻止 Windows 7 PC 进入休眠状态 - 2

    我需要在客户计算机上运行Ruby应用程序。通常需要几天才能完成(复制大备份文件)。问题是如果启用sleep，它会中断应用程序。否则，计算机将持续运行数周，直到我下次访问为止。有什么方法可以防止执行期间休眠并让Windows在执行后休眠吗？欢迎任何疯狂的想法;-) 最佳答案 Here建议使用SetThreadExecutionStateWinAPI函数，使应用程序能够通知系统它正在使用中，从而防止系统在应用程序运行时进入休眠状态或关闭显示。像这样的东西:require'Win32API'ES_AWAYMODE_REQUIRED=0x0

  5. ruby-on-rails - Rails 3 中的多个路由文件 - 2

    Rails2.3可以选择随时使用RouteSet#add_configuration_file添加更多路由。是否可以在Rails3项目中做同样的事情？ 最佳答案 在config/application.rb中:config.paths.config.routes在Rails3.2(也可能是Rails3.1)中，使用:config.paths["config/routes"] 关于ruby-on-rails-Rails3中的多个路由文件，我们在StackOverflow上找到一个类似的问题

  6. ruby - 将差异补丁应用于字符串/文件 - 2

    对于具有离线功能的智能手机应用程序，我正在为Xml文件创建单向文本同步。我希望我的服务器将增量/差异(例如GNU差异补丁)发送到目标设备。这是计划:Time=0Server:hasversion_1ofXmlfile(~800kiB)Client:hasversion_1ofXmlfile(~800kiB)Time=1Server:hasversion_1andversion_2ofXmlfile(each~800kiB)computesdeltaoftheseversions(=patch)(~10kiB)sendspatchtoClient(~10kiBtransferred)Cl

  7. ruby - 如何将脚本文件的末尾读取为数据文件(Perl 或任何其他语言) - 2

    我正在寻找执行以下操作的正确语法(在Perl、Shell或Ruby中):#variabletoaccessthedatalinesappendedasafileEND_OF_SCRIPT_MARKERrawdatastartshereanditcontinues. 最佳答案 Perl用__DATA__做这个:#!/usr/bin/perlusestrict;usewarnings;while(){print;}__DATA__Texttoprintgoeshere 关于ruby-如何将脚

  8. ruby - 如何以所有可能的方式将字符串拆分为长度最多为 3 的连续子字符串？ - 2

    我试图获取一个长度在1到10之间的字符串，并输出将字符串分解为大小为1、2或3的连续子字符串的所有可能方式。例如:输入:123456将整数分割成单个字符，然后继续查找组合。该代码将返回以下所有数组。[1,2,3,4,5,6][12,3,4,5,6][1,23,4,5,6][1,2,34,5,6][1,2,3,45,6][1,2,3,4,56][12,34,5,6][12,3,45,6][12,3,4,56][1,23,45,6][1,2,34,56][1,23,4,56][12,34,56][123,4,5,6][1,234,5,6][1,2,345,6][1,2,3,456][123

  9. ruby - 如何指定 Rack 处理程序 - 2

    Rackup通过Rack的默认处理程序成功运行任何Rack应用程序。例如:classRackAppdefcall(environment)['200',{'Content-Type'=>'text/html'},["Helloworld"]]endendrunRackApp.new但是当最后一行更改为使用Rack的内置CGI处理程序时，rackup给出“NoMethodErrorat/undefinedmethod`call'fornil:NilClass”:Rack::Handler::CGI.runRackApp.newRack的其他内置处理程序也提出了同样的反对意见。例如Rack

  10. ruby - 使用 Vim Rails，您可以创建一个新的迁移文件并一次性打开它吗？ - 2

    使用带有Rails插件的vim，您可以创建一个迁移文件，然后一次性打开该文件吗？textmate也可以这样吗？ 最佳答案 你可以使用rails.vim然后做类似的事情::Rgeneratemigratonadd_foo_to_bar插件将打开迁移生成的文件，这正是您想要的。我不能代表textmate。 关于ruby-使用VimRails，您可以创建一个新的迁移文件并一次性打开它吗？，我们在StackOverflow上找到一个类似的问题： https://sta

随机推荐