我编写了一个简单的程序，它在 3d 环境中渲染一个球体，并根据球体周围的四个光源为其着色。 当我在桌面上运行该程序时，它工作得很好，但在 Android 设备上，球体只是纯色。

这里有图片来说明我在说什么:

-> 桌面

-> 安卓

这是着色器代码:

sphere.vert

#ifdef GL_ES
    precision mediump float;
#endif

uniform mat4 u_projectionMatrix;
uniform mat3 u_normalMatrix;
uniform mat4 u_modelViewMatrix;

const int MAX_LIGHTS = 8;
uniform int u_lights_active;
uniform vec3 u_ambient;
uniform vec3 u_position[ MAX_LIGHTS ];
uniform vec3 u_diffuse[ MAX_LIGHTS ];
uniform vec3 u_att_coeffs[ MAX_LIGHTS ];

// since builtins aren't used, we use attributes as substitute
attribute vec2 a_texCoord0;
attribute vec4 a_position;
attribute vec3 a_normal;

// outputs to fragment shader
varying vec2 v_tex_coord;
varying vec4 v_color;

void main()
{
    vec3 tempColor  = u_ambient;
    vec3 ecPosition = vec3( u_modelViewMatrix * a_position );
    vec3 viewVec    = normalize( -ecPosition );
    vec3 tnorm      = normalize( u_normalMatrix * a_normal );

    for ( int i = 0; i < u_lights_active; ++i )
    {
        float dist   = length( ecPosition - u_position[i] ); // distance from light to fragment
        float att    = 1.0 / ( u_att_coeffs[i].x + u_att_coeffs[i].y*dist + u_att_coeffs[i].z*dist*dist );

        vec3 lightVec  = normalize( u_position[i] - ecPosition );
        float diffuse  = max( dot( lightVec, tnorm ), 0.0 );
        tempColor      += att * u_diffuse[i] * diffuse;
    }

    tempColor    = clamp( tempColor, 0.0, 1.0 );
    v_color      = vec4( tempColor, 0.0 );

    gl_Position  = u_projectionMatrix * vec4( ecPosition, 1.0 );
    v_tex_coord  = a_texCoord0.xy;
}

sphere.frag

#ifdef GL_ES
    precision mediump float;
#endif

uniform sampler2D u_texture;

varying vec2 v_tex_coord;
varying vec4 v_color;

void main()
{
    vec4 texColor = texture2D( u_texture, v_tex_coord );
    gl_FragColor  = texColor * v_color;
}

我真的希望你们中的任何一个能向我解释我做错了什么。

版本号:

LibGDX:0.9.8

ADT:构建 v22.0.1-685705

Android 设备:Sony Xperia S，Android 4.1.2

项目构建目标:Android 4.3，API 18

Mainfest 包含

<uses-feature android:glEsVersion="0x00020000" android:required="true" />

着色器由以下人员创建:

shaderProgram = new ShaderProgram( Gdx.files.internal( "shaders/sphere.vert" ), Gdx.files.internal( "shaders/sphere.frag" ) );
if ( !shaderProgram.isCompiled() )
{
    Gdx.app.error( TAG, shaderProgram.getLog() );
}

球体是 StillModel:

创作:

final ModelLoaderHints hint = new ModelLoaderHints( true );
model = ModelLoaderRegistry.loadStillModel( Gdx.files.internal( "data/sphere.obj" ), hint );
texture = new Texture( Gdx.files.internal( "data/sphere_tex.png" ), Format.RGB888, false );
material = new Material( "mat", new TextureAttribute( texture, 0, "u_texture" ) );

渲染:

shaderProgram.begin();
texture.bind( 0 );

shaderProgram.setUniformMatrix( C.U_PROJECTION_MATRIX, cam.projection );
// light values
shaderProgram.setUniformi( C.U_LIGHTS_ACTIVE, lightsActive );
shaderProgram.setUniform3fv( C.U_LIGHT_AMBIENT, lightAmbient, 0, 3 );
shaderProgram.setUniform3fv( C.U_LIGHT_POSITION, lightPosition, 0, 3 * lightsActive );
shaderProgram.setUniform3fv( C.U_LIGHT_DIFFUSE, lightDiffuse, 0, 3 * lightsActive );
shaderProgram.setUniform3fv( C.U_LIGHT_ATT_COEFFS, lightAttCoeffs, 0, 3 * lightsActive );

modelMatrix.setToTranslation( positionWrap );
modelMatrix.rotate( rotationAxis, rotation );
modelMatrix.scale( scaleX, scaleY, scaleZ );

modelViewMatrix.set( cam.view ).mul( modelMatrix );
normalMatrix.set( modelViewMatrix ).inv().tra();

shaderProgram.setUniformMatrix( C.U_NORMAL_MATRIX, normalMatrix3x3.set( normalMatrix ) );
shaderProgram.setUniformMatrix( C.U_MODEL_VIEW_MATRIX, modelViewMatrix );

stillModel.render( shaderProgram );

shaderProgram.end();

希望这就是所需的全部信息。

提前致谢!

最佳答案

将我的评论转化为答案:

GLSL 规范只要求支持非常简单的循环(非常“恒定”的循环边界等)。看我的回答for-loop in shader code working with hardcoded number but not with uniform variable

在您的情况下，您可能可以通过始终循环 MAX_LIGHTS 来解决此问题，并且只需将非 Activity 灯光的影响乘以 0(或确保非 Activity 灯光设置全部为零或全部为 1.0 或其他任何设置)无效)。

请注意，由于像素着色器的运行方式(在 SIMD 并行执行中)，在循环内添加一个分支以“跳过”不必要的工作可能会更慢。尝试让所有像素始终运行相同的指令序列。

关于android - LibGDX - 着色器在桌面上工作但不在 Android 上，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/18735667/