好吧，即使我一直在努力使用该网站，也要发布我的第一个问题。在过去的两天里，我一直在尝试为此找到解决方案，但没有成功。使用本网站上类似问题的一些答案(this、this、this、this 以及许多许多其他问题)我已经取得了一些进展，但完整(且正确!)解决方案仍然逃避我。

我有一个现有的 XML (file1.xml)，我必须根据我正在生成的另一个 XML (file2.xml) 进行更新: 的内容>file2 必须包含在 file1 中，以遵守我稍后将说明的一些规则(文件内容已被过度简化以仅显示相关元素):

file1.xml

<?xml version="1.0" encoding="UTF-8"?>
<list>
    <decade lastyear="2012" firstyear="2011">
        <year value="2012">
            <issue year="2012"  number="242" />
            <issue year="2012"  number="241" />
            <issue year="2012"  number="240" />
        </year>
        <year value="2011">
            <issue year="2011"  number="238" />
            <issue year="2011"  number="237" />
            <issue year="2011"  number="236" />
            <issue year="2011"  number="235" />
        </year>
    </decade>
    <decade lastyear="2010" firstyear="2001">
        <year value="2010">
            <issue year="2010"  number="234" />
            <issue year="2010"  number="233" />
            <issue year="2010"  number="232" />
            <issue year="2010"  number="231" />
            <issue year="2010"  number="230" />
        </year>
        <year value="2009">
            <issue year="2009"  number="229" />
            <issue year="2009"  number="228" />
            <issue year="2009"  number="227" />
            <issue year="2009"  number="226" />
            <issue year="2009"  number="225" />
        </year>
           ...
    </decade>
 </list>

file2.xml

<?xml version="1.0" encoding="UTF-8"?>
<issue year="2013" number="245" />
...

如前所述，file2 的内容必须插入 file1 并遵守一些规则:

• 如果 file1 上不存在问题的年份(即，如果插入当年的第一期)，则必须创建它(已经完成)
• 新期必须插入相应年份下(已完成)
• decade 必须更新以反射(reflect)最后插入的年份(这个年份有问题!)
• issue 元素必须按年份和数字降序排列
• 如果问题的年份属于新的十年，则必须与相应的子年份和问题一起创建这一年
• 在生成的文档中，所有元素必须按降序排列:decade(去年)、year(值)和 issue(年份和编号)

我使用的是 Saxon-HE 9.4.0.6，到目前为止我完成的 xsl 是这个:

XSL

<?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output method="xml" omit-xml-declaration="yes" indent="no" encoding="UTF-8"/>

    <xsl:variable name="up" select="document('../test/ExcelStory/file2.xml')"/>
    <xsl:variable name="year" select="$up/issue/@year" />

    <xsl:template match="@* | node()" >
       <xsl:copy>
           <xsl:apply-templates select="@*|node()">
               <xsl:sort select="//issue/@year" />
            </xsl:apply-templates>
       </xsl:copy>
    </xsl:template>

    <xsl:template match="decade" >
        <xsl:copy>
            <xsl:apply-templates select="* | @*"/>
            <xsl:choose>
                <xsl:when test="year[1]/@value lt $year">
                    <year value="{$year}"/>
                </xsl:when>
            </xsl:choose>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="year[@value=$year]">
        <xsl:copy>
            <xsl:apply-templates select="* | @*"/>
            <xsl:apply-templates select="$up/*" />
        </xsl:copy>
    </xsl:template>    
</xsl:stylesheet>

此样式表假定 file1.xml 上的内容在阅读时已经排序(情况就是如此)。

我想知道我是否必须使用“模式”进行多次传递以首先根据年份创建十年(如有必要)，然后将年份插入正确的十年(在第二遍？？)，之后在正确的年份插入问题(第三遍？？)并最终重新排序所有元素(甚至是另一遍？？)或者是否可以更有效地进行所有必需的处理(一次或两次遍)。 Michael Key 先生在其他地方建议使用 xsl:for-each 进行这种处理，但我不知道在这种情况下它是否更适合(更容易？)。

即使这个问题看起来与 stackoverflow 上的其他一些问题相似，我认为还是有一些额外的复杂性使其值得一读(并且可能正在回答，我希望!)。

如果您能提供一些关于如何进行的想法，或者您能为我指出其他资源，我将不胜感激。

最佳答案

我要做的不是尝试添加新的 issue，而是合并两个文件中的所有 issue，然后重新创建结构。

这可能不适用于您的实际用例，因为您说:

(content of files has been oversimplified to show only relevant elements)

但希望它能为您提供另一个视角和/或起点。

您可能想要添加身份转换并将 xsl:copy-of 和 xsl:perform-sort 替换为 xsl:apply-templates。您还需要更新 xsl:param 以指向外部文件。

XML 输入(略微修改以添加更多年份并更改编号以进行测试)

<list>
    <decade lastyear="2012" firstyear="2011">
        <year value="2012">
            <issue year="2012"  number="242" />
            <issue year="2012"  number="241" />
            <issue year="2012"  number="240" />
        </year>
        <year value="2011">
            <issue year="2011"  number="238" />
            <issue year="2011"  number="237" />
            <issue year="2011"  number="236" />
            <issue year="2011"  number="235" />
        </year>
    </decade>
    <decade lastyear="2010" firstyear="2001">
        <year value="2010">
            <issue year="2010"  number="234" />
            <issue year="2010"  number="232" />
            <issue year="2010"  number="233" />
            <issue year="2010"  number="231" />
            <issue year="2010"  number="230" />
        </year>
        <year value="2009">
            <issue year="2009"  number="229" />
            <issue year="2009"  number="228" />
            <issue year="2009"  number="227" />
            <issue year="2009"  number="226" />
            <issue year="2009"  number="225" />
        </year>
        <year value="2001">
            <issue year="2001"  number="123" />
        </year>
    </decade>
</list>

XSLT 2.0

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <!--This can be changed to point to an external XML file.-->
    <xsl:param name="up">
        <issue year="2013" number="245" />
        <issue year="2002" number="135" />
        <issue year="2011" number="239" />
    </xsl:param>

    <xsl:template match="/*">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:for-each-group select="($up/issue|*/*/issue)" group-by="floor((number(@year) - 1) div 10)">
                <xsl:sort select="@year" data-type="number" order="descending"/>
                <decade lastyear="{max(current-group()/@year)}" firstyear="{min(current-group()/@year)}">
                    <xsl:for-each-group select="current-group()" group-by="@year">
                        <xsl:sort select="current-grouping-key()" data-type="number" order="descending"/>                   
                        <year value="{current-grouping-key()}">
                            <xsl:perform-sort select="current-group()">
                                <xsl:sort select="@number" data-type="number" order="descending"/>
                            </xsl:perform-sort>
                        </year>
                    </xsl:for-each-group>
                </decade>
            </xsl:for-each-group>           
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

XML 输出

<list>
   <decade lastyear="2013" firstyear="2011">
      <year value="2013">
         <issue year="2013" number="245"/>
      </year>
      <year value="2012">
         <issue year="2012" number="242"/>
         <issue year="2012" number="241"/>
         <issue year="2012" number="240"/>
      </year>
      <year value="2011">
         <issue year="2011" number="239"/>
         <issue year="2011" number="238"/>
         <issue year="2011" number="237"/>
         <issue year="2011" number="236"/>
         <issue year="2011" number="235"/>
      </year>
   </decade>
   <decade lastyear="2010" firstyear="2001">
      <year value="2010">
         <issue year="2010" number="234"/>
         <issue year="2010" number="233"/>
         <issue year="2010" number="232"/>
         <issue year="2010" number="231"/>
         <issue year="2010" number="230"/>
      </year>
      <year value="2009">
         <issue year="2009" number="229"/>
         <issue year="2009" number="228"/>
         <issue year="2009" number="227"/>
         <issue year="2009" number="226"/>
         <issue year="2009" number="225"/>
      </year>
      <year value="2002">
         <issue year="2002" number="135"/>
      </year>
      <year value="2001">
         <issue year="2001" number="123"/>
      </year>
   </decade>
</list>

关于xml - 将节点插入另一个 XML，创建新元素(或更新现有元素)并重新排序生成的文档，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/21487217/