我正在运行一个应用程序，它构建 ICMP ECHO 请求并将其发送到几个不同的 IP 地址。该应用程序是用 Crystal 编写的。尝试从 crystal docker 容器中打开套接字时，Crystal 引发异常:权限被拒绝。

在容器中，运行 ping 8.8.8.8 没有问题。

在 macOS 上运行应用程序，我没有问题。

阅读https://docs.docker.com/engine/security/apparmor/和 https://docs.docker.com/engine/security/seccomp/ apparmor 和 seccomp 上的页面 我确信我找到了解决方案，但问题仍然没有解决，即使以 docker run --rm --security-opt seccomp=unconfined --security-opt apparmor=unconfined socket_permission 运行时也是如此

更新/编辑:深入了解capabilities(7)后，我将以下行添加到我的dockerfile:RUN setcap cap_net_raw+ep bin/ping 试图让套接字打开但没有改变。

谢谢!

相关的 Crystal socket 代码，完整的工作代码示例如下:

  # send request
  address = Socket::IPAddress.new host, 0
  socket = IPSocket.new Socket::Family::INET, Socket::Type::DGRAM, Socket::Protocol::ICMP
  socket.send slice, to: address

docker 文件:

FROM crystallang/crystal:0.23.1
WORKDIR /opt
COPY src/ping.cr src/
RUN mkdir bin

RUN crystal -v
RUN crystal build -o bin/ping src/ping.cr

ENTRYPOINT ["/bin/sh","-c"]
CMD ["/opt/bin/ping"]

运行代码，首先是原生的，然后是通过 docker:

#!/bin/bash
crystal run src/ping.cr
docker build -t socket_permission .
docker run --rm --security-opt seccomp=unconfined --security-opt apparmor=unconfined socket_permission

最后，一个无法在 docker 中打开套接字的 50 行 crystal 脚本:

require "socket"

TYPE = 8_u16
IP_HEADER_SIZE_8 = 20
PACKET_LENGTH_8 = 16
PACKET_LENGTH_16 = 8
MESSAGE = " ICMP"

def ping
  sequence = 0_u16
  sender_id = 0_u16
  host = "8.8.8.8"

  # initialize packet with MESSAGE
  packet = Array(UInt16).new PACKET_LENGTH_16 do |i|
    MESSAGE[ i % MESSAGE.size ].ord.to_u16
  end

  # build out ICMP header
  packet[0] = (TYPE.to_u16 << 8)
  packet[1] = 0_u16
  packet[2] = sender_id
  packet[3] = sequence

  # calculate checksum
  checksum = 0_u32
  packet.each do |byte|
    checksum += byte
  end
  checksum += checksum >> 16
  checksum = checksum ^ 0xffff_ffff_u32
  packet[1] = checksum.to_u16

  # convert packet to 8 bit words
  slice = Bytes.new(PACKET_LENGTH_8)

  eight_bit_packet = packet.map do |word|
    [(word >> 8), (word & 0xff)]
  end.flatten.map(&.to_u8)

  eight_bit_packet.each_with_index do |chr, i|
    slice[i] = chr
  end

  # send request
  address = Socket::IPAddress.new host, 0
  socket = IPSocket.new Socket::Family::INET, Socket::Type::DGRAM, Socket::Protocol::ICMP
  socket.send slice, to: address

  # receive response
  buffer = Bytes.new(PACKET_LENGTH_8 + IP_HEADER_SIZE_8)
  count, address = socket.receive buffer
  length = buffer.size
  icmp_data = buffer[IP_HEADER_SIZE_8, length-IP_HEADER_SIZE_8]
end

ping

最佳答案

事实证明，Linux(以及 docker 的扩展名)并未提供与 macOS 对 DGRAM 套接字相同的权限。将套接字声明更改为 socket = IPSocket.new Socket::Family::INET, Socket::Type::RAW, Socket::Protocol::ICMP 允许套接字在 docker 下连接。

在非 root 上下文中运行该程序还需要一点。因为原始套接字仅限于 root，二进制文件也必须发布正确的 capability用于访问原始套接字，CAP_NET_RAW。但是，在 docker 中，这不是必需的。通过运行 sudo setcap cap_net_raw+ep bin/ping，我能够让程序在 super 用户上下文之外运行。 This is a decent primer on capabilities and the setpcap command

MacOS 不使用相同的权限系统，因此 setcap 只是一个无法识别的命令。因此，为了让上述代码在没有 super 用户上下文的情况下在 macOS 上成功编译和运行，我将套接字创建代码更改为:

socket_type = Socket::Type::RAW

{% if flag?(:darwin) %}
  socket_type = Socket::Type::DGRAM
{% end %}

socket = IPSocket.new Socket::Family::INET, socket_type, Socket::Protocol::ICMP

如果需要，在构建过程的其他地方应用 CAP_NET_RAW 功能以在 linux 中使用。

通过这些更改，我没有看到任何需要更改 seccomp 或 apparmor 以运行该程序的默认 Docker 附带的。

关于sockets - 从 docker 容器中打开 DGRAM 套接字失败(权限被拒绝)，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/47370366/