以下批处理文件没有正确地将变量 %%a、%%b、%%c 正确传递给子例程。

@echo off
enter code here`setlocal EnableDelayedExpansion

FOR /F "tokens=1,2,3 delims= " %%a in (ftp_config.txt) do (
  echo %%a
  echo %%b
  echo %%c
  call :SUB_ftp_cmd %%a %%b %%c
  )
exit

:SUB_ftp_cmd
echo open %1>ftp.txt
echo %2>>ftp.txt
echo %3>>ftp.txt
echo cd /public_html>>ftp.txt
echo bin>>ftp.txt
echo hash>>ftp.txt
echo put "test.txt">>ftp.txt
echo close>>ftp.txt
echo bye>>ftp.txt

c:\windows\system32\ftp.exe -i <ftp.txt

del ftp.txt

exit /b

ftp.config 包含以下内容:

domain_name1 username1 password1
domain_name2 username2 password2

ftp.txt 的内容最终是:

open 
ECHO is off.
ECHO is off.
cd /public_html
bin
hash
put "test.txt"
close
bye

我在调试中放入了几行，发现 %%a、%%b、%%c 在 FOR 循环中被正确分配，但没有正确传递给 SUB_ftp_cmd。

将批处理文件更新为:

@echo off
setlocal DisableDelayedExpansion
FOR /F "tokens=1,2,* delims=      " %%a in (ftp_config.txt) do (
  echo(=== for loop variables: a=[%%a], b=[%%b], c=[%%c]
    set "passw=%%c"
    call :SUB_ftp_cmd %%a %%b
  )
exit /B

:SUB_ftp_cmd
SETLOCAL EnableDelayedExpansion
>ftp.txt (
echo open %1
echo(%2
echo(!passw!
echo cd /public_html
echo bin
echo hash
echo put "test.txt"
echo close
echo bye
)
ENDLOCAL
echo(=== ftp.txt content
type ftp.txt
echo(=== ftp command is merely displayed using `ECHO`
ECHO c:\windows\system32\ftp.exe -i -s:ftp.txt
echo(
rem del ftp.txt
exit /b

ftp_config.txt 有:

"ftp.domain1.com" username1 pas3&^#%$
"ftp.domain2.com" username2 passworks

生成的 ftp.txt:

open "ftp.domain2.com"
username2

cd /public_html
bin
hash
put "test.txt"
close
bye

感谢任何帮助。

最佳答案

如果 ftp_config.txt 中有一行看似空，我可以重现非常相似的结果文件甚至认为它包含(一个或多个)<tab> (字符制表)。
反驳"tokens=1,2,3 delims= "子句:

• 如果指定 "delims=<space>" ( Unicode 代码点 U+0020 ) 然后 for /F <tab> 的标记化将失败(代码点 U+0009)，反之亦然。
• If you don’t specify delims it will default to "delims=<tab><space>" .
• 因此，您可以指定 "tokens=1,2,*"省略 delims根本。
• 不幸的是，还有一个额外的不可见类似空格的字符  (No-Break Space，代码点 U+00A0)不是有效的分隔符。

结论:使用"delims=<tab><No-Break Space><space>" ;在键盘输入方面(我不知道如何在此处显示更好的方法):“delims=TabAlt+0160Space ".

即使密码包含 cmd poisonous characters or valid delimiters，下一个脚本也应该有效喜欢% , & , | , < , > , ! , , , ; , =等(假设计算机名和用户名不包含这些)，请参阅下面的输出:

@echo off
setlocal DisableDelayedExpansion
rem FOR /F "tokens=1,2,*" %%a in (ftp_config.txt) do (
rem in next line     delims=<tab><No-Break Space><space>" %%a …
FOR /F "tokens=1,2,* delims=      " %%a in (ftp_config.txt) do (
  echo(=== for loop variables: a=[%%a], b=[%%b], c=[%%c]
    set "passw=%%c"
    call :SUB_ftp_cmd %%a %%b
  )
exit /B

:SUB_ftp_cmd
SETLOCAL EnableDelayedExpansion
>ftp.txt (
echo open %1
echo(%2
echo(!passw!
echo cd /public_html
echo bin
echo hash
echo put "test.txt"
echo close
echo bye
)
ENDLOCAL
echo(=== ftp.txt content
type ftp.txt
echo(=== ftp command is merely displayed using `ECHO`
ECHO c:\windows\system32\ftp.exe -i -s:ftp.txt
echo(
del ftp.txt
exit /b

输出:

==> D:\bat\SO\37648941.bat
=== for loop variables: a=[domain_name1], b=[username1], c=[pass&,!%word1]
=== ftp.txt content
open domain_name1
username1
pass&,!%word1
cd /public_html
bin
hash
put "test.txt"
close
bye
=== ftp command is merely displayed using `ECHO`
c:\windows\system32\ftp.exe -i -s:ftp.txt

=== for loop variables: a=[domain_name2], b=[username2], c=[pass<;!%word2]
=== ftp.txt content
open domain_name2
username2
pass<;!%word2
cd /public_html
bin
hash
put "test.txt"
close
bye
=== ftp command is merely displayed using `ECHO`
c:\windows\system32\ftp.exe -i -s:ftp.txt

==>

关于windows - Microsoft 批处理文件未将参数传递给子例程，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/37648941/