我有一个复合视觉控件，它由编辑框和一个下拉按钮组成。下拉按钮不是窗口控件，而是绘制在编辑框上。我通过以下调用限制编辑的宽度:

SendMessage(Handle, EM_SETMARGINS, EC_RIGHTMARGIN, 
  (DropDownButtonWidth + 2) shl 16);

它在 Windows XP 下工作正常但在 Windows 7 下不起作用。在后一种情况下，当焦点编辑框与下拉按钮重叠并删除其图像时。

在两种操作系统下限制编辑框矩形的正确方法是什么？

PS:我也试过另一种方法:

  SendMessage(Handle, EM_GETRECT, 0, LongInt(@Loc));
  Loc.Bottom := ClientHeight + 1;  
  Loc.Right := ClientWidth - FButton.Width - 2;
  Loc.Top := 0;
  Loc.Left := 0;
  SendMessage(Handle, EM_SETRECTNP, 0, LongInt(@Loc));

但它也不适用于 Windows 7。

最佳答案

您设置边距的第一个代码是正确的。

然而，由于 VCL 的工作方式，事情变得棘手，为给定 VCL 控件创建的底层窗口可能会重新创建以响应运行时对 VCL 属性所做的更改(某些属性更改只能应用于 Windows API 级别通过销毁和重新创建窗口)。尽管消息的顺序(通常)在不同的 Windows 版本中没有改变，但可以引入其他消息，其中一些消息可能会改变环绕这些窗口的 VCL 代码可能触发的顺序，或干扰该代码的行为.

也有可能在底层 Windows API 窗口中引入了 VCL 不满足的行为(同样，最有可能在混合低级 API 调用时发生，如本例)。

将 VCL 行为与较低级别的直接 API 调用混合时尤其如此 - 如本例所示。

还有其他一些东西会在应用后干扰某些设置，这需要您自己销毁并重新创建窗口并重新应用您自己的设置。

我已经看到其他关于在不同版本的 XP 上使用相同代码(不是 Delphi)的问题的报告 - 似乎在 SP2 中引入的更改对该区域产生了一些影响。

在 EM_SETMARGINS 的情况下，我遇到了与您相同的问题，并通过查看 TButtonEdit 控件如何应用它所需的边距来解决它(这是有效的至少在我的 Windows 7 安装上)。

由于我正在实现自己的自定义控件，而不是尝试将边距应用到某些现有的编辑控件，所以事情对我来说可能变得更容易了。在下面的代码片段中，TCustomPickEdit 是我的自定义控件类，它包含一个 fButton 对象，该对象包含与选择器按钮相关的所有设置。您将需要进行适当的调整以在您的特定情况下应用此代码。

我发现的是:

1. 至少需要在 3 个地方应用边距。首先，每当可能影响边距的设置发生更改时，其次是当创建编辑控件窗口句柄时，最后是当编辑控件上的字体发生更改时:

2. 即使边距设置正确，也需要调整控件的剪辑矩形以确保正确绘制。这需要重写编辑控件的 WndProc 并拦截几条消息。此 WndProc 还需要响应字体更改通知，以便在编辑控件字体发生更改时重新应用边距。

在我的案例中，处理这些问题的代码如下所示:

  procedure TCustomPickEdit.ConfigureButton;
  // 1. Apply margins when button settings are changed 
  begin
    fButton.Caption   := Button.Caption;
    fButton.Flat      := Button.Flat;
    fButton.Glyph     := Button.Glyph;
    fButton.NumGlyphs := Button.NumGlyphs;
    fButton.Visible   := Button.Visible;
    ApplyMargins;
  end;

  procedure TCustomPickEdit.CreateHandle;
  // 2. Apply margins when underlying window handle is created 
  begin
    inherited;
    ApplyMargins;
  end;

  procedure TCustomPickEdit.WndProc(var aMessage: TMessage);
  // 3. Adjust clipping rectangle for correct drawing
  // 4. Apply margins when font is changed
  var
    top: Integer;
  begin
    case aMessage.Msg of
      CN_CTLCOLORSTATIC,
      CN_CTLCOLOREDIT    : if Button.Visible then
                           begin
                             top := fButton.Top;
                             if ThemeServices.ThemesEnabled and Ctl3D then
                               Inc(top);

                             ExcludeClipRect(aMessage.WParam, fButton.Left,
                                                              top + 1,
                                                              fButton.Left + fButton.Width,
                                                              fButton.Height);
                           end;
    end;

    inherited;

    case aMessage.Msg of
      CM_FONTCHANGED : if NOT (csLoading in ComponentState) then
                         ApplyMargins;
    end;
  end;

关于windows - 为什么 EM_SETMARGINS 在 Windows 7 下不起作用？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/4217761/