编辑:我开始悬赏这个问题。目前，我已经开始使用 VS2010 Pro Beta 开发我的应用程序，但我真的希望它能够使用 Express Edition 构建，因为我们通常不是 .net 商店，即使一个或两个开发人员拥有 VS PRO，我们整个团队都无法使用它。

要成为公认的答案并领取赏金，您必须提供示例代码和说明，以允许使用 vb 2008 Express Edition 安装和卸载 Windows 服务。您不一定需要从我的代码开始(但它的要点包含在下面)。

我编写了一个 VB.NET 应用程序，我想将其作为服务运行。目前我使用的是 VB.net Express Edition (2008)，它没有附带“Service”模板，但我添加了一个 Service 类(继承自 ServiceBase)和一个 Installer 类(继承自 Installer)；在这两种情况下，我都遵循 MSDN 中的示例代码。不幸的是，我无法让此代码作为服务安装和运行。

这段代码的核心是一个名为 sampleListener 的 TCP 监听器类。如果我将 sampleListener 类设置为启动对象并运行我的项目，它作为控制台应用程序运行良好。

有一个服务类(如下)，它只是启动 sampleListener。

Public Class sampleSocketService
    Inherits System.ServiceProcess.ServiceBase

    Public Sub New()
        Me.ServiceName = "sample Socket Service"
        Me.CanStop = True
        Me.CanPauseAndContinue = True
        Me.AutoLog = True
    End Sub

    Shared Sub Main()
        System.ServiceProcess.ServiceBase.Run(New sampleSocketService)
    End Sub

    Protected Overrides Sub OnStart(ByVal args() As String)
        sampleListener.Main()
    End Sub

End Class

还有一个我认为是问题根源的安装程序类。这是我最初编写的安装程序类。

Imports System
Imports System.Collections
Imports System.Configuration.Install
Imports System.ServiceProcess
Imports System.ComponentModel

<RunInstallerAttribute(True)> _
Public Class sampleSocketServiceInstaller
    Inherits Installer
    Private serviceInstaller1 As ServiceInstaller
    Private processInstaller As ServiceProcessInstaller

    Public Sub New()
        ' Instantiate installers for process and services.
        processInstaller = New ServiceProcessInstaller()
        serviceInstaller1 = New ServiceInstaller()

        processInstaller.Account = ServiceAccount.LocalSystem
        serviceInstaller1.StartType = ServiceStartMode.Automatic

        ' ServiceName must equal those on ServiceBase derived classes.            
        serviceInstaller1.ServiceName = "sample Socket Service"

        ' Add installers to collection. Order is not important.
        Installers.Add(serviceInstaller1)
        Installers.Add(processInstaller)
    End Sub
End Class

在此运行 installutil.exe 会产生以下消息:

An exception occurred during the Install phase.
System.Security.SecurityException: The source was not found, but some or all event logs could not be searched.  Inaccessible logs: Security.

这看起来像是一个安全问题，但我正在使用以管理员身份运行打开的 cmd 窗口中运行。

我尝试了一个基于在线示例的非常简化的 Installer 类:

Imports System.ComponentModel
Imports System.Configuration.Install

<RunInstaller(True)> Public Class ProjectInstaller
    Inherits System.Configuration.Install.Installer

End Class

这看起来简单得可笑，我无法弄清楚它是如何工作的，事实上它并没有。但是，当使用此版本的安装程序类在项目上运行 installutil.exe 时，installutil.exe 不会抛出错误消息并报告服务已成功安装。

我怀疑我的安装程序类中的代码需要执行我第一个示例中的某些操作，但不执行导致错误的任何部分。

有什么建议吗？

(为了清楚起见并添加了最初未包含的代码示例，已对其进行了大量编辑)

最佳答案

这似乎对我有用，但我没有在您自己的代码中添加。

创建两个文件 Service1.vb 和 ProjectInstaller.vb。通常 Service1 和 ProjectInstaller 被设置为部分类，但为了在这里发布它们不是。我认为它没有任何副作用，但其他人可以对此发表评论。

我通常使用 bat 文件处理安装/卸载。

为项目添加两个引用

系统.服务进程
系统.配置.安装

服务1.vb

Imports System.ServiceProcess

Public Class Service1
Inherits System.ServiceProcess.ServiceBase

Protected Overrides Sub OnStart(ByVal args() As String)
End Sub

Protected Overrides Sub OnStop()
End Sub

<System.Diagnostics.DebuggerNonUserCode()> _
Protected Overrides Sub Dispose(ByVal disposing As Boolean)
    Try
        If disposing AndAlso components IsNot Nothing Then
            components.Dispose()
        End If
    Finally
        MyBase.Dispose(disposing)
    End Try
End Sub

<MTAThread()> _
<System.Diagnostics.DebuggerNonUserCode()> _
Shared Sub Main()
    Dim ServicesToRun() As System.ServiceProcess.ServiceBase

    ServicesToRun = New System.ServiceProcess.ServiceBase() {New Service1}

    System.ServiceProcess.ServiceBase.Run(ServicesToRun)
End Sub

Private components As System.ComponentModel.IContainer

<System.Diagnostics.DebuggerStepThrough()> _
Private Sub InitializeComponent()
    components = New System.ComponentModel.Container()
    Me.ServiceName = "Service1"
End Sub

End Class

项目安装程序.vb

Imports System.ComponentModel
Imports System.Configuration.Install

<System.ComponentModel.RunInstaller(True)> _
Public Class ProjectInstaller
Inherits System.Configuration.Install.Installer

Public Sub New()
    MyBase.New()

    InitializeComponent()

End Sub

<System.Diagnostics.DebuggerNonUserCode()> _
Protected Overrides Sub Dispose(ByVal disposing As Boolean)
    Try
        If disposing AndAlso components IsNot Nothing Then
            components.Dispose()
        End If
    Finally
        MyBase.Dispose(disposing)
    End Try
End Sub

Private components As System.ComponentModel.IContainer

<System.Diagnostics.DebuggerStepThrough()> _
Private Sub InitializeComponent()
    Me.ServiceProcessInstaller1 = New System.ServiceProcess.ServiceProcessInstaller
    Me.ServiceInstaller1 = New System.ServiceProcess.ServiceInstaller

    Me.ServiceProcessInstaller1.Account = System.ServiceProcess.ServiceAccount.LocalSystem
    Me.ServiceProcessInstaller1.Password = Nothing
    Me.ServiceProcessInstaller1.Username = Nothing

    Me.ServiceInstaller1.ServiceName = "Service1"
    Me.ServiceInstaller1.StartType = System.ServiceProcess.ServiceStartMode.Automatic

    Me.Installers.AddRange(New System.Configuration.Install.Installer() {Me.ServiceProcessInstaller1, Me.ServiceInstaller1})

End Sub
Friend WithEvents ServiceProcessInstaller1 As System.ServiceProcess.ServiceProcessInstaller
Friend WithEvents ServiceInstaller1 As System.ServiceProcess.ServiceInstaller

End Class

安装 bat

C:
CD \WINDOWS\Microsoft.NET\Framework\v2.0.50727
installutil "C:\Visual Studio 2008\Projects\....\Temp.exe"
pause
NET START Service1

卸载 bat

C:
CD \WINDOWS\Microsoft.NET\Framework\v2.0.50727
NET STOP Service1
installutil /u "C:\Visual Studio 2008\Projects\....\Temp.exe"

希望对你有用

关于.net - 如何使用 visual basic.net Express Edition 安装 Windows 服务？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/1870322/