我正在使用 ADO 向 MySQL 表中添加一条记录。代码工作正常，数据被发布到新记录，除了 userid。我不明白为什么。

'---------------------------------------------------------------------------------------
' Procedure : IPhpList_AddHistory
' Author    : Adam
' Date      : 12/8/2014
' Purpose   : Add a history record to the phpList account.
'---------------------------------------------------------------------------------------
'
Private Sub IPhpList_AddHistory(cUser As clsUser, cHistory As clsHistory)

    Dim strSQL As String
    Dim rst As ADODB.Recordset

    Set rst = New ADODB.Recordset
    strSQL = "phplist_user_user_history limit 0,1"
    rst.Open strSQL, oConn, adOpenDynamic, adLockOptimistic

    With rst
        .AddNew
            !userid = cUser.PhpListID
            !ip = ""
            ![Date] = cHistory.AddDate
            !Summary = cHistory.Subject
            !Detail = cHistory.Body
            !systeminfo = "Automated syncronization process. " & VBE.ActiveVBProject.Description
        .Update
        .Close
    End With

    ' Clear reference
    Set rst = Nothing

End Sub

看起来很简单，但是在 MySQL 中生成的记录缺少 userid 值。

列上有一个索引，但这似乎不应该阻止我设置值。 (不，这张表上没有触发器。)

当我单步执行代码时，我可以看到该字段的值已设置，并且在更新记录时没有错误，但不知何故在添加记录时它只是恢复为零。

我意识到我可以使用 .Execute(strSQL) 添加记录，但我想了解为什么 ADO 代码难以为此列设置值。

更有趣的是，当我返回并尝试更新现有记录的 userid 列时，我得到了类似的结果。我设置了该值，它恢复为零(或之前的任何值)。

更新

现在这变得非常令人费解...我向表中添加了具有相同数据类型、长度等的另一列...突然间代码按预期运行。我可以编辑新列<​​strong>和/或 userid 列中的值。 (并独立编辑值)

但是当我删除测试列时，它又回到了以前的行为，即不允许我更改 userid 中的值。 (为什么会这样？？)

更进一步，我在本地 MySQL 实例上创建了表，这样我就可以在 ADO 查询 Access 数据库时分析它们。这揭示了一些非常有趣的行为。以下两个语句由相同的 ADO 代码生成，但第二个语句将测试列添加到表中。

INSERT INTO `test`.`phplist_user_user_history`(`id`,`userid`,`ip`,`date`,`summary`,`detail`,`systeminfo`) 
VALUES (DEFAULT,DEFAULT,'',_binary'2014-12-18 11:51:13','My Subject','New Details','IBLP automated syncronization process. Version 1.0')

INSERT INTO `test`.`phplist_user_user_history`(`id`,`userid`,`ip`,`date`,`summary`,`detail`,`systeminfo`,`testcol`) 
VALUES (DEFAULT,456,'',_binary'2014-12-18 13:22:44','My Subject','New Details','IBLP automated syncronization process. Version 1.0',1)

请注意第一个插入语句如何输入 DEFAULT 而不是我通过 ADO 传递的值。

第二个调用代码是相同的，只是它在 testcol 中设置了一个值。当有两个 INT(11) 列而不是一个时，为什么运行会有所不同？

进一步的线索是，当我针对我的测试数据库中的表运行代码时，我在 VBA 中收到以下错误(即使我明确设置了 userid 值):

添加测试列后，测试列上会弹出错误。在测试列上显式设置值后，.Update 成功，两个字段都正确更新。

这可能是 ODBC 驱动程序中的错误吗？我正在使用最新的 MySQL ODBC 连接器驱动程序 (5.3.4) 和以下连接字符串:

"Driver=MySQL ODBC 5.3 Unicode Driver;SERVER=myserver;UID=myuser;PWD={mysecretpwd};DATABASE=test;PORT=3306;DFLT_BIGINT_BIND_STR=1"

最佳答案

我能够使用 64 位版本的 MySQL ODBC 5.3 Unicode 驱动程序 (5.03.04.00) 重现您的问题。当表中的最后一列的类型为 TEXT 时，这似乎是 ADO Recordset 更新的问题。我什至没有关于 userid 的索引，但我得到了相同的结果。

一种可能的解决方法是使用带有参数的 ADODB.Command 来执行插入，使用类似于以下的代码:

Dim oConn As ADODB.Connection
Dim cmd As ADODB.Command

Set oConn = New ADODB.Connection
oConn.Open _
        "Driver=MySQL ODBC 5.3 Unicode Driver;" & _
        "SERVER=localhost;" & _
        "UID=root;" & _
        "PWD=whatever;" & _
        "DATABASE=mydb;" & _
        "PORT=3306;" & _
        "DFLT_BIGINT_BIND_STR=1"

Set cmd = New ADODB.Command
cmd.ActiveConnection = oConn
cmd.CommandText = _
        "INSERT INTO phplist_user_user_history " & _
        "(`userid`, `ip`, `date`, `Summary`, `Detail`, `systeminfo`) " & _
        "VALUES (?,?,?,?,?,?)"
cmd.Parameters.Append cmd.CreateParameter("?", adInteger, adParamInput, , 456)
cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, "")
cmd.Parameters.Append cmd.CreateParameter("?", adDBTimeStamp, adParamInput, 255, Now)
cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, "cHistory.Subject")
cmd.Parameters.Append cmd.CreateParameter("?", adLongVarWChar, adParamInput, 2147483647, "cHistory.Body")
cmd.Parameters.Append cmd.CreateParameter("?", adLongVarWChar, adParamInput, 2147483647, "Automated syncronization process.")
cmd.Execute

Set cmd = Nothing
oConn.Close
Set oConn = Nothing

我从 Access 2010 数据库对其进行了测试，它对我来说运行良好。

关于mysql - 通过 ADO 创建/编辑记录时索引 MySQL 字段不保存值，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/27492235/