我正在尝试将元素除以一个数字(比如 3.33)，然后将这些元素转换为属性。元素被转换但没有除法运算。

这是原始的xml格式

<box>
     <h>721</h>
     <w>198</w>
     <xc>499.</xc>
     <yc>8.5450000000000000e+02</yc>
</box>

当前输出为

<box h="721" w="198" xc="499." yc="8.5450000000000000e+02"/>

我正在使用的 XSLT 代码

<xsl:template match="box">
    <xsl:element name="box">
        <xsl:for-each select="*">
            <xsl:attribute name="{name()}" >
                <xsl:value-of select="text()" />
            </xsl:attribute>
        </xsl:for-each>
    </xsl:element>
</xsl:template>

<xsl:template match="box/@*">
    <xsl:variable name="num">
        <xsl:choose>
            <xsl:when test="contains(., 'e+')">
                <xsl:variable name="factor">
                    <xsl:call-template name="power-of-10">
                        <xsl:with-param name="exponent" select="substring-after(., 'e+')"/>
                    </xsl:call-template>
                </xsl:variable>
                <xsl:value-of select="substring-before(., 'e+') * $factor" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <xsl:value-of select="$num div 3.3" />
    <xsl:if test="position()!=last()">
        <xsl:text>,</xsl:text>
    </xsl:if>
</xsl:template>

<xsl:template name="power-of-10">
    <xsl:param name="exponent"/>
    <xsl:param name="result" select="1"/>
    <xsl:choose>
        <xsl:when test="$exponent">
            <xsl:call-template name="power-of-10">
                <xsl:with-param name="exponent" select="$exponent - 1"/>
                <xsl:with-param name="result" select="$result * 10"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$result"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

最佳答案

您的第二个模板对属性进行操作，但您的输入 XML 中没有属性。意识到模板匹配的是输入 XML，而不是输出 XML。

您可以将执行转换的第二个模板更改为可从第一个模板调用的可调用模板。然后，在消除逗号代码的同时，您将获得反射(reflect)指定数字转换的 XML 输出。

完整的 XSLT:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="box">
    <xsl:element name="box">
      <xsl:for-each select="*">
        <xsl:attribute name="{name()}" >
          <xsl:call-template name="convert">
            <xsl:with-param name="val" select="."/>
          </xsl:call-template>
        </xsl:attribute>
      </xsl:for-each>
    </xsl:element>
  </xsl:template>

  <xsl:template name="convert">
    <xsl:param name="val"/>
    <xsl:variable name="num">
      <xsl:choose>
        <xsl:when test="contains(., 'e+')">
          <xsl:variable name="factor">
            <xsl:call-template name="power-of-10">
              <xsl:with-param name="exponent"
                              select="substring-after(., 'e+')"/>
            </xsl:call-template>
          </xsl:variable>
          <xsl:value-of select="substring-before(., 'e+') * $factor" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="." />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:value-of select="$num div 3.3" />
  </xsl:template>

  <xsl:template name="power-of-10">
    <xsl:param name="exponent"/>
    <xsl:param name="result" select="1"/>
    <xsl:choose>
      <xsl:when test="$exponent">
        <xsl:call-template name="power-of-10">
          <xsl:with-param name="exponent" select="$exponent - 1"/>
          <xsl:with-param name="result" select="$result * 10"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$result"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>  

</xsl:stylesheet> 

XML 输出

<?xml version="1.0" encoding="UTF-8"?>
<box h="218.4848484848485"
     w="60"
     xc="151.21212121212122"
     yc="258.93939393939394"/>

关于xml - 将 XML 元素转换为具有计算值的属性，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/31455239/