我写了一个批处理文件，我在其中放入了一堆设置为某个变量的文本，然后下一行将该变量回显到一个文本文件中。

问题是它将所有内容回显到一长行中并且无法阅读(它会强制您切换换行模式，但如果软件不支持它怎么办)。

echo "Lorem ipsum dolor sit amet, consectetur adipiscing elit. Phasellus at elit eu felis gravida pretium. Morbi suscipit eu metus quis facilisis. Sed aliquet eget sem ac semper. Fusce tempor magna dui, nec ullamcorper nulla rutrum eget. Suspendisse mattis lorem ut nulla placerat vestibulum. Vivamus sollicitudin nisl in lorem suscipit luctus. Nam a nisi vestibulum, lacinia nulla faucibus, condimentum eros. Donec fringilla neque et massa sagittis sollicitudin. Pellentesque vestibulum, metus maximus lacinia varius, nisi tortor facilisis ante, et porttitor magna urna sed odio. Maecenas ut mi sed ipsum pretium mattis et a urna. Nunc vulputate ornare bibendum. Pellentesque libero lacus, porttitor ut sem vitae, lobortis dictum erat. Sed viverra euismod nisl, nec malesuada turpis pellentesque eget." > text_file.txt

(只看这个例子，不可读)

所以我需要把它打印成类似这样的东西:

"Lorem ipsum dolor sit amet, consectetur adipiscing elit. Phasellus at elit
 eu felis gravida pretium. Morbi suscipit eu metus quis facilisis. Sed 
aliquet eget sem ac semper. Fusce tempor magna dui, nec ullamcorper nulla 
rutrum eget. Suspendisse mattis lorem ut nulla placerat vestibulum. Vivamus 
sollicitudin nisl in lorem suscipit luctus. Nam a nisi vestibulum, lacinia 
nulla faucibus, condimentum eros. Donec fringilla neque et massa sagittis 
sollicitudin. Pellentesque vestibulum, metus maximus lacinia varius, nisi 
tortor facilisis ante, et porttitor magna urna sed odio. Maecenas ut mi sed 
ipsum pretium mattis et a urna. Nunc vulputate ornare bibendum. Pellentesque 
libero lacus, porttitor ut sem vitae, lobortis dictum erat. Sed viverra 
euismod nisl, nec malesuada turpis pellentesque eget." 

如您所见，最长的一行是76 个字符。是否可以将其用作断点或其他东西？

但这也意味着它不能在单词中间切掉它。

更新:我在 Linux 上发现了相同的问题和答案 https://unix.stackexchange.com/questions/60219/is-there-a-command-line-tool-to-insert-line-breaks-into-a-long-string该命令称为 fold。 Windows 的任何替代方案？

最佳答案

巧合的是，大约4年前，我刚开始学习批处理时写过这样的东西。它几乎肯定不接受 &s 或 )s，但你的示例文本中没有任何内容，我也不太关心测试它们。

将字符串作为单个参数传入。

@echo off
setlocal enabledelayedexpansion

cls
set unformattedText=Lorem ipsum dolor sit amet, consectetur adipiscing elit. Phasellus at elit eu felis gravida pretium. Morbi suscipit eu metus quis facilisis. Sed aliquet eget sem ac semper. Fusce tempor magna dui, nec ullamcorper nulla rutrum eget. Suspendisse mattis lorem ut nulla placerat vestibulum. Vivamus sollicitudin nisl in lorem suscipit luctus. Nam a nisi vestibulum, lacinia nulla faucibus, condimentum eros. Donec fringilla neque et massa sagittis sollicitudin. Pellentesque vestibulum, metus maximus lacinia varius, nisi tortor facilisis ante, et porttitor magna urna sed odio. Maecenas ut mi sed ipsum pretium mattis et a urna. Nunc vulputate ornare bibendum. Pellentesque libero lacus, porttitor ut sem vitae, lobortis dictum erat. Sed viverra euismod nisl, nec malesuada turpis pellentesque eget.
set width=76
set counter=0
set slashN=^


if not [%1]==[] set unformattedText=%~1

:wordCounter
for /f "tokens=1,* delims= " %%A in ("%unformattedText%") do (
    if not "%%A"=="" (
        set words[!counter!]=%%A
        set /a counter=!counter!+1
        set unformattedText=%%B
        goto wordCounter
    ) else (
        goto loopBreak
    )
)

:loopBreak
echo There are !counter! words in your sentence.

set /a counter=!counter!-1
for /l %%A in (0,1,!counter!) do (
    echo !words[%%A]!>tmp.txt
    for %%J in (tmp.txt) do (
        set /a len[%%A]=%%~zJ
        set /a len[%%A]-=2
        del tmp.txt
        if !len[%%A]! gtr %width% set /a width=!len[%%A]!+1
    )
)

:: -- Concatenate the words and spaces --
set newString=
set stringLength=0
for /l %%A in (0,1,!counter!) do (
    if %%A lss !counter! (
        set /a possLength=!stringLength!+!len[%%A]!+1

        if !possLength! leq %width% (
            set newString=!newString!!words[%%A]! 
            set /a stringLength+=!len[%%A]!+1
        ) else (
            set newString=!newString!!slashN!!words[%%A]! 
            set /a stringLength=!len[%%A]!+1
        )
    ) else (
        set /a possLength=!stringLength!+!len[%%A]!

        if !possLength! leq %width% (
            set newString=!newString!!words[%%A]!
            set /a stringLength+=!len[%%A]!
        ) else (
            set newString=!newString!!slashN!!words[%%A]!
            set /a stringLength=!len[%%A]!
        )
    )
)

echo !newString!

关于窗口/命令 |如果例如，如何断线字符数达到？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/43310631/