问题摘要：
我可以在安全模式下从Windows批处理脚本启动Excel文件installer.xlsm，而不提供Excel.exe安装路径吗？
细节
我有一个windows批处理脚本，它可以从远程服务器下载一系列excel加载项的最新版本，将它们放在一个目录（c:\appname\add ins）中，并调用excel文件installer.xlsm。
加载时，installer.xlsm执行VBA宏，该宏卸载旧版本的加载项并安装其新版本。
当前，我使用以下命令启动installer.xlsm：

start "Launching installer file" /wait "<Path to file>\Installer.xlsm"

start "Launching installer file" /wait "<Path to file>\Installer.xlsm /safemode"

最佳答案

首先，我建议阅读Microsoft TechNet关于Application Registration的文章。它解释了应用程序或应用程序套件（如Microsoft Office）的安装程序应如何注册已安装的应用程序，以便其他应用程序可以找到应用程序的可执行文件。
建议在注册表项下创建

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths

@echo off
for /F "skip=1 tokens=2*" %%A in ('%SystemRoot%\System32\reg.exe QUERY "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\excel.exe" /ve 2^>nul') do set "ExcelApp=%%~B"
echo ExcelApp=%ExcelApp%
pause

@echo off
for /F "skip=3 tokens=3*" %%A in ('%SystemRoot%\System32\reg.exe QUERY "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\excel.exe" /ve 2^>nul') do set "ExcelApp=%%~B"
echo ExcelApp=%ExcelApp%
pause

start "Launching installer file" "C:\Path to file\Installer.xlsm"

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem First query default string value of HKEY_CLASSES_ROOT\.xlsm from registry.
call :GetDefaultRegValue "HKCR\.xlsm"

rem Is there no key HKEY_CLASSES_ROOT\.xlsm or was the default string empty?
if not defined RegValue goto GetFromAppPaths

SET RegValue
rem Get the shell command line used for opening a *.xlsm file.
call :GetDefaultRegValue "HKCR\%RegValue%\shell\open\command"

rem Could the command line not read successfully from Windows registry?
if not defined RegValue goto GetFromAppPaths

SET RegValue
rem The command line contains as first string usually enclosed in double
rem quotes EXCEL.EXE with full path enclosed in double quotes. And there
rem can be even more arguments on the command line which are not needed
rem here. The command line below is used to get just first string of
rem the command line which should be EXCEL.EXE with full path.
for %%I in (%RegValue%) do set "RegValue=%%~I" & goto CheckExcelExistence

rem It is not good when both registry queries above fail. This means
rem either Microsoft Excel is not installed at all or a version of
rem Excel is installed which does not support *.xlsm files like Excel
rem of MS Office 2003, MS Office 2000 or MS Office 97.

rem However, perhaps just *.xlsm is not correct registered and therefore
rem get full path to excel.exe from application registration key.

:GetFromAppPaths
call :GetDefaultRegValue "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\excel.exe"
if defined RegValue goto CheckExcelExistence

echo Failed to determine installation location of Microsoft Excel.
echo/
endlocal
pause
goto :EOF

:CheckExcelExistence
SET RegValue
rem Remove surrounding double quotes if the Excel executable file name
rem read from Windows registry is still enclosed in double quotes.
set "RegValue=%RegValue:"=%"
if exist "%RegValue%" goto :RunInstall

echo Registered "%RegValue%" does not exist.
echo/
endlocal
pause
goto :EOF

:RunInstall
SET RegValue
ECHO start "Launching installer file" /wait "%RegValue%" "%~dp0Installer.xlsm" /safemode
endlocal
goto :EOF


rem This subroutine queries from Windows registry the default string value of
rem the key passed to the subroutine as first and only parameter and assigns
rem this value to environment variable RegValue. Environment variable RegValue
rem is deleted and therefore is not defined after subroutine exits on failure
rem to get the registry value or when the default value is an empty string.
rem This subroutine works for Windows XP and all later versions of Windows.

:GetDefaultRegValue
set "TypeToken=2"

:Reg3Run
for /F "skip=1 tokens=%TypeToken%*" %%A in ('%SystemRoot%\System32\reg.exe QUERY "%~1" /ve 2^>nul') do (
    if "%%A" == "REG_SZ" (
        if not "%%~B" == "" (
            set "RegValue=%%B"
            goto :EOF
        )
    ) else if "%%A" == "NAME>" (
        set "TypeToken=3"
        goto Reg3Run
    )
)
set "RegValue="
goto :EOF

关于excel - 从Windows批处理脚本以安全模式启动Excel文件，使用默认文件关联，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/45509710/