考虑以下 XML 结构:

<a>
    <t>abc</t>
</a>
<a type="start"></a>
<b>
    <t>ignore</t>
</b>
<a></a>    
<a>
    <t>1</t>
</a>
<a>
    <t>2</t>
</a>
<a>
    <t>3</t>
</a>
<b>
    <t>ignore</t>
</b>
<a>
    <t>4</t>
</a>
<a type="end"></a>
<a>
    <t>def</t>
</a>

我需要获取属性值为 start 和 end 的 a 标签之间的所有 a 标签的内容总和。

我尝试使用以下 XSL:

<xsl:template match="a">
    <xsl:choose>
        <xsl:when test="@type='start'">
            <merged>
                <xsl:call-template name="getMergedText">
                    <xsl:with-param name="text" select="''"/>
                <xsl:call-template>
            </merged>
        </xsl:when>
        <xsl:otherwise>
            <single>
                <xsl:value-of select="t"/>
            </single>
        </xsl:otherwise>
    <xsl:choose>
</xsl:template>

<xsl:template name="getMergedText">
    <xsl:param name="text"/>

    <xsl:choose>
        <xsl:when test="following-sibling::a[1]/@type='end'">
            <xsl:value-of select="$text"/>
        </xsl:when>
        <xsl:when test="following-sibling::a[1]/t">
            <xsl:variable name="text.update">
                <xsl:value-of select="$text"/>
                <xsl:value-of select="following-sibling::a[1]/t"/>
            </xsl:variable>
            <xsl:for-each select="following-sibling::a[1]">
                <xsl:call-template name="getMergedText">
                    <xsl:with-param name="text" select="$text.update"/>
                <xsl:call-template>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <xsl:for-each select="following-sibling::a[1]">
                <xsl:call-template name="getMergedText">
                    <xsl:with-param name="text" select="$text"/>
                <xsl:call-template>
            </xsl:for-each>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

所需的输出是:

<single>abc</single>
<merged>1234</merged>
<single>def</single>

我得到的输出是:

<single>abc</single>
<merged>1234</merged>
<single>1</single>
<single>2</single>
<single>3</single>
<single>4</single>
<single>def</single>

如何避免重新处理已由 getMergedText 模板处理的 a 节点？

提前致谢!

注意:我正在使用 XSLT 1.0。 XML 中可以有多个开始-结束节点对的实例，在这些对之前、之后和之间可以有任意数量的节点。

最佳答案

这里最有效的方法可能是我听说过的被描述为“兄弟递归”的方法，使用尾递归模板来模拟“while 循环”类型的结构。顶部模板从处理 first a 元素开始，然后每个模板做的最后一件事是将适当的模板应用到 next 一个元素。

<xsl:template match="---whatever matches the parent element of the a's---">
  <xsl:apply-templates select="a[1]" />
</xsl:template>

<xsl:template match="a[@type = 'start']">
  <!-- edge case - start followed immediately by end shouldn't generate
       a "merged" element -->
  <xsl:if test="not(following-sibling::a[1][@type = 'end'])">
    <merged>
      <xsl:apply-templates mode="merge" select="following-sibling::a[1]" />
    </merged>
  </xsl:if>
  <!-- continue with the a after the "end" -->
  <xsl:apply-templates select="
      following-sibling::a[@type = 'end'][1]/following-sibling::a[1]" />
</xsl:template>

<xsl:template match="a">
  <single><xsl:value-of select="t"/></single>
  <xsl:apply-templates select="following-sibling::a[1]" />
</xsl:template>

<!-- stop the merge when we get the the "end" -->
<xsl:template match="a[@type = 'end']" mode="merge" />

<xsl:template match="a" mode="merge">
  <xsl:value-of select="t" />
  <xsl:apply-templates select="following-sibling::a[1]" mode="merge" />
</xsl:template>

注意 following-sibling::a[1][@type = 'end'] 之间的区别(检查紧随其后的 a 元素是否具有type="end") 和 following-sibling::a[@type = 'end'][1](找到最近的 a 确实有 type="end").

关于xml - XSLT:处理所有后续兄弟直到满足特定条件而无需重新处理已处理的节点，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/21953047/