我找不到使用加载程序填充选项卡 View 中的选项卡的方法。加载器在 TabView 之外时工作正常(即，如果我删除 mainTrial.qml 顶部的多行注释字符并且加载器加连接位于顶部。但是如果我将加载器作为一个选项卡，我得到一个错误“无法为单个属性分配多个值。我也不能使用 menuLoader.source 或 column1.menuLoader.source 或其他变体来解决 TabView 外部的加载程序。这是主文件。(另外两个定义信号的文件也包含在内，以便您可以看到信号有效)。我做错了什么？

编辑:(很好的排列和组合法则)我发现如果我进行连接声明，即选项卡上加载程序的子项，问题就会消失。我将在选项卡上分配一个“值”——即加载程序，现在我可以为每个选项卡加载一个 qml 项目。

//主要试验

import QtQuick 2.2
import QtQuick.Controls 1.1
import QtQuick.Layouts 1.1 


Item {
    id: trial
    width: 360
    height: 360
    ColumnLayout {
        id: column1
        spacing:150
        Item {Layout.fillHeight: true}
        TabView {
            id: tabPages
            Tab {
                id: welcomePage
                title: "Welcome"
                // /*
                Loader{
                    id: menuLoader
                    source: "mainTrial1.qml"
                    anchors.top: parent.top
                    Connections {
                        id: menuConnection
                        ignoreUnknownSignals: true
                        target: menuLoader.item
                        onMainTrial3: {
                            menuLoader.source = "mainTrial3.qml"
                            console.log("originated from " + origin)
                        }
                        onMainTrial1: {
                            menuLoader.source = "mainTrial1.qml"
                            console.log("originated from " + origin)
                        }
                    }
                }        
            }
            Tab {
                id: statusPage
                title: "Status"
            }
        }
    }
}

//mainTrial1(有一个信号定义)

此文件定义了用于加载下一个 qml 对象的信号之一。我将其包含在这里，以便您可以看到信号有效)。

import QtQuick 2.2
import QtQuick.Controls 1.1
import QtQuick.Layouts 1.1

Item {
    id: page1
    property string origin: "Hello"
    signal mainTrial3(string origin)
    ColumnLayout {
        spacing: 15
        Rectangle {
            width: 100
            height: 62
            color: "red"

            MouseArea {
                anchors.fill: parent
                onClicked: {
                    mainTrial3("origin = from MouseArea")
                }
            }
        }

        Button {
            text: "Sorting and scanning"
            onClicked: {
                mainTrial3(origin = "from Button")
            }
        }
    }
}

//mainTrial3(与其他信号定义)

此文件定义了用于重新加载先前 qml 对象的其他信号。我将它包含在这里，以便您可以看到当单击矩形时两个信号都有效。

import QtQuick 2.2
import QtQuick.Controls 1.1
import QtQuick.Layouts 1.1

Item {
    id: page3
    property string origin: "Hello"
    signal mainTrial1(string origin)
    GridLayout {
        columnSpacing: 5
        rowSpacing: 5
        columns: 1
        Rectangle {
            width: 100
            height: 62
            color: "blue"

            MouseArea{
                anchors.fill: parent
                onClicked: {
                    mainTrial1(origin = "from MouseArea1")
                }
            }
        }
        Rectangle {
            width: 100
            height: 62
            color: "blue"

            MouseArea{
                anchors.fill: parent
                onClicked: {
                    mainTrial1("from MouseArea2")
                }
            }
        }
    }
}

最佳答案

好的，所以我使用了您的代码，使用了一些代码，然后自定义了其余部分以加载单个选项卡，以便更轻松地讨论它。它不完全是你发布的内容，但它应该告诉你如何:

1. 在您的选项卡内点击某些内容时接收信号。
2. 在哪里以及如何加载您的标签。

有了这个，您应该有坚实的基础来进一步自定义和添加两个、三个等...选项卡，并根据我示例中的信号动态更改它们。

重要的是，Tab 本身就是一个Loader，所以不需要定义一个内部的Loader。接下来我还没有完全使用 QML(QWidget 更适合我)但是你使用的 Connections 似乎导致了一些问题，我不确定它们是否完全需要，所以我删除了它们来 self 的示例。

在我的示例中，我只是在选项卡中加载单个 QML 文件，并在您单击刚刚加载的选项卡内的蓝色矩形或红色矩形时发送信号。

您将能够在控制台中看到输出。我在信号处理程序中留下了评论，您可以在其中更改 Tab 的 source 并动态加载下一个 Tab。

尽情享受吧!

TabViewTest.qml

import QtQuick 2.2
import QtQuick.Controls 1.1
import QtQuick.Layouts 1.1


Item {
    id: tabViewTest
    width: 360
    height: 360

    TabView {
        id: tabView
        width: parent.width
        height: parent.height

        Tab {
            title: "Welcome"
            id: dynamicTab
            anchors.top: parent.top

            // [1] Specify the source URL to load the content.
            source: "RectanglesTab.qml"

            // [2] Define a signal within the Tab that will
            // be connected to the 'contentsClicked' signal
            // in each tab QML file.
            signal tabContentsClicked( string rectColor )

            // [3] Implement the signal handler.
            onTabContentsClicked: {
                console.log( "Clicked on a", rectColor, "rectangle." )

                // [4] Now that the user has clicked somewhere within the tab
                // you could optionally the source or sourceComponent here like
                // the comment below.
                //
                // Just make sure it also has a signal called 'contentsClicked'
                //
                // dynamicTab.source = "someOtherTab.qml"
            }

            onLoaded: {
                console.debug( "Loaded", source );

                // [4] Here's the key action, connect the signal 
                // 'contentsClicked' to our signal 
                // 'tabContentsClicked' from the loaded item 
                // i.e. RectanglesTab.qml
                dynamicTab.item.contentsClicked.connect(tabContentsClicked)
            }
        }

        Tab {
            id: statusTab
            title: "Status"
        }
    }
}

RectanglesTab.qml

import QtQuick 2.0
import QtQuick.Layouts 1.1

Rectangle {
    id: rectanglesTab
    width: parent.width
    height: parent.height
    color: "black"

    signal contentsClicked( string rectColor )

    GridLayout {
        width: parent.width
        height: parent.height
        columnSpacing: 5
        rowSpacing: 5
        columns: 1
        Rectangle {
            width: parent.width
            height: 120
            color: "blue"

            MouseArea{
                anchors.fill: parent
                onClicked: {
                    contentsClicked( "blue" )
                }
            }
        }
        Rectangle {
            width: parent.width
            height: 120
            color: "red"

            MouseArea{
                anchors.fill: parent
                onClicked: {
                    contentsClicked( "red" )
                }
            }
        }
    }
}

关于android - qml如何在tabview中使用loader，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/21596592/